Msg: 5581 *Conference*

12-06-94 19:19:35

From: RON WIESEN

To : TOM POWERS

Subj: REPLY TO MSG #5554 (UPLOAD TO WINDOWS)

I avoid Windows whenever possible and just use a pair of U.BAT and D.BAT batch
files (Up/Down) to upload and download ASCII files via a nul modem cable to
computers with DOS operating systems.  The up/down designation is from the
Model T laptop perspective, not from the tabletop perspective.
 
These batch files let me upload and download via the first serial port (COM:1)
of the tabletop computer at from 110 to 19,200 baud.  The corresponding Stat
settings for TELCOM are from 28N1E to 98N1E.  Edit them if you want to use
other serial ports (e.g., COM:2).
 
But sometimes I'm forced (kicking & screaming) to contend with a Windows
environment.  In these cases I transfer files through the Winodws environment
in one of two ways: through the MS_DOS shell via the U.BAT and D.BAT batch
files; via the Terminal application.  In both cases, the Windows environment
imposes time penalties that garble transmissions above 2,400 baud (despite
using a 66 MHz 80486 speed deamon).  Perhaps this is the problem you're
experiencing.
 
Although no time penalty applies to uploads from the Model T, downloads above
300 baud (600 and 1,200) are only possible with Liquid Crystal Display (LCD)
scroll disabled in the Model T.  To disable LCD scroll, memory location 63038
must set to a non-zero value while you are in TELCOM.  I think there's a
program or two in the Library that link to TELCOM for this purpose.  I use my
own, called LFKYR_, which is a whole other topic I've described to you
privately by E-Mail here on the BBS.  In short, LFKYR_ has no HIMEM requirement
to install it (just run it's .CO file), consumes no free memory (you Kill the
.CO), leaves much needed functions added to BASIC and TELCOM, and makes
PRINTing easier.  I swear it's true!
 
Here's the U.BAT and D.BAT batch files I use in tabletops.  They're friendly.
 
        U.BAT batch file
 
 @ECHO OFF
 REM Upload from laptop to tabletop or to printer (PRN). Beeps at EndOfFile
 REM Toward PRN, file U.FNT is a printer specific preamble for font load
 CLS
 IF /%2==/ MODE COM1:19200,N,8,1 >nul
 IF NOT /%2==/ MODE COM1:%2,N,8,1 >nul
 IF /%1==/ ECHO U accepts [?] baud upload from laptop.
 IF /%1==/ ECHO         Syntax:         U filename [baud]
 IF /%1==/ ECHO                 baud:   110,300,600,1200,2400,4800,9600,19200
 IF /%1==/ ECHO         default 19200
 IF /%1==/ GOTO END
 IF /%2==/ ECHO Begin 19200 baud upload from laptop computer.
 IF NOT /%2==/ ECHO Begin %2 baud upload from laptop computer.
 ECHO Laptop must send End-Of-File (ctrl Z) to end this upload.
 IF /%1==/PRN GOTO PRN
 IF /%1==/prn GOTO PRN
 IF /%1==/Prn GOTO PRN
 IF /%1==/PRn GOTO PRN
 IF /%1==/pRN GOTO PRN
 IF /%1==/prN GOTO PRN
 IF /%1==/pRn GOTO PRN
 IF /%1==/PrN GOTO PRN
 GOTO NOTPRN
 :NOTPRN
 COPY COM1:+NUL %1 >nul
 REM next line sends BELL character ctrl G i.e., CHR$(7) to beep
 ECHO 
 ECHO Upload ended
 DIR %1
 GOTO END
 :PRN
 REM next line sends file U.FNT for font load and then the upload from laptop
 COPY U.FNT+COM1:+NUL PRN >nul
 REM next line sends BELL character ctrl G i.e., CHR$(7) to beep
 ECHO 
 ECHO Upload to PRN ended
 GOTO END
 :END
 
        D.BAT batch file
 
 @ECHO OFF
 REM Download from tabletop to laptop. Beeps at EndOfFile
 CLS
 IF /%2==/ MODE COM1:19200,N,8,1 >nul
 IF NOT /%2==/ MODE COM1:%2,N,8,1 >nul
 IF /%1==/ ECHO D gives [?] baud download to laptop.
 IF /%1==/ ECHO         Syntax:         D filename [baud]
 IF /%1==/ ECHO                 baud:   110,300,600,1200,2400,4800,9600,19200
 IF /%1==/ ECHO         default 19200
 IF /%1==/ GOTO END
 IF /%2==/ ECHO Begin 19200 baud download to laptop computer.
 IF NOT /%2==/ ECHO Begin %2 baud download to laptop computer.
 COPY %1+NUL COM1: >nul
 REM next line sends BELL character ctrl G i.e., CHR$(7) to beep
 ECHO 
 ECHO Download ended
 :END
 
Hope this helps.  Have a nice day.