Bitchin100 DocGarden - User contributions [en]

M100 TS-DOS ROM UI Code

2009-04-03T08:52:27Z

Kpettit:

== TS-DOS Model 100/102 User Interface Code ==

<pre>
; =========================================================================================
; TS-DOS UI Entry location
; =========================================================================================

.org 3535H

3535H LXI H,FCC0H ; Start of Alt LCD character buffer
3538H MVI B,B4H ; Prepare to clear 180 bytes from the ALTLCD buffer
353AH XRA A ; Prepare to clear the ALTLCD buffer
353BH CALL 4A34H ; Fill (HL) with B bytes of A
353EH LXI H,0000H ; Prepare to get current stack pointer
3541H DAD SP ; Copy SP into HL
3542H SHLD FCCEH ; Stack pointer upon entry - pointer to arguments
3545H MVI A,01H ; Set flag to print error message to LCD - GUI mode
3547H CALL 4A85H ; Save the currently selected baud rate settings
354AH XRA A ; Zero A to clear our vars
354BH STA FCD4H ; Current Page of files being displayed
354EH STA FCDAH ; TPDD "skip page" count
3551H STA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3554H STA FCCAH ; TPDD2 Bank number
3557H INR A ; A = 1 to select 1st file on page
3558H STA FCCDH ; Currently selected file index
355BH LXI H,3564H ; Get pointer to main loop routine
355EH SHLD FCD0H ; Return vector after error
3561H CALL 4C27H ; CLS statement

; =========================================================================================
; UI Main loop
; =========================================================================================
3564H CALL 4C5AH ; Resume automatic scrolling
3567H CALL 3611H ; Print Copyright and files
356AH LDA FCD5H ; Load currently selected index from temp storage
356DH STA FCCDH ; Currently selected file index
3570H CALL 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Code will return here when a funtion key is pressed (except F4 & F6)
; =========================================================================================
3573H LXI H,48B5H ; Get address of "Long jump"
3576H PUSH H ; Push "Long jump" address to stack
3577H PUSH PSW ; Save function key press to stack
3578H CPI 02H ; Test if function key is F5-F8 (Non file operation F Keys)
357AH JNC 35B9H ; Jump to Function key handler if F5-F8 (No tagging to process)
357DH LDA FCCCH ; Last Tag/Untag operation code
3580H ANA A ; Test if a tag operation was performed
3581H JZ 35B9H ; Jump to Function key handler if no tag operation performed
3584H LDA FCD6H ; Count of files on screen
3587H MOV C,A ; Save count of files for loop decrementing
3588H INR C ; Increment by 1 for loop bounding
3589H MVI B,00H ; Start with index zero on the LCD
358BH PUSH B ; Save the current index on the stack

; =========================================================================================
; Display next file
; =========================================================================================
358CH LDA FCCDH ; Currently selected file index
358FH STA FCD5H ; Currently selected file index - temp
3592H CALL 3AC4H ; Print selected file using normal video
3595H POP B ; Restore index from stack
3596H INR B ; Increment to the next file index to display
3597H DCR C ; Decrement the loop control
3598H JZ 48B5H ; Branch to perform "Long Jump" if all files printed to LCD
359BH MOV A,B ; Get the index of the current file
359CH STA FCD5H ; Save in temporary "current file" area
359FH STA FCCDH ; Currently selected file index
35A2H PUSH B ; Push the value on the stack for the next iteration
35A3H CALL 3AB2H ; Print currently selected file using inverse video
35A6H LHLD FCE4H ; LCD Buffer address of current file selection
35A9H DCX H ; Decrement to the Tag area for the file
35AAH MOV A,M ; Get the file's Tag code
35ABH CPI 3EH ; Compare with '>'
35ADH JNZ 358CH ; Jump to process next file if not tagged
35B0H POP B ; Pop currently selected file value from stack
35B1H POP PSW
35B2H LXI H,358CH ; Return address to display the next file
35B5H PUSH PSW ; ? Stack trickery
35B6H PUSH B ; Save current file index to stack for use after a RET operation
35B7H PUSH H ; Setup "Display next file" as a return address for RET
35B8H PUSH PSW ; ? More stack trickery

; =========================================================================================
; Function key handler - Disk mode and dispatch to RAM mode
; =========================================================================================
35B9H CALL 4C56H ; Stop automatic scrolling
35BCH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
35BFH ORA A
35C0H JZ 35E2H ; Branch if in RAM mode
35C3H POP PSW
35C4H ANA A ; Test for F1
35C5H JZ 3B2EH ; Branch to F1 handler for disk
35C8H DCR A ; Test for F2
35C9H JZ 3D73H
35CCH DCR A ; Test for F3
35CDH JZ 3D9FH
35D0H DCR A ; Skip F4 - handled at lower level
35D1H DCR A ; Test for F5
35D2H JZ 3D53H
35D5H DCR A ; Skip F6 - handled at lower level
35D6H DCR A ; Test for F7
35D7H JZ 3D00H
35DAH DCR A ; Test for F8
35DBH POP H
35DCH JZ 35FEH ; Jump to exit if F8
35DFH JMP 3564H ; Jump to main loop

; =========================================================================================
; Function key handler - RAM mode
; =========================================================================================
35E2H POP PSW
35E3H ANA A ; Test for F1
35E4H JZ 3C4BH
35E7H DCR A ; Test for F2
35E8H JZ 3C2BH
35EBH DCR A ; Test for F3
35ECH JZ 3AF8H
35EFH DCR A ; Skip F4 - handled at lower level
35F0H DCR A ; Test for F5
35F1H JZ 3E5CH
35F4H DCR A ; Skip F6 - handled at lower level
35F5H DCR A ; Skip F7 - not defined for RAM
35F6H DCR A ; Test for F8
35F7H POP H
35F8H JZ 35FEH ; Jump to exit if F8
35FBH JMP 3564H ; Jump back to main loop

; =========================================================================================
; This is the UI exit routine
; =========================================================================================
35FEH CALL 4AC4H ; Restore original baud settings
3601H CALL 4BD7H ; Wait for TX empty and Reset UART to accept mode bits
3604H CALL 4C27H ; CLS statement
3607H CALL 4C5AH ; Resume automatic scrolling
360AH LXI H,0000H
360DH PUSH H
360EH JMP 00A6H ; Exit TS-DOS

; =========================================================================================
; Print Copyright string and files
; =========================================================================================
3611H LXI H,0101H ; Goto top left corner
3614H SHLD F639H ; Cursor row (1-8)
3617H LXI H,3E69H ; Point to "TS-DOS" copyright string
361AH CALL 4A2CH ; Send buffer at M to screen
361DH XRA A ; Indicate no previous Tag/Untag operation
361EH STA FCCCH ; Last Tag/Untag operation code
3621H MVI A,01H ; Start with 1st file in list
3623H STA FCD5H ; Currently selected file index - temp
3626H LXI H,0202H ; Goto first file entry location
3629H SHLD F639H ; Cursor row (1-8)
362CH JMP 383BH ; Draw the display

; =========================================================================================
; Print length of selected file using inverse video
; =========================================================================================
362FH LDA FCCDH ; Currently selected file index
3632H STA FCD5H ; Currently selected file index - temp
3635H CALL 3AB2H ; Print currently seleted file using inverse video
3638H LDA FCD5H ; Currently selected file index - temp
363BH DCR A ; Make index zero based for multiply x2
363CH STC ; Set Carry flag
363DH CMC ; Compliment (clear) carry flag
363EH RLC ; Rotate left circular
363FH MOV E,A ; E = File index * 2 to point to file length value
3640H MVI D,00H ; Clear MSB of file length offset
3642H LXI H,F685H ; Keyboard buffer - store file lengths
3645H DAD D ; Add file lenght offset from beginning of keyboard buffer
3646H XCHG ; HL <--> DE Save file length address pointer in DE
3647H LXI H,2307H ; Load position of File Size area on LCD
364AH SHLD F639H ; Cursor row (1-8)
364DH CALL 4C2BH ; Erase from cursor to end of line
3650H LHLX ; Load HL with file length
3651H CALL 4C2FH ; Start inverse character mode
3654H CALL 4C3EH ; Print binary number in HL at current position
3657H CALL 4C33H ; Cancel inverse character mode

; =========================================================================================
; Keyboard scan loop
; =========================================================================================
365AH CALL 3DFEH ; Process automatic power off logic
365DH CALL 4BEFH ; Scan keyboard for character (CTRL-BREAK ==> CTRL-C)
3660H JZ 365AH ; Jump to scan keyboard again if no key pressed
3663H JC 380CH ; Jump to Function Key Handler if FKey
3666H CPI 0DH ; Test for CR
3668H JZ 3722H
366BH CPI 17H ; Test for Ctrl-Up key
366DH JZ 37AAH
3670H CPI 14H ; Test for Shift-Up key
3672H JZ 3798H
3675H CPI 5DH ; Test for "]" key
3677H JZ 3798H
367AH CPI 3FH ; Test for "?" key
367CH JZ 3777H
367FH CPI 02H ; Test for Shift-Down arrow key
3681H JZ 3777H
3684H CPI 1EH ; Test for up key
3686H JZ 36EEH
3689H CPI 1FH ; Test for down key
368BH JZ 36FCH
368EH CPI 1DH ; Test for "left arrow" key
3690H JZ 36DDH
3693H CPI 1CH ; Test for "Right arrow" key
3695H JZ 36CAH
3698H CPI 20H ; Test for space key
369AH JZ 36CAH ; Treat space the same as right arrow
369DH ANI DFH ; Convert to Upper case
369FH CPI 52H ; Test for 'R' character
36A1H JZ 3759H
36A4H CPI 54H ; Test for 'T' character
36A6H JZ 37EEH
36A9H CPI 41H ; Test for "A" key
36ABH JZ 3715H
36AEH CPI 47H ; Test for "G" key
36B0H JZ 3715H
36B3H CPI 55H ; Test for "U" key
36B5H JZ 37AEH
36B8H CPI 44H ; Test for "D" key
36BAH JZ 39B9H
36BDH CPI 4CH ; Test for "L" key
36BFH JZ 39C2H
36C2H CPI 50H ; Test for "P" key
36C4H JZ 39C2H
36C7H JMP 365AH ; Go scan keyboard again

; =========================================================================================
; Handle Right Arrow key from TS-DOS key scan
; =========================================================================================
36CAH MVI A,01H ; Prepare to add 1 to selected file
36CCH LXI H,FCD5H ; Currently selected file index - temp storage
36CFH ADD M ; Add 1 to the selected file index
36D0H INX H ; Point to file count on screen
36D1H CMP M ; Compare new index with screen file count
36D2H JC 370AH ; Jump to process new file if we didn't wrap
36D5H JZ 370AH ; Jump to process new file if = file count
36D8H MVI A,01H ; Wrap to the first file
36DAH JMP 370AH ; Go process file 1 as the new selection

; =========================================================================================
; Handle Left Arrow key from TS-DOS key scan
; =========================================================================================
36DDH LDA FCD5H ; Currently selected file index - temp storage
36E0H DCR A ; Move to next lowest file index
36E1H JNZ 370AH ; If no wrap, jump to process new selection
36E4H LDA FCD6H ; Count of files on screen
36E7H ANA A ; Ensure there is at least 1 file on the screen
36E8H JZ 365AH ; Jump to keyboard scan loop if no files on LCD
36EBH JMP 370AH ; Go process new selection as the max (wrap-around)

; =========================================================================================
; Handle Up Arrow key from TS-DOS key scan
; =========================================================================================
36EEH LDA FCD5H ; Currently selected file index - temp storage
36F1H SUI 04H ; Subtract 4 from file count (4 files per line)
36F3H JC 365AH ; Jump to keysacn loop if negative
36F6H JZ 365AH ; Jump to keysacn loop if zero
36F9H JMP 370AH ; Go process the new file index setting

; =========================================================================================
; Handle Down Arrow key from TS-DOS key scan
; =========================================================================================
36FCH MVI A,04H ; There are 4 files per line
36FEH LXI H,FCD5H ; Currently selected file index - temp storage
3701H ADD M ; Add 4 to the index number
3702H MOV C,A ; Save new index for comparison and further processing
3703H INX H ; Maximum file index count
3704H MOV A,M ; Load maximum index for bounds
3705H CMP C ; Compare new index with maximum
3706H JC 365AH ; Jump to keyboard scan if moving past last file
3709H MOV A,C ; Restore new current file index
370AH PUSH PSW ; Save new file index for storage after the call
370BH CALL 3AC4H ; Print selected file using normal video
370EH POP PSW ; Restore new file index from stack
370FH STA FCCDH ; Save the new file index
3712H JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle "A" or "G" key from TS-DOS key scan
; =========================================================================================
3715H MVI A,3EH ; Load ">" for the tag symbol
3717H CALL 37CAH ; Go tag all files on the LCD
371AH MVI A,01H ; Indicate last operation as "Tag All"
371CH STA FCCCH ; Last Tag/Untag operation code
371FH JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle Enter key from TS-DOS key scan - Change Directory
; =========================================================================================
3722H LDA FCCBH ; Get NADSBox/Desklink/TPDD2 flag
3725H CPI 02H ; Test if NADSBox current directory valid
3727H JNZ 365AH ; Back to keyscan if no "current directory" - Enter is meaningless
372AH LHLD FCE4H ; LCD Buffer address of current file selection
372DH LXI B,0007H ; Load offset of file extension
3730H DAD B ; Point to file extension of selected file
3731H MOV A,M ; Load the 1st byte of the file extension
3732H CPI 3CH ; Test if 1st byte of extension is "<"
3734H JNZ 365AH ; Jump to keyscan if current selection not directory entry
3737H CALL 4A3BH ; Initialize blank filename and attribute byte
373AH LHLD FCE4H ; LCD Buffer address of current file selection
373DH CALL 3D95H ; Copy filename at (HL) to TX buffer
3740H CALL 408AH ; Open TPDD file for Read Mode
3743H LXI H,0002H ; Load opcode to close currently opened file
3746H CALL 409BH ; Send Request in HL and await response
3749H LHLD FCE4H ; LCD Buffer address of current file selection
374CH LXI D,FCC0H ; NADSBox current directory storage
374FH LXI B,0009H ; Copy 9 bytes of NADSBox directory to the LCD
3752H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3755H XRA A ; Clear A to show 1st page of files
3756H JMP 378AH ; Branch to show the page of files in A

; =========================================================================================
; Handle "R" key from TS-DOS key scan
; =========================================================================================
3759H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
375CH ANA A ; Test if in Disk mode
375DH JNZ 362FH ; Jump to keyscan if in Disk mode
3760H LHLD FCE4H ; LCD Buffer address of current file selection
3763H CALL 4902H ; Copy filename at (HL) to current BASIC program
3766H CALL 4A51H ; Get RAM directory address of current BASIC program
3769H CPI C0H ; Test if filetype is .DO
376BH CZ 5000H ; Call routine to Compress / Decompress .DO files
376EH CALL 4C0FH ; Update system pointers
3771H CALL 3611H ; Print Copyright and files
3774H JMP 362FH ; Jump to keyscan

; =========================================================================================
; Handle "?" and Shift-Down key from TS-DOS key scan
; =========================================================================================
3777H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
377AH ANA A ; Test if RAM mode
377BH JZ 365AH ; Branch to keyscan if in RAM mode
377EH LDA FCD6H ; Count of files on screen
3781H CPI 14H ; Maximum number of files that fit on the screen
3783H JC 365AH ; Branch to keyscan if on last page
3786H LDA FCD4H ; Current Page of files being displayed
3789H INR A ; Increment to next page of files

; =========================================================================================
; Show the page of files indicated by A
; =========================================================================================
378AH STA FCD4H ; Current Page of files being displayed
378DH MVI A,01H ; Go to 1st file on the new page
378FH STA FCCDH ; Currently selected file index
3792H CALL 3611H ; Print copyright and files
3795H JMP 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Handle "]" and Shift-Up key from TS-DOS key scan
; =========================================================================================
3798H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
379BH ANA A ; Test if RAM mode
379CH JZ 365AH ; Branch to keyscan if in RAM mode
379FH LDA FCD4H ; Current Page of files being displayed
37A2H ANA A ; Test if current page is zero
37A3H JZ 365AH ; Branch to keyscan if already on page 0
37A6H DCR A ; Decrement the page number
37A7H JMP 378AH ; Show the page of files indicated by A

; =========================================================================================
; Handle Ctrl-Up key from TS-DOS key scan
; =========================================================================================
37AAH XRA A ; Go to page zero
37ABH JMP 378AH ; Show the page of files indicated by A

; =========================================================================================
; Handle "U" key from TS-DOS key scan - Remove all tags
; =========================================================================================
37AEH MVI A,20H ; Display ' ' as the tag marker
37B0H CALL 37CAH ; Go process tag for all files
37B3H XRA A ; Indicate last tag operation was untag
37B4H STA FCCCH ; Store as "last tag" operation
37B7H JMP 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Swap TPDD2 Bank number
; =========================================================================================
37BAH LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
37BDH DCR A ; Test if the flag = 1 (TPDD2)
37BEH JNZ 365AH ; Jump to keyscan if not 1
37C1H LDA FCCAH ; Get TPDD Bank Number
37C4H XRI 01H ; Switch to the other bank
37C6H STA FCCAH ; Save TPDD bank number
37C9H RET

; =========================================================================================
; Process Tag or Untag for all files on screen
; =========================================================================================
37CAH STA FCCCH ; Store tag/untag code for later
37CDH LDA FCD6H ; Get Maximum file count on screen
37D0H ANA A ; Test for zero
37D1H RZ ; Return if no files on screen
37D2H XRA A ; Clear A
37D3H INR A ; A=1 to selet 1st file
37D4H STA FCD5H ; Currently selected file index
37D7H CALL 3ACDH ; Calculate Row and Column of soon-to-be (newly) selected file
37DAH LHLD FCE4H ; LCD Buffer address of current file selection
37DDH DCX H ; Point to Tag location for the file
37DEH LDA FCCCH ; Get the tag/untag code
37E1H RST 4 ; Display A to the LCD
37E2H LDA FCD5H ; Get currently selected file index
37E5H LXI H,FCD6H ; Point to count of files on screen
37E8H CMP M ; Compare current selection with count of files on LCD
37E9H JC 37D3H ; Jump to process next file if more files left
37ECH ANA A ; Set zero flag to indicate files were tagged/untagged
37EDH RET

; =========================================================================================
; Handle "T" key key from TS-DOS key scan - TAG
; =========================================================================================
37EEH CALL 3ACDH ; Calculate Row and Column of soon-to-be (newly) selected file
37F1H CALL 4C2FH ; Start inverse character mode
37F4H LHLD FCE4H ; LCD Buffer address of current file selection
37F7H DCX H ; Point to the "Tag" area for the file
37F8H MVI A,3EH ; Load the code for ">"
37FAH CMP M ; Compare if file is already tagged
37FBH JNZ 3800H ; Skip ahead if already tagged
37FEH MVI A,20H ; Need to untag - load the untag code
3800H RST 4 ; Display the tag code on the LCD
3801H CALL 4C33H ; Cancel inverse character mode
3804H LXI H,FCCCH ; Point to "last tag" operation code
3807H MVI M,01H ; Indicate last operation was "tag"
3809H JMP 36CAH ; Move to next file - jump to Right Arrow key handler

; =========================================================================================
; 1st level Function Key Handler (handles F4 and F6)
; =========================================================================================
380CH CPI 08H ; Test for valid function key code
380EH JNC 365AH ; Branch back to scan loop if invalid
3811H CPI 05H ; Test for F6
3813H JZ 3833H ; Jump if F6 pressed
3816H CPI 03H ; Test for F4
3818H RNZ ; Return to "Main Loop" if not F4 pressed
3819H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
381CH XRI 01H ; Swap RAM/DISK mode
381EH STA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3821H XRA A ; Clear A to go to 1st page of files
3822H STA FCD4H ; Current Page of files being displayed
3825H MVI A,01H ; Select the 1st file in the page
3827H STA FCCDH ; Currently selected file index
382AH CALL 4C27H ; CLS statement
382DH CALL 3611H ; Print the title bar and files
3830H JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; F6 Function Key Handler
; =========================================================================================
3833H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3836H ANA A ; Test if in RAM or DISK mode
3837H RZ ; Return if RAM mode
3838H JMP 37AAH ; Jump to Ctrl-Up key handler

; =========================================================================================
; Draw the display. This takes care of RAM and Disk mode displays, handles
; skipping page number to the proper "Disk" page, displaying the Bank# or
; current directory for NADSBox/Desklink, showing free space, filling in
; empty slots with "-.-", etc.
; =========================================================================================
383BH LXI H,F685H ; Keyboard buffer
383EH SHLD FCDBH ; Initialize pointer to file length table (in keyboard buffer)
3841H XRA A ; Prepare to set 1st file lenght to zero
3842H MOV M,A ; Set LSB of length of 1st file to zero
3843H INX H ; Increment to MSB of length
3844H MOV M,A ; Set MSB of length of file to zero
3845H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3848H ANA A ; Test if RAM or DISK
3849H JZ 395DH ; Jump to show RAM files if in RAM mode
384CH XRA A ; Prepare to initialize the "page being processed" variable
384DH STA FCDAH ; Clear the "page being processed" variable
3850H CALL 4735H ; Clear #files displayed, init TPDD and send 1st file dir referene opcode
3853H JNZ 390FH ; Process unformated disk (empty slots and error message)
3856H LDA FCD4H ; Current Page of files being displayed
3859H ANA A ; Test if displaying page 0
385AH JZ 3871H ; Jump if showing page 0 - don't need to skikp any pages
385DH STA FCDAH ; Initialize the number of pages left to skip count
3860H CALL 4742H ; Read next page of files from server
3863H LDA FCDAH ; Get the "Pages left to skip" count
3866H DCR A ; Decrement the remaining skip page count
3867H JNZ 385DH ; Keep reading pages until we have skipped enough pages
386AH XRA A ; Prepare to clear the remaining skip page count
386BH STA FCDAH ; Clear the remaining skip page count
386EH STA FCD6H ; Count of files on screen
3871H CALL 4742H ; Read next page of files from server
3874H LDA FCD6H ; Count of files on screen
3877H CPI 14H ; Test if all file slots are full
3879H CC 39AAH ; Print "-.-" for all empty file slots (if any)

; =========================================================================================
; Print NADSBox directory or TPDD Bank number to LCD
; =========================================================================================
387CH LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
387FH ANA A ; Test if server is TPDD
3880H JZ 389FH ; Skip processing Bank # or Current Dir if TPDD
3883H DCR A ; Test if server is TPDD2
3884H JZ 388DH ; Jump to print bank number if TPDD2
3887H LXI H,FCC0H ; Load pointer to NADSBox current directory storage
388AH JMP 38A5H ; Jump to print the NADSBox / Desklink directory

; =========================================================================================
; Print the TPDD Bank number to LCD
; =========================================================================================
388DH LXI H,2401H ; Go to Row 1, column 24
3890H SHLD F639H ; Cursor row (1-8)
3893H CALL 4C2FH ; Start inverse character mode
3896H MVI A,23H ; ASCII code for '#'
3898H RST 4 ; Send character in A to the LCD
3899H LDA FCCAH ; Load TPDD Bank number
389CH ADI 30H ; Convert to ASCII digit
389EH RST 4 ; Send it to the LCD
389FH CALL 4C33H ; Cancel inverse character mode
38A2H JMP 38B8H ; Branch to print the function menu, RAM/Disk free, etc.

; =========================================================================================
; Print the NADSBox / Desklink current directory in title bar
; =========================================================================================
38A5H PUSH H ; Save address of the directory string
38A6H LXI H,2101H ; Prepare to position the cursor in the title bar
38A9H SHLD F639H ; Cursor row (1-8)
38ACH CALL 4C2FH ; Start inverse character mode
38AFH POP H ; Retrieve the directory string from the stack
38B0H MVI C,06H ; Prepare to redraw 6 chars with inverse video
38B2H CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
38B5H CALL 4C33H ; Cancel inverse character mode

; =========================================================================================
; Print funtion menu, RAM/Disk free & selected file length
; =========================================================================================
38B8H LXI H,3E97H ; Point to Disk function menu
38BBH LXI B,3936H ; Routine to print free disk space
38BEH LDA FCD9H ; RAM/Disk mode
38C1H ANA A ; Test if in Disk mode and skip ahead to print Disk FKeys
38C2H JNZ 38CBH ; Skip ahead if in disk mode to keep vectors
38C5H LXI H,3ED9H ; Point to RAM function menu
38C8H LXI B,3922H ; Routine to print free RAM space
38CBH PUSH B ; Save routine address to stack
38CCH PUSH H ; Save pointer to function text to stack
38CDH LDA FCCDH ; Currently selected file index
38D0H LXI H,FCD6H ; Count of files on screen
38D3H CMP M ; Compare selected file with count of files on screen
38D4H JC 38DDH ; Branch if within bounds
38D7H MOV A,M ; Get the file count
38D8H ANA A ; Test if #files = 0
38D9H JNZ 38DDH ; Skip ahead if not zero
38DCH INR A ; Don't allow a count of zero - must be 1
38DDH STA FCD5H ; Currently selected file index - temp
38E0H LXI H,0B07H ; Row & column of start of text
38E3H SHLD F639H ; Cursor row (1-8)
38E6H POP H ; Get address of text from the stack and display it
38E7H CALL 4A2CH ; Send buffer at M to screen
38EAH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
38EDH ANA A ; Test if in RAM mode
38EEH JZ 3905H ; Jump if in RAM mode (0 = RAM)
38F1H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
38F4H ANA A ; Test if server is TPDD
38F5H JZ 3905H ; Skip printing of "Bank" or "Mkdr" if TPDD
38F8H LXI H,3FE9H ; Point to text for "Bank"
38FBH DCR A ; Test if server is TPDD2
38FCH JZ 3902H ; Jump to print "Bank" if TPDD2
38FFH LXI H,3FD8H ; Point to text for "Mkdr"
3902H CALL 4A2CH ; Send buffer at M to screen
3905H CALL 3940H ; Display DISK ON/OFF status on LCD
3908H LXI H,1507H ; Point to location for "Free" space (RAM or DISK)
390BH SHLD F639H ; Cursor row (1-8)
390EH RET

; =========================================================================================
; Handle unformatted disks. Print message and show empty slots.
; =========================================================================================
390FH XRA A ; Starting with slot zero...
3910H CALL 39AAH ; Print "-.-" for all empty file slots
3913H LXI H,3E97H ; Point to Disk Function menu string
3916H LXI B,391CH ; Print NOT FORMATTED to the display
3919H JMP 38CBH ; Go process the print and jump to error handler

; =========================================================================================
; Print "NOT FORMATTED" on the LCD and return
; =========================================================================================
391CH LXI H,`H ; Point to "NOT FORMATTED" string
391FH JMP 4A2CH ; Send buffer at M to screen

; =========================================================================================
; Print RAM free space at current posiiton
; =========================================================================================
3922H LHLD FBB2H ; Start of variable data pointer
3925H XCHG ; HL <--> DE
3926H LHLD F678H ; BASIC string buffer pointer
3929H MOV A,L ; Prepare for 16 bit subtract
392AH SUB E ; Subtract LSB
392BH MOV L,A ; Save LSB of difference for printing
392CH MOV A,H ; Prepare for subtrating MSB
392DH SBB D ; Subtract MSB
392EH MOV H,A ; Save in H for printing
392FH LXI B,FFF2H ; Load signed number -14
3932H DAD B ; Subtract 14 from free memory
3933H JMP 4C3EH ; Print binary number in HL at current position

; =========================================================================================
; Display free space on disk
; =========================================================================================
3936H CALL 4A10H ; Calculate free space on disk
3939H CALL 4C3EH ; Print binary number in HL at current position
393CH MVI A,30H ; Prepare to add an extra '0' since calc is /10
393EH RST 4 ; Send A to the LCD
393FH RET

; =========================================================================================
; Display DISK ON/OFF status on LCD
; =========================================================================================
3940H LDA FCD9H ; DISK/RAM mode (0=RAM, 1=DISK)
3943H ANA A ; Test if in RAM mode
3944H RNZ ; Return if not in RAM mode
3945H LDA FB2CH ; DISK-OFF/ON status
3948H LXI D,3FF2H ; Load pointer to "OFF" text
394BH CPI DBH ; Test if DISK mode (vector LSB) indicates ON or OFF
394DH JZ 3953H ; Branch if in DISK-OFF mode
3950H LXI D,3FF6H ; Load pointer to "ON" text
3953H LXI H,1908H ; Location of DISK-OFF/ON indication on LCD
3956H SHLD F639H ; Cursor row (1-8)
3959H XCHG ; HL = pointer to text in DE
395AH JMP 4A2CH ; Send buffer at M to screen

; =========================================================================================
; Display RAM files to LCD and calculate file lengths
; =========================================================================================
395DH LXI H,F9BAH ; Load pointer to 1st available file slot in catalog
3960H XRA A ; Set count of RAM files on screen to zero
3961H STA FCD6H ; Count of files on screen
3964H MVI A,14H ; Get max # files that will fit on LCD
3966H DCR A ; Decrement the max file count
3967H PUSH PSW ; Save count to the stack
3968H MOV A,M ; Get file type
3969H XRI 80H ; Compliment ?active bit
396BH ANI 9FH ; Test if file is active and should be displayed
396DH JNZ 3996H ; Branch to test next file if not displayed
3970H PUSH H ; Save address of current catalog file
3971H INX H ; Point to file address
3972H MOV E,M ; Get LSB of file address
3973H INX H ; Point to MSB of address
3974H MOV D,M ; Get MSB of file address
3975H XTHL ; HL <--> (SP) Get address of file within catalog
3976H PUSH H ; Push pointer to MSB of address on stack
3977H CALL 3CD3H ; Calculate length of RAM file
397AH XCHG ; HL <--> DE DE has the length
397BH CALL 4791H ; Store next file length to keyboard buffer
397EH POP H ; Get catalog address of current file from stack
397FH XTHL ; HL <--> (SP) swap catalog address with pointer to MSB of file address
3980H INX H ; Increment to filename
3981H MVI C,06H ; Prepare to print 6 characters of filename
3983H CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
3986H MVI A,2EH ; Load code for '.'
3988H RST 4 ; Send A to the LCD
3989H MVI C,02H ; Prepare to print 2 ext bytes to LCD
398BH CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
398EH MVI A,20H ; Load code for space
3990H RST 4 ; Send A to the LCD
3991H LXI H,FCD6H ; Count of files on screen
3994H INR M ; Increment number of files displayed on LCD
3995H POP H ; Get catalog address of file from stack
3996H LXI D,000BH ; Load offset to next file locaion in catalog
3999H DAD D ; Offset HL to next file
399AH POP PSW ; Restore the file count from the stack
399BH DCR A ; Decrement the max file count on the LCD
399CH JNZ 3967H ; Branch to test and display next file until zero
399FH LDA FCD6H ; Get the count of files actually displayed on screen
39A2H CPI 14H ; Test if max number of files displayed
39A4H CC 39AAH ; Branch to display "-.-" for remaining empty slots if not max
39A7H JMP 387CH ; Print NADSBox directory or TPDD Bank number to LCD

; =========================================================================================
; Print "-.-" for all empty file slots
; =========================================================================================
39AAH PUSH PSW ; Save current file index count on stack
39ABH LXI H,3FCDH ; Point to "-.-" text
39AEH CALL 4A2CH ; Send buffer at M to screen
39B1H POP PSW ; Restore current count
39B2H INR A ; Increment file index number
39B3H CPI 14H ; Compare A with max files that fit on LCD
39B5H JNZ 39AAH ; Jump to print next "-.-" if not done
39B8H RET

; =========================================================================================
; Handle "D" key from TS-DOS key scan
; =========================================================================================
39B9H CALL 3AA8H ; Test if printer busy. Return if not busy or error
39BCH CALL 4C52H ; LCOPY statement
39BFH JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle "L", "P" and "O" keys from TS-DOS key scan - list or print .DO file contents
; =========================================================================================
39C2H STA FCDFH ; Save key pressed
39C5H LXI D,0007H ; Load offset of Extension bytes
39C8H LHLD FCE4H ; LCD Buffer address of current file selection
39CBH DAD D ; Point to extension bytes in LCD buffer
39CCH MOV A,M ; Get 1st extension byte
39CDH CPI 44H ; Compare byte with "D"
39CFH JNZ 362FH ; Print length of selected file using inverse video if not "D"
39D2H INX H ; Point to 2nd extension byte
39D3H MOV A,M ; Load 2nd extension byte for comparison
39D4H CPI 4FH ; Compare with "0"
39D6H JNZ 3A06H ; Jump to print compressed file
39D9H CALL 3A49H ; Prepare file for reading (open disk file, address of RAM file)
39DCH LDA FCDFH ; Restore key pressed
39DFH CPI 4CH ; Test if key was "L" - List to LCD
39E1H CZ 4C27H ; CLS statement if LCD
39E4H CNZ 3AA8H ; Test if printer busy. Return if not busy or error
39E7H CALL 3A24H ; Get next block of data to display/print (HL=address)
39EAH PUSH PSW ; Push Z flag indicating if a full 128 bytes was read
39EBH CALL 3A6BH ; Display / print file data bytes at HL, A has length
39EEH POP PSW ; Get Z flag indicating if 128 bytes read
39EFH JZ 39E7H ; Jump to process more if 128 bytes were read last time
39F2H LDA FCDFH ; Restore key pressed
39F5H CPI 4CH ; Test if key was "L"
39F7H JNZ 3A00H ; Skip beep if printing
39FAH MVI A,07H ; Load code for BELL
39FCH RST 4 ; Go print a BELL (beep)
39FDH CALL 3DF8H ; Process power-off logic and wait for a key from keyboard

; =========================================================================================
; Clear screen and perform Long Jump
; =========================================================================================
3A00H CALL 4C27H ; CLS statement
3A03H JMP 48B5H ; Branch to "Long Jump" operation

; =========================================================================================
; Handler for the "O" key - print a compressed file??
; =========================================================================================
3A06H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A09H ANA A ; Test if in Disk mode
3A0AH JNZ 362FH ; Jump to keyscan if in Disk mode
3A0DH LHLD FCE4H ; LCD Buffer address of current file selection
3A10H CALL 4902H ; Copy filename at (HL) to current BASIC program
3A13H CALL 4A51H ; Get RAM directory address of current BASIC program
3A16H CPI C0H ; Test if filetype is .DO
3A18H CZ 5004H ; Call routine to Compress / Decompress .DO files
3A1BH CALL 4C0FH ; Update system pointers
3A1EH CALL 3611H ; Print Copyright and files
3A21H JMP 362FH ; Jump to keyscan

; =========================================================================================
; Get next 128 bytes (or less) of data from RAM or disk file for display
; =========================================================================================
3A24H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A27H ANA A ; Test if RAM mode
3A28H JNZ 40B6H ; If not RAM mode, go send TPDD_READ data opcode and recieve response
3A2BH LHLD FCDDH ; Get length of file to be displayed / printed
3A2EH LXI B,0080H ; Prepare to subtract 128 from length
3A31H MOV A,C ; Save 128 to A
3A32H DSUB ; Subtract 128 from file length
3A33H JNC 3A3AH ; Branch if length >= 128
3A36H DAD B ; Add 128 back to length to print "partial" buffer
3A37H MOV A,L ; Move remainder of bytes to display/print
3A38H MOV L,H ; Clear LSB of remainder
3A39H MOV C,A ; Move LSB of remainder to C
3A3AH SHLD FCDDH ; Save new remaining file length
3A3DH LHLD FCE0H ; Load the address to be printed / saved
3A40H PUSH H ; Save on stack
3A41H DAD B ; Update address to be used for display/printing next time
3A42H SHLD FCE0H ; Save address to be displayed / printed
3A45H POP H ; Retrieve address to be printed this loop from stack
3A46H CPI 80H ; Compare length with maximum
3A48H RET

; =========================================================================================
; Initialize Selected file for display (RAM or Disk)
; =========================================================================================
3A49H CALL 4A3BH ; Initialize blank filename and attribute byte
3A4CH LHLD FCE4H ; LCD Buffer address of current file selection
3A4FH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A52H ANA A ; Test if in RAM mode
3A53H JNZ 3A65H ; Branch to process Disk files if in Disk mode
3A56H CALL 4A4BH ; Get RAM directory address of selected file
3A59H PUSH D ; Push file address to stack
3A5AH CALL 3CD3H ; Calculate length of RAM file, HL=address of catalog entry, DE=file address
3A5DH SHLD FCDDH ; Save length to FDC emulation sector storage area
3A60H POP H ; Pop address of file into H
3A61H SHLD FCE0H ; Save file address
3A64H RET

; =====================================================================================
; Send TPDD Open command to open selected file
; =====================================================================================
3A65H CALL 3D95H ; Copy filename at (HL) to TX buffer
3A68H JMP 408AH ; Open TPDD file for Read Mode

; =====================================================================================
; Display / print file data bytes at HL, A has length
; =====================================================================================
3A6BH XCHG ; HL <--> DE
3A6CH ORA A ; Test if length = 0
3A6DH RZ ; Return if length = 0
3A6EH MOV C,A ; Save length count in C
3A6FH LDA FCDFH ; Load key press value
3A72H CPI 4CH ; Test if key was "L"
3A74H JNZ 3A82H ; Jump to print contents if not "L"
3A77H CALL 3A8FH ; Check for CTRL-C
3A7AH LDAX D ; Load next byte from src pointer
3A7BH RST 4 ; Send A to LCD
3A7CH INX D ; Increment the pointer
3A7DH DCR C ; Decrement the length count
3A7EH JNZ 3A77H ; Keep looping until all data displayed
3A81H RET

; =====================================================================================
; Print file data bytes at HL, A has length
; =====================================================================================
3A82H CALL 3A8FH ; Test for CTRL-C, etc.
3A85H LDAX D ; Load next file byte from source poiner
3A86H CALL 4C42H ; Print A to printer, expanding tabs if necessary
3A89H INX D ; Increment pointer
3A8AH DCR C ; Decrement length count
3A8BH JNZ 3A82H ; Keep looping until all data printed
3A8EH RET

; =========================================================================================
; Test for ESC, CTRL-C or Space
; =========================================================================================
3A8FH CALL 4C4AH ; Check keyboard queue for pending characters
3A92H RZ ; Return if no pending characters
3A93H CALL 4BEBH ; Wait for key from keyboard
3A96H CPI 03H ; Test for F4 maybe?
3A98H JZ 3A00H ; Clear screen and perform Long Jump if F4 maybe?
3A9BH CPI 1BH ; Test for ESC key
3A9DH JZ 3A00H ; Clear screen and perform Long Jump if ESC
3AA0H CPI 20H ; Test for space key
3AA2H JNZ 3A8FH ; Branch back to wait for ESC, CTRL-C or space if not space
3AA5H JMP 4BEBH ; Wait for key from keyboard

; =========================================================================================
; Test if printer busy. Return if not busy, print error if it is
; =========================================================================================
3AA8H IN BBH ; Get printer port input
3AAAH ANI 06H ; Mask all but BUSY and /BUSY
3AACH XRI 02H ; Compliment /BUSY
3AAEH JNZ 487BH ; Printer not ready / FF error
3AB1H RET

; =========================================================================================
; Print currently selected file using inverse video
; =========================================================================================
3AB2H CALL 3ACDH ; Calculate Row and Column of newly selected file
3AB5H SHLD FCE4H ; LCD Buffer address of current file selection
3AB8H CALL 4C2FH ; Start inverse character mode
3ABBH DCX H ; Start drawing from left edge of selection (include space)
3ABCH MVI C,0AH ; Draw 10 characters
3ABEH CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
3AC1H JMP 4C33H ; Cancel inverse character mode

; =========================================================================================
; Print selected file using normal video to "unselect" it
; =========================================================================================
3AC4H CALL 4C33H ; Cancel inverse character mode
3AC7H CALL 3ACDH ; Calculate row and column of newly selected file
3ACAH JMP 3ABBH ; Print the file to the LCD

; =========================================================================================
; Calculate Row and Column of soon-to-be (newly) selected file
; =========================================================================================
3ACDH LDA FCD5H ; Currently selected file index
3AD0H DCR A ; Make selected file zero based
3AD1H MOV L,A ; Save index to 16-bit HL
3AD2H MVI H,00H ; Make MSB zero
3AD4H LXI D,000AH ; Prepare to multiply index * 10 cols
3AD7H CALL 4C1FH ; Signed integer muliply (FAC1=HL*DE)
3ADAH LXI D,FE28H ; Load address of line 2 in the LCD buffer
3ADDH DAD D ; Calculate starting LCD buffer address for this file
3ADEH INX H ; Skip the "tag" space on the LCD
3ADFH PUSH H ; Save address on the stack
3AE0H LXI B,FE00H ; Load starting address of LCD character buffer
3AE3H DSUB ; Calculate file start offset from start of LCD buffer
3AE4H LXI D,0028H ; Load 1 LCD line width
3AE7H XCHG ; HL <--> DE Prepare for divide
3AE8H CALL 4C1BH ; Signed integer divide (FAC1=DE/HL)
3AEBH MOV A,L ; Save selected file's row number to A
3AECH INR A ; Make row 1-based
3AEDH STA F639H ; Cursor row (1-8)
3AF0H XCHG ; HL <--> DE DE had remainder*2 from divide
3AF1H ASHR ; Divide HL by 2
3AF2H MOV A,L ; Prepare to save remainder as the column
3AF3H STA F63AH ; Cursor column (1-40)
3AF6H POP H ; Restore address of LCD buffer location from stack
3AF7H RET

; =========================================================================================
; F3 Function key handler for RAM mode - Rename
; =========================================================================================
3AF8H CALL 4A4BH ; Get RAM directory address of selected file
3AFBH SHLD FCE0H ; Save address of file being processed
3AFEH LXI H,3F4AH ; Address of "New name" string
3B01H CALL 3E1AH ; Get 6-byte input filename from keyboard
3B04H RZ ; Return if no input provided
3B05H CALL 4902H ; Copy filename at (HL) to current BASIC program
3B08H LHLD FCE0H ; Load RAM directory address of file being renamed
3B0BH LXI B,0009H ; Load offset of extension within catalog entry
3B0EH DAD B ; Point to extension bytes
3B0FH LXI D,FC99H ; Load address of extension field of current BASIC program name
3B12H MOV A,M ; Get 1st byte of extension of catalog file being renamed
3B13H STAX D ; Save extension byte in current BASIC program filename - preserve EXT
3B14H INX D ; Point to 2nd ext byte of BASIC program name
3B15H INX H ; Point to 2nd ext byte of catalog filename
3B16H MOV A,M ; Get 2nd extension byte from catalog filename
3B17H STAX D ; Save byte in current BASIC program filename area
3B18H CALL 4A51H ; Get RAM directory address of current BASIC program
3B1BH JNZ 487EH ; If found, jump to File Exists Error
3B1EH LHLD FCE0H ; Load catalog address of file being renamed
3B21H INX H ; Point to LSB of file address
3B22H INX H ; Point to MSB of file address
3B23H INX H ; Point to name
3B24H LXI D,FC93H ; Load address of filename of current BASIC program
3B27H LXI B,0006H ; Prepare to copy 6 bytes of filename (ext doesn't change)
3B2AH XCHG ; HL <--> DE
3B2BH JMP 4A05H ; Move BC bytes from M to (DE) with increment

; =========================================================================================
; F1 Function key handler for DISK mode - Load
; =========================================================================================
3B2EH CALL 4A3BH ; Initialize blank filename and attribute byte
3B31H LHLD FCE4H ; LCD Buffer address of current file selection
3B34H CALL 3D95H ; Copy filename at (HL) to TX buffer
3B37H LDA FCCCH ; Last Tag/Untag operation code
3B3AH ANA A ; Test if a tag operation is pending
3B3BH JNZ 3B56H ; Branch if doing tag load operation
3B3EH LXI H,3F7AH ; Point to "Load as:" text
3B41H CALL 3E1AH ; Get 6-byte filename input from keyboard
3B44H JZ 3B56H ; Jump to use existing disk name as filename
3B47H CALL 4902H ; Copy filename at (HL) to current BASIC program
3B4AH LXI B,0002H ; Prepare to copy 2 extension bytes to current BASIC program space
3B4DH LXI H,FCEFH ; Point to disk file extension in TX buffer
3B50H LXI D,FC99H ; Point to current BASIC program extension address
3B53H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3B56H CALL 4A51H ; Get RAM directory address of current BASIC program
3B59H JZ 3B69H ; Branch to load if file doesn't already exist
3B5CH LXI H,3FB0H ; Point to "File Exists, Replace?" text
3B5FH CALL 48F4H ; Print string at HL to col 1 on the bottom line
3B62H CALL 3DEEH ; Get key from keyboard and test for 'Y' or 'y'
3B65H RNZ ; Return if isn't 'y' or 'Y'
3B66H CALL 3C38H ; Kill file in current BASIC program space
3B69H LHLD FD1DH ; Get file size from RX buffer
3B6CH MOV A,H ; Swap bytes (big endian in RX buffer)
3B6DH MOV H,L ; Move LSB to MSB
3B6EH MOV L,A ; Move MSB to LSB
3B6FH SHLD FD1DH ; Save with little endian to RX buffer
3B72H LDA FCEFH ; Get 1st byte of extension from TX buffer
3B75H CPI 44H ; Test if 1st extension byte is "D"
3B77H JNZ 3B82H ; Jump if not "D" to check for "C" or "B"
3B7AH LHLD FBAEH ; Get start of DO files pointer for location of new file
3B7DH MVI A,C0H ; Load file type code for .DO files
3B7FH JMP 3BA3H ; Process the file load

; =========================================================================================
; Test file exension type in A for .CO files
; =========================================================================================
3B82H CPI 43H ; Test if A contains "C"
3B84H JNZ 3B95H ; Branch if not .CO file
3B87H LHLD FBB0H ; Start of CO files pointer
3B8AH SHLD FCD5H ; Save in currently selected file index storage area
3B8DH LHLD FBB2H ; Get Start of variable data pointer as location for new file
3B90H MVI A,A0H ; Load file type code for .CO files
3B92H JMP 3BA3H ; Process the file load

; =========================================================================================
; Process load of .BA file
; =========================================================================================
3B95H LHLD FD1DH ; Get file size from RX buffer
3B98H SHLD FCD5H ; Save in Currently selected file index storage
3B9BH LHLD F99AH ; Get BASIC program not saved pointer
3B9EH SHLD FCE0H ; Save as address of file being processed
3BA1H MVI A,80H ; Load file type code for .BA files

; =========================================================================================
; Process file load operation
; =========================================================================================
3BA3H STA FCDFH ; Save file type code for later
3BA6H SHLD FCE2H ; Save address for new file
3BA9H LHLD FD1DH ; Get file size from RX buffer
3BACH SHLD FCDDH ; Save in FDC emulation physical/logical sector storage area
3BAFH PUSH H ; Save file size on stack
3BB0H POP B ; Copy file size to BC
3BB1H LDA FCDFH ; Get file type code
3BB4H CPI A0H ; Test for .CO file
3BB6H JZ 3BC0H ; Skip increment if .CO file (.BA has trailing 0x0000, .DO a 0x1A)
3BB9H INX B ; Increment file length for .BA and .DO files
3BBAH CPI 80H ; Test if file is .BA
3BBCH JNZ 3BC0H ; Skip additional increment if .BA
3BBFH INX B ; Add 1 more to length for .BA files to account for both trailing 0's
3BC0H PUSH B ; Save updated length on stack
3BC1H CALL 3E48H ; Find empty catalog entry
3BC4H JC 4887H ; Generate system error 0x0A ("DD") if full
3BC7H POP B ; Get length from stack
3BC8H PUSH H ; Save new file catalog address on stack
3BC9H PUSH B ; Save new file length on stack
3BCAH LHLD FCE2H ; Get address for new contents of new file
3BCDH CALL 4C0BH ; Insert BC spaces at M - make room
3BD0H JC 488AH ; Branch if error - RAM full error
3BD3H LHLD FCE2H ; Restore address of new file contents
3BD6H POP B ; Get file length from stack
3BD7H MVI M,00H ; Fill newly created file space with zero's
3BD9H INX H ; Increment pointer
3BDAH DCX B ; Decrement count
3BDBH MOV A,C ; Move LSB to A to check for zero - could use JNX here!
3BDCH ORA B ; Or in MSB to check for zero
3BDDH JNZ 3BD7H ; Keep looping until all are zero
3BE0H DCX H ; Decrement pointer to last byte in new file
3BE1H POP D ; Get File catalog address from stack
3BE2H LDA FCDFH ; Load file type code byte
3BE5H CPI C0H ; Test for .DO file
3BE7H JNZ 3BF3H ; Branch if not .DO file
3BEAH MVI M,1AH ; Terminate .DO file with EOF marker
3BECH LHLD FCE2H ; Reload address of new file contents
3BEFH DCX H ; Decrement pointer to jump into middle of loop
3BF0H JMP 3C1BH ; Write file entry to catalog

; =========================================================================================
; Process end-of-file / file length for .CO and .BA files
; =========================================================================================
3BF3H CPI A0H ; Test if new file is .CO
3BF5H JNZ 3C04H ; Branch if not .CO - must be .BA
3BF8H LHLD FCD5H ; Get old start of CO files pointer
3BFBH SHLD FBB0H ; Save as current start of CO files pointer
3BFEH LHLD FCE2H ; Reload address of new file contents
3C01H JMP 3C1BH ; Write file entry to catalog

; =========================================================================================
; Process end-of-file for .BA files
; =========================================================================================
3C04H PUSH D ; Push file catalog address to stack
3C05H LHLD FBAEH ; Get start of DO files pointer
3C08H DCX H ; Decrement address by 1
3C09H SHLD F99AH ; Save as new BASIC program not saved pointer
3C0CH INX H ; Increment back to start of .DO files
3C0DH XCHG ; HL <--> DE DE has start of DO files
3C0EH LHLD FCD5H ; Get BA file size
3C11H INX H ; Increment file size to account for trailing 0's
3C12H INX H ; Increment file size to account for trailing 0's
3C13H DAD D ; Add new length to start of DO files pointer
3C14H SHLD FBAEH ; Save new start of DO files pointer
3C17H POP D ; Retrieve file catalog address from stack
3C18H LHLD FCE0H ; Reload address of new file contents

; =========================================================================================
; Write file entry to catalog
; =========================================================================================
3C1BH XCHG ; HL <--> DE DE has file address, HL has catalog address
3C1CH CALL 4C17H ; Write new entry to catalog (A=type, DE=file address,HL=catalog address)
3C1FH CALL 4127H ; Open TPDD file and read data to file address being processed
3C22H CALL 4C0FH ; Update system pointers
3C25H LXI H,0002H ; Load TPDD_READ opcode in HL
3C28H JMP 409BH ; Send Request in HL and await response

; =========================================================================================
; F2 Function key handler for RAM mode - Kill
; =========================================================================================
3C2BH LDA FCCCH ; Get last Tag/Untag operation code
3C2EH ANA A ; Test if there is a pending tag operation
3C2FH CZ 3DE1H ; Display "Sure ?", validate and return if validated if no tag
3C32H LHLD FCE4H ; LCD Buffer address of current file selection
3C35H CALL 4902H ; Copy filename at (HL) to current BASIC program

; =========================================================================================
; Kill file in current BASIC program space
; =========================================================================================
3C38H CALL 4A51H ; Get RAM directory address of current BASIC program
3C3BH CPI C0H ; Test if file is .DO
3C3DH JZ 4BFFH ; Kill .DO file
3C40H CPI A0H ; Test if file is .CO
3C42H JZ 4C07H ; Kill .CO file
3C45H CPI 80H ; Test if file is .BA
3C47H JZ 4C03H ; Kill .BA file
3C4AH RET

; =========================================================================================
; F1 Function key handler for RAM mode - Save
; =========================================================================================
3C4BH CALL 4A3BH ; Initialize blank filename and attribute byte
3C4EH CALL 4A4BH ; Get RAM directory address of selected file
3C51H PUSH D ; Push file address to stack
3C52H PUSH H ; Push file catalog address to stack
3C53H INX H ; Point to LSB of file address
3C54H INX H ; Point to MSB of file address
3C55H INX H ; Point to filename in catalog
3C56H LXI D,FCE8H ; Point to TX buffer data area (payload)
3C59H LXI B,0006H ; Prepare to copy 6 filename bytes to TX packet data
3C5CH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C5FH MVI A,2EH ; Load code for '.'
3C61H STAX D ; Store '.' separator in TX packet data
3C62H INX D ; Increment TX packet data pointer
3C63H LXI B,0002H ; Prepare to copy 2 extention bytes from catalog
3C66H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C69H LDA FCCCH ; Last Tag/Untag operation code
3C6CH ANA A ; Test if a tag save operation is being performed
3C6DH JNZ 3C88H ; Jump ahead if doing a tag save - skip filename questioning
3C70H LXI H,3F71H ; Point to "Save as:" text
3C73H CALL 3E1AH ; Get 6-byte input filename from keyboard
3C76H JZ 3C88H ; Skip ahead to use catalog name if no input given
3C79H CALL 4902H ; Copy filename at (HL) to current BASIC program
3C7CH LXI B,0006H ; Prepare to copy 6 filename bytes from input string
3C7FH LXI D,FCE8H ; Point to filename area in TX buffer
3C82H LXI H,FC93H ; Filename of current BASIC program
3C85H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C88H POP H ; Restore file catalog address from stack
3C89H POP D ; Restore file address from stack
3C8AH PUSH D ; Save file address on stack
3C8BH CALL 3CD3H ; Calculate length of RAM file, HL=address of catalog entry, DE=file address
3C8EH MOV A,H ; Test for zero length file - move H to A
3C8FH ORA L ; OR LSB to test for zero
3C90H JZ 4884H ; Branch if empty - File Empty Error
3C93H PUSH H ; Save file address to stack
3C94H MVI A,01H ; Set file open mode to new file
3C96H STA FCD6H ; Save open mode to pass to open routine
3C99H CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3C9CH CALL 4A72H ; Send Dir Reference opcode
3C9FH JZ 3CCEH ; Jump to write data if file doesn't exist (size = 0)
3CA2H LXI H,3F8BH ; Point to "File Exists, A)ppend R)eplace Q)uit" text
3CA5H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3CA8H CALL 3DF8H ; Process power-off logic and wait for a key from keyboard
3CABH ANI DFH ; Make key uppercase
3CADH RST 4 ; Display key on LCD
3CAEH CPI 52H ; Test if key is 'R'
3CB0H JNZ 3CBCH ; Jump if not 'R'eplace
3CB3H CALL 431AH ; Issue TPDD Delete file Opcode
3CB6H CALL 4A72H ; Send Dir Reference opcode
3CB9H JMP 3CCEH ; Go write data to the file

; =========================================================================================
; F1-Save: Test for 'A'ppend
; =========================================================================================
3CBCH POP H ; Get file length from stack
3CBDH POP D ; Get file address from stack
3CBEH CPI 41H ; Test if response is 'A'ppend
3CC0H RNZ ; Return if not 'A'
3CC1H LDA FCEFH ; Load 1st byte of extension from TX buffer
3CC4H CPI 44H ; Test if file is "D"O file
3CC6H RNZ ; Don't allow appending non DO files
3CC7H MVI A,02H ; Set open mode to open existing (append)
3CC9H STA FCD6H ; Save mode to pass to open routine
3CCCH PUSH D ; Save file address on stack
3CCDH PUSH H ; Save file length on stack

; =========================================================================================
; Save function - Replace or new file, write data to file
; =========================================================================================
3CCEH POP H ; Retrieve file length from stack
3CCFH POP D ; Retrieve file address from stack
3CD0H JMP 40C8H ; Write HL bytes of data from (DE) to TPDD

; =========================================================================================
; Calculate length of RAM file, HL=address of catalog entry, DE=file address
; =========================================================================================
3CD3H MOV A,M ; Get RAM file type from catalog
3CD4H CPI C0H ; Test for .DO file
3CD6H JZ 3CE6H ; Jump to calculate length if .DO file
3CD9H CPI A0H ; Test for .CO file
3CDBH JZ 3CF5H ; Jump to calculate length if .CO file
3CDEH PUSH D ; Save address of start of BASIC program to stack
3CDFH CALL 4C13H ; Call ROM routine to find BASIC end of program
3CE2H POP B ; Get BASIC program start address from stack
3CE3H DSUB ; Subtract starting address from end address
3CE4H DCX H ; Don't count trailing 0x00 as part of BASIC program length
3CE5H RET

; =========================================================================================
; Calculate length of .DO file, HL=Catalog address, DE=file address
; =========================================================================================
3CE6H XCHG ; HL <--> DE Get file address in HL
3CE7H LXI D,0000H ; Clear file length
3CEAH MOV A,M ; Get next byte from .DO file
3CEBH INX H ; Increment pointer
3CECH INX D ; Increment length
3CEDH CPI 1AH ; Test for EOF marker
3CEFH JNZ 3CEAH ; Branch to next byte if not EOF
3CF2H DCX D ; Subtract EOF marker from file length
3CF3H XCHG ; HL <--> DE HL=length
3CF4H RET

; =========================================================================================
; Calculate length of .CO file, HL=Catalog address, DE=file address
; =========================================================================================
3CF5H XCHG ; HL <--> DE Get file address in HL
3CF6H INX H ; Increment past .CO load address
3CF7H INX H ; Increment past MSB of load address
3CF8H MOV C,M ; Get LSB of length
3CF9H INX H ; Increment to MSB of length
3CFAH MOV B,M ; Get MSB of length
3CFBH LXI H,0006H ; Prepare to add 6-byte header to length
3CFEH DAD B ; Add 6-byte header to length
3CFFH RET

; =========================================================================================
; F7 Function key handler for DISK mode - Mkdir
; =========================================================================================
3D00H LDA FCCBH ; NADSBox / TPDD2 / Desklink flag
3D03H ANA A ; Test if server is TPDD
3D04H RZ ; Return if not NADSBox or TPDD2
3D05H DCR A ; Test if TPDD2
3D06H JZ 37BAH ; Go Swap TPDD Bank Number if TPDD2
3D09H CALL 4A3BH ; Must be NADSBOx Initialize blank filename
3D0CH LXI H,3F61H ; Load pointer to "Directory name:" text
3D0FH CALL 3E1AH ; Get 6-byte input filename from keyboard
3D12H RZ ; Return if no input given
3D13H CALL 4902H ; Copy filename at (HL) to current BASIC program
3D16H LXI H,FC93H ; Filename of current BASIC program
3D19H LXI D,FCE8H ; Point to TX buffer data area (payload)
3D1CH LXI B,0006H ; Prepare to copy 6 filename bytes to TX buffer
3D1FH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3D22H LXI H,3E3CH ; Load code for "<>"
3D25H SHLD FCEFH ; Save "<>" extension bytes in TX buffer - NADSBox Mkdir
3D28H MVI A,2EH ; Load code for '.' extension separator
3D2AH STA FCEEH ; Save "." to TX buffer
3D2DH CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D30H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
3D33H CPI 02H ; Test if we have NADSBox current directory
3D35H RNZ ; Return if we don't have current directory
3D36H CALL 4A72H ; Send Directory Reference opcode
3D39H JNZ 3D4DH ; If the file exists, branch to open it for READ mode
3D3CH MVI A,01H ; Load OPEN_WRITE mode into A to create the directory
3D3EH STA FCE8H ; Save A in TX data storage mode field
3D41H LXI H,0101H ; Load opcode to open a file
3D44H CALL 409BH ; Send Request in HL and await response
3D47H LXI H,0002H ; Load opcode to close the file
3D4AH JMP 409BH ; Send Request in HL and await response

; =========================================================================================
; Open and close a directory file (from above)
; =========================================================================================
3D4DH CALL 408AH ; Open TPDD file for Read Mode
3D50H JMP 3D47H ; Branch to close the directory open request

; =========================================================================================
; F5 Function key handler for DISK mode - Format
; =========================================================================================
3D53H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
3D56H CPI 02H ; Test if we have "current directory" name
3D58H RZ ; Return if server is NADSBox / Desklink - No format supported
3D59H LXI H,3F1BH ; Load pointer to "Insert Disk" string
3D5CH CALL 48F4H ; Print string at HL to col 1 on the bottom line
3D5FH CALL 3DEEH ; Get key from keyboard and test for 'Y' or 'y'
3D62H RNZ ; Return if response not 'Y'
3D63H CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D66H CALL 49E3H ; Delay routine - about 3ms
3D69H LXI H,0006H ; Load TPDD_FORMAT opcode in HL
3D6CH CALL 409BH ; Send Request in HL and await response
3D6FH MVI A,07H ; Load code for BELL
3D72H RET ; Go beep to indicate format

; =========================================================================================
; F2 Function key handler for DISK mode - Kill
; =========================================================================================
3D73H LDA FCCCH ; Last Tag/Untag operation code
3D76H ANA A ; Test if there's an active tag group
3D77H CZ 3DE1H ; Display "Sure ?", validate and return if validated if no tag
3D7AH CALL 4A3BH ; Initialize blank filename and attribute byte
3D7DH CALL 3D83H ; Copy selected filename to TX buffer and init TPDD/NADSBox
3D80H JMP 431AH ; Issue TPDD Delete file Opcode

; =========================================================================================
; Copy selected filename to TX buffer and init TPDD/NADSBox
; =========================================================================================
3D83H LXI B,0009H ; Prepare to copy 9 filename bytes
3D86H LHLD FCE4H ; LCD Buffer address of current file selection
3D89H LXI D,FCE8H ; Address of TX packet data
3D8CH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3D8FH CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D92H JMP 4A72H ; Send Dir Reference opcode

; =========================================================================================
; Copy filename at (HL) to TX buffer
; =========================================================================================
3D95H CALL 4902H ; Copy filename at (HL) to current BASIC program
3D98H LXI H,FC93H ; Filename of current BASIC program
3D9BH CALL 4A57H ; Send Dir Reference for filename at (HL)
3D9EH RET

; =========================================================================================
; F3 Function key handler for DISK mode - Name
; =========================================================================================
3D9FH CALL 4A3BH ; Initialize blank filename and attribute byte
3DA2H CALL 3D83H ; Copy selected filename to TX buffer and init TPDD/NADSBox
3DA5H LXI H,FCE8H ; Point to TX buffer data area (payload)
3DA8H LXI D,FC9CH ; Filename of last program loaded from tape
3DABH LXI B,0009H ; Prepare to copy 9 bytes to "last program loaded" filename
3DAEH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3DB1H LHLD FD1DH ; Get file size from RX buffer
3DB4H MOV C,H ; Save file size MSB to C (swap endian)
3DB5H MOV B,L ; Save file size LSB to B (swap endian)
3DB6H LXI H,7CC0H ; ? Load HL with 31936
3DB9H DSUB ; ? Compare file length with 31936
3DBAH LXI H,3F4AH ; Address of "New name" string
3DBDH JNZ 3DD7H ; Branch to change filename if not 30656
3DC0H LXI B,0009H ; Allow a 9-byte filename input string
3DC3H CALL 3E1DH ; Get max BC length input for filename and convert to uppercase
3DC6H RZ ; Return if no input provided
3DC7H PUSH H ; Save pointer to input string to stack
3DC8H PUSH PSW ; Save string length to stack
3DC9H CALL 4A3BH ; Initialize blank filename and attribute byte
3DCCH POP PSW ; Get string length from stack
3DCDH POP H ; Get string address from stack
3DCEH LXI D,FCE8H ; Point to TX buffer data area (payload)
3DD1H MOV C,A ; Copy length to BC
3DD2H MVI B,00H ; Make MSB of length = 0
3DD4H JMP 41B0H ; Rename the TPDD file whose name is in (HL)

; =========================================================================================
; Get filename from keyboard and rename Disk file, filename in "current BASIC program"
; =========================================================================================
3DD7H CALL 3E1AH ; Get 6-byte input filename from keyboard
3DDAH RZ ; Return if no input provided
3DDBH CALL 4902H ; Copy filename at (HL) to current BASIC program
3DDEH JMP 41A7H ; Rename the TPDD file whose name is in "current BASIC program"

; =========================================================================================
; Display "Sure ?", validate and return if validated
; =========================================================================================
3DE1H LXI H,3F83H ; Load pointer to "Sure ?" string
3DE4H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3DE7H CALL 3DEEH ; Get key and test for 'Y' or 'y'
3DEAH JNZ 48B5H ; Branch to "Long jump" operation to abort if not 'y'
3DEDH RET

; =========================================================================================
; Get key from keyboard and test for 'Y' or 'y'
; =========================================================================================
3DEEH CALL 3DF8H ; Process power-off logic and wait for a key from keyboard
3DF1H RST 4 ; Display the key on the LCD
3DF2H CPI 59H ; Test if key pressed was 'Y'
3DF4H RZ ; Return if key pressed was 'Y'
3DF5H CPI 79H ; Test if key pressed was 'y'
3DF7H RET

; =========================================================================================
; Process power-off logic and wait for a key from keyboard
; =========================================================================================
3DF8H CALL 3DFEH ; Process automatic poweroff logic
3DFBH JMP 4BEBH ; Wait for key from keyboard

; =========================================================================================
; Process automatic power-off logic during key scan loop
; =========================================================================================
3DFEH XRA A ; Clear A
3DFFH DCR A ; Set A to 0xFF
3E00H STA F656H ; Power off exit condition switch
3E03H CALL 4C4AH ; Check keyboard queue for pending characters
3E06H JZ 3DFEH ; Branch back if no keyboard characters in queue - wait for key
3E09H XRA A ; Clear A
3E0AH STA F656H ; Power off exit condition switch
3E0DH LXI H,F932H ; Load address of "Renew Automatic Poweroff Counter Flag"
3E10H ORA M ; Test if auto poweroff counter should be renewed
3E11H JZ 4BF7H ; Renew automatic power-off counter if enabled
3E14H CALL 4BF3H ; Turn off the computer
3E17H JMP 3DFEH ; Branch back to continue processing power off logic

; =========================================================================================
; Get max 6-byte input for filename and convert to uppercase
; =========================================================================================
3E1AH LXI B,0006H ; Get maximum 6 characters of input

; =========================================================================================
; Get max BC length input for filename and convert to uppercase
; =========================================================================================
3E1DH CALL 3E2FH ; Get max BC length input string from keyboard
3E20H RZ ; Return if no input provided
3E21H PUSH H ; Preserve pointer to input string
3E22H PUSH PSW ; Preserve flags from input
3E23H CALL 4C5EH ; Get char at M and convert to uppercase
3E26H MOV M,A ; Save uppercase char back to string
3E27H INX H ; Point to next byte in input
3E28H ANA A ; Test for NULL - end of string
3E29H JNZ 3E23H ; Keep looping until end of string
3E2CH POP PSW ; Restore flags from input routine
3E2DH POP H ; Restore pointer to input string
3E2EH RET

; =========================================================================================
; Get maximum BC length input character string from keyboard
; =========================================================================================
3E2FH PUSH B ; Save maximum input length to stack
3E30H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3E33H CALL 4C46H ; Input and display (no "?") line and store
3E36H JC 48B5H ; Branch to "Long jump" if CTRL-C
3E39H INX H ; Point to start of input string
3E3AH MOV A,B ; Get string length (counting NULL)
3E3BH DCR A ; Remove NULL from count
3E3CH POP D ; Restore maximum input length
3E3DH RZ ; Return if string length is zero
3E3EH CMP E ; Compare expected length with actual length
3E3FH RC ; Return if string is shorter than expected
3E40H PUSH H ; Save pointer to start of string on stack
3E41H DAD D ; Add Expected length to pointer
3E42H MVI M,00H ; Truncate the string to the max length
3E44H POP H ; Restore pointer to input string
3E45H MOV A,E ; Update length to reflect maximum
3E46H ORA A ; Clear zero flag to indicate input provided
3E47H RET

; =========================================================================================
; Find Empty catalog entry (only 9 instructions...Don't bother with Main ROM)
; =========================================================================================
3E48H LXI H,F9AFH ; Point to the "RickY" catalog entry (start of valid entries)
3E4BH LXI B,000BH ; Load length of each catalog entry
3E4EH DAD B ; Point to next catalog entry to test if empty
3E4FH MOV A,M ; Get file attribute byte from catalog entry
3E50H CPI FFH ; Test if at end of catalog
3E52H JZ 3E5AH ; Jump to report directory full if at end
3E55H ADD A ; Test if MSB is set (entry being used)
3E56H JC 3E4EH ; Jump to test next enry if MSB set
3E59H RET ; Entry found...return with Carry clear

; =========================================================================================
; Empty catalog entry not found...set Carry and exit
; =========================================================================================
3E5AH STC ; Indicate empty entry not found
3E5BH RET

; =========================================================================================
; F5 Function key handler for RAM mode - DOS ON/OF
; =========================================================================================
3E5CH LHLD FB2CH ; Get LFILES statement hook address
3E5FH LXI B,08DBH ; Load address of default (DOS-OFF) hook for LFILES
3E62H DSUB ; Test if in DOS-OFF mode
3E63H JZ 401FH ; Jump to add our custom RST 7 hooks if in DOS-OFF mode
3E66H JMP 3FFAH ; Must be in DOS-ON mode, jump to turn it off

; =========================================================================================
; Strings
; =========================================================================================
3E69H DB 0x1B, "p TS-DOS (100 v4.00) (c)87,TSI. ",0x1B,'q',0x00
3E97H DB "DISK Free: File:",0DH,0AH,"Load Kill Name Ram Frmt Log Menu",00H
3ED9H DB " RAM Free: File:",0DH,0AH,"Save Kill Name Disk DOS- Menu",00H
3F1BH DB "Insert Disk, Press \"Y\" to begin ",00H
3F3CH DB "NOT FORMATTED",00H
3F4AH DB "New Name:",00H
3F54H DB "System name:",00H
3F61H DB "Directory name:",00H
3F71H DB "Save as:",00H
3F7AH DB "Load as:",00H
3F83H DB "Sure ? ",00H
3F8BH DB "File exists, A)ppend R)eplace Q)uit:",00H
3FB0H DB "File exists, Replace? (Y/N):",00H
3FCDH DB "-.- ",00H
3FD8H DB 0x1B,"Y74 ",1BH,"Y7>MkDr",00H ; TODO: Check this
3FE9H DB 0x1B,"Y7>Bank",00H ; TODO: Check this
3FF2H DB "OFF",00H
3FF6H DB "ON ",00H
</pre>

Navigate to:
* [[Dissasembly of RAM and ROM versions of TS-DOS]]
* [[M100 TS-DOS ROM OptROM Support]]
* [[M100 TS-DOS ROM RST 7 Handlers]]
* [[M100 TS-DOS ROM TPDD Protocol]]
* [[M100 TS-DOS ROM Compression]]
* [[M100 TS-DOS ROM Cold Boot Recovery]]

Disassembly of RAM and ROM versions of TS-DOS

2009-04-03T08:35:37Z

Kpettit: /* Model 200 RAM Version */

== TS-DOS Dissassembly ==

There are various version of TS-DOS for The Model 100/102, for T200 and for the PC-8201a. Additionally each of these versions has a ROM and a RAM. While the majority of the code is equivalent across the various incarnations of TS-DOS, there are some differences due to varying RS-232 hardware and to accomodate execution from OptROM vs. RAM.

The goal of the disassembly is to create a fully commented source file that can be assembled and subsequently modified / enhanced for new functionality. The disassembly is split into several sections to keep each page "relatively" short. The disassembly currently will not assemble as it contains absolute addresses that must be converted into assembly labels, or deleted where not needed.

== Model 100/102 ROM Version ==
* [[M100 TS-DOS ROM OptROM Support]]
* [[M100 TS-DOS ROM UI Code]]
* [[M100 TS-DOS ROM RST 7 Handlers]]
* [[M100 TS-DOS ROM TPDD Protocol]]

Not Completed Yet
* [[M100 TS-DOS ROM Compression]]
* [[M100 TS-DOS ROM Cold Boot Recovery]]

== Model 200 RAM Version ==

* [[T200 TS-DOS RAM UI Code]]
* [[T200 TS-DOS RAM RST 7 Handlers]]
* [[T200 TS-DOS RAM TPDD Protocol]]

M100 TS-DOS ROM UI Code

2009-04-03T08:34:18Z

Kpettit:

== TS-DOS Model 100/102 User Interface Code

<pre>
; =========================================================================================
; TS-DOS UI Entry location
; =========================================================================================

.org 3535H

3535H LXI H,FCC0H ; Start of Alt LCD character buffer
3538H MVI B,B4H ; Prepare to clear 180 bytes from the ALTLCD buffer
353AH XRA A ; Prepare to clear the ALTLCD buffer
353BH CALL 4A34H ; Fill (HL) with B bytes of A
353EH LXI H,0000H ; Prepare to get current stack pointer
3541H DAD SP ; Copy SP into HL
3542H SHLD FCCEH ; Stack pointer upon entry - pointer to arguments
3545H MVI A,01H ; Set flag to print error message to LCD - GUI mode
3547H CALL 4A85H ; Save the currently selected baud rate settings
354AH XRA A ; Zero A to clear our vars
354BH STA FCD4H ; Current Page of files being displayed
354EH STA FCDAH ; TPDD "skip page" count
3551H STA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3554H STA FCCAH ; TPDD2 Bank number
3557H INR A ; A = 1 to select 1st file on page
3558H STA FCCDH ; Currently selected file index
355BH LXI H,3564H ; Get pointer to main loop routine
355EH SHLD FCD0H ; Return vector after error
3561H CALL 4C27H ; CLS statement

; =========================================================================================
; UI Main loop
; =========================================================================================
3564H CALL 4C5AH ; Resume automatic scrolling
3567H CALL 3611H ; Print Copyright and files
356AH LDA FCD5H ; Load currently selected index from temp storage
356DH STA FCCDH ; Currently selected file index
3570H CALL 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Code will return here when a funtion key is pressed (except F4 & F6)
; =========================================================================================
3573H LXI H,48B5H ; Get address of "Long jump"
3576H PUSH H ; Push "Long jump" address to stack
3577H PUSH PSW ; Save function key press to stack
3578H CPI 02H ; Test if function key is F5-F8 (Non file operation F Keys)
357AH JNC 35B9H ; Jump to Function key handler if F5-F8 (No tagging to process)
357DH LDA FCCCH ; Last Tag/Untag operation code
3580H ANA A ; Test if a tag operation was performed
3581H JZ 35B9H ; Jump to Function key handler if no tag operation performed
3584H LDA FCD6H ; Count of files on screen
3587H MOV C,A ; Save count of files for loop decrementing
3588H INR C ; Increment by 1 for loop bounding
3589H MVI B,00H ; Start with index zero on the LCD
358BH PUSH B ; Save the current index on the stack

; =========================================================================================
; Display next file
; =========================================================================================
358CH LDA FCCDH ; Currently selected file index
358FH STA FCD5H ; Currently selected file index - temp
3592H CALL 3AC4H ; Print selected file using normal video
3595H POP B ; Restore index from stack
3596H INR B ; Increment to the next file index to display
3597H DCR C ; Decrement the loop control
3598H JZ 48B5H ; Branch to perform "Long Jump" if all files printed to LCD
359BH MOV A,B ; Get the index of the current file
359CH STA FCD5H ; Save in temporary "current file" area
359FH STA FCCDH ; Currently selected file index
35A2H PUSH B ; Push the value on the stack for the next iteration
35A3H CALL 3AB2H ; Print currently selected file using inverse video
35A6H LHLD FCE4H ; LCD Buffer address of current file selection
35A9H DCX H ; Decrement to the Tag area for the file
35AAH MOV A,M ; Get the file's Tag code
35ABH CPI 3EH ; Compare with '>'
35ADH JNZ 358CH ; Jump to process next file if not tagged
35B0H POP B ; Pop currently selected file value from stack
35B1H POP PSW
35B2H LXI H,358CH ; Return address to display the next file
35B5H PUSH PSW ; ? Stack trickery
35B6H PUSH B ; Save current file index to stack for use after a RET operation
35B7H PUSH H ; Setup "Display next file" as a return address for RET
35B8H PUSH PSW ; ? More stack trickery

; =========================================================================================
; Function key handler - Disk mode and dispatch to RAM mode
; =========================================================================================
35B9H CALL 4C56H ; Stop automatic scrolling
35BCH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
35BFH ORA A
35C0H JZ 35E2H ; Branch if in RAM mode
35C3H POP PSW
35C4H ANA A ; Test for F1
35C5H JZ 3B2EH ; Branch to F1 handler for disk
35C8H DCR A ; Test for F2
35C9H JZ 3D73H
35CCH DCR A ; Test for F3
35CDH JZ 3D9FH
35D0H DCR A ; Skip F4 - handled at lower level
35D1H DCR A ; Test for F5
35D2H JZ 3D53H
35D5H DCR A ; Skip F6 - handled at lower level
35D6H DCR A ; Test for F7
35D7H JZ 3D00H
35DAH DCR A ; Test for F8
35DBH POP H
35DCH JZ 35FEH ; Jump to exit if F8
35DFH JMP 3564H ; Jump to main loop

; =========================================================================================
; Function key handler - RAM mode
; =========================================================================================
35E2H POP PSW
35E3H ANA A ; Test for F1
35E4H JZ 3C4BH
35E7H DCR A ; Test for F2
35E8H JZ 3C2BH
35EBH DCR A ; Test for F3
35ECH JZ 3AF8H
35EFH DCR A ; Skip F4 - handled at lower level
35F0H DCR A ; Test for F5
35F1H JZ 3E5CH
35F4H DCR A ; Skip F6 - handled at lower level
35F5H DCR A ; Skip F7 - not defined for RAM
35F6H DCR A ; Test for F8
35F7H POP H
35F8H JZ 35FEH ; Jump to exit if F8
35FBH JMP 3564H ; Jump back to main loop

; =========================================================================================
; This is the UI exit routine
; =========================================================================================
35FEH CALL 4AC4H ; Restore original baud settings
3601H CALL 4BD7H ; Wait for TX empty and Reset UART to accept mode bits
3604H CALL 4C27H ; CLS statement
3607H CALL 4C5AH ; Resume automatic scrolling
360AH LXI H,0000H
360DH PUSH H
360EH JMP 00A6H ; Exit TS-DOS

; =========================================================================================
; Print Copyright string and files
; =========================================================================================
3611H LXI H,0101H ; Goto top left corner
3614H SHLD F639H ; Cursor row (1-8)
3617H LXI H,3E69H ; Point to "TS-DOS" copyright string
361AH CALL 4A2CH ; Send buffer at M to screen
361DH XRA A ; Indicate no previous Tag/Untag operation
361EH STA FCCCH ; Last Tag/Untag operation code
3621H MVI A,01H ; Start with 1st file in list
3623H STA FCD5H ; Currently selected file index - temp
3626H LXI H,0202H ; Goto first file entry location
3629H SHLD F639H ; Cursor row (1-8)
362CH JMP 383BH ; Draw the display

; =========================================================================================
; Print length of selected file using inverse video
; =========================================================================================
362FH LDA FCCDH ; Currently selected file index
3632H STA FCD5H ; Currently selected file index - temp
3635H CALL 3AB2H ; Print currently seleted file using inverse video
3638H LDA FCD5H ; Currently selected file index - temp
363BH DCR A ; Make index zero based for multiply x2
363CH STC ; Set Carry flag
363DH CMC ; Compliment (clear) carry flag
363EH RLC ; Rotate left circular
363FH MOV E,A ; E = File index * 2 to point to file length value
3640H MVI D,00H ; Clear MSB of file length offset
3642H LXI H,F685H ; Keyboard buffer - store file lengths
3645H DAD D ; Add file lenght offset from beginning of keyboard buffer
3646H XCHG ; HL <--> DE Save file length address pointer in DE
3647H LXI H,2307H ; Load position of File Size area on LCD
364AH SHLD F639H ; Cursor row (1-8)
364DH CALL 4C2BH ; Erase from cursor to end of line
3650H LHLX ; Load HL with file length
3651H CALL 4C2FH ; Start inverse character mode
3654H CALL 4C3EH ; Print binary number in HL at current position
3657H CALL 4C33H ; Cancel inverse character mode

; =========================================================================================
; Keyboard scan loop
; =========================================================================================
365AH CALL 3DFEH ; Process automatic power off logic
365DH CALL 4BEFH ; Scan keyboard for character (CTRL-BREAK ==> CTRL-C)
3660H JZ 365AH ; Jump to scan keyboard again if no key pressed
3663H JC 380CH ; Jump to Function Key Handler if FKey
3666H CPI 0DH ; Test for CR
3668H JZ 3722H
366BH CPI 17H ; Test for Ctrl-Up key
366DH JZ 37AAH
3670H CPI 14H ; Test for Shift-Up key
3672H JZ 3798H
3675H CPI 5DH ; Test for "]" key
3677H JZ 3798H
367AH CPI 3FH ; Test for "?" key
367CH JZ 3777H
367FH CPI 02H ; Test for Shift-Down arrow key
3681H JZ 3777H
3684H CPI 1EH ; Test for up key
3686H JZ 36EEH
3689H CPI 1FH ; Test for down key
368BH JZ 36FCH
368EH CPI 1DH ; Test for "left arrow" key
3690H JZ 36DDH
3693H CPI 1CH ; Test for "Right arrow" key
3695H JZ 36CAH
3698H CPI 20H ; Test for space key
369AH JZ 36CAH ; Treat space the same as right arrow
369DH ANI DFH ; Convert to Upper case
369FH CPI 52H ; Test for 'R' character
36A1H JZ 3759H
36A4H CPI 54H ; Test for 'T' character
36A6H JZ 37EEH
36A9H CPI 41H ; Test for "A" key
36ABH JZ 3715H
36AEH CPI 47H ; Test for "G" key
36B0H JZ 3715H
36B3H CPI 55H ; Test for "U" key
36B5H JZ 37AEH
36B8H CPI 44H ; Test for "D" key
36BAH JZ 39B9H
36BDH CPI 4CH ; Test for "L" key
36BFH JZ 39C2H
36C2H CPI 50H ; Test for "P" key
36C4H JZ 39C2H
36C7H JMP 365AH ; Go scan keyboard again

; =========================================================================================
; Handle Right Arrow key from TS-DOS key scan
; =========================================================================================
36CAH MVI A,01H ; Prepare to add 1 to selected file
36CCH LXI H,FCD5H ; Currently selected file index - temp storage
36CFH ADD M ; Add 1 to the selected file index
36D0H INX H ; Point to file count on screen
36D1H CMP M ; Compare new index with screen file count
36D2H JC 370AH ; Jump to process new file if we didn't wrap
36D5H JZ 370AH ; Jump to process new file if = file count
36D8H MVI A,01H ; Wrap to the first file
36DAH JMP 370AH ; Go process file 1 as the new selection

; =========================================================================================
; Handle Left Arrow key from TS-DOS key scan
; =========================================================================================
36DDH LDA FCD5H ; Currently selected file index - temp storage
36E0H DCR A ; Move to next lowest file index
36E1H JNZ 370AH ; If no wrap, jump to process new selection
36E4H LDA FCD6H ; Count of files on screen
36E7H ANA A ; Ensure there is at least 1 file on the screen
36E8H JZ 365AH ; Jump to keyboard scan loop if no files on LCD
36EBH JMP 370AH ; Go process new selection as the max (wrap-around)

; =========================================================================================
; Handle Up Arrow key from TS-DOS key scan
; =========================================================================================
36EEH LDA FCD5H ; Currently selected file index - temp storage
36F1H SUI 04H ; Subtract 4 from file count (4 files per line)
36F3H JC 365AH ; Jump to keysacn loop if negative
36F6H JZ 365AH ; Jump to keysacn loop if zero
36F9H JMP 370AH ; Go process the new file index setting

; =========================================================================================
; Handle Down Arrow key from TS-DOS key scan
; =========================================================================================
36FCH MVI A,04H ; There are 4 files per line
36FEH LXI H,FCD5H ; Currently selected file index - temp storage
3701H ADD M ; Add 4 to the index number
3702H MOV C,A ; Save new index for comparison and further processing
3703H INX H ; Maximum file index count
3704H MOV A,M ; Load maximum index for bounds
3705H CMP C ; Compare new index with maximum
3706H JC 365AH ; Jump to keyboard scan if moving past last file
3709H MOV A,C ; Restore new current file index
370AH PUSH PSW ; Save new file index for storage after the call
370BH CALL 3AC4H ; Print selected file using normal video
370EH POP PSW ; Restore new file index from stack
370FH STA FCCDH ; Save the new file index
3712H JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle "A" or "G" key from TS-DOS key scan
; =========================================================================================
3715H MVI A,3EH ; Load ">" for the tag symbol
3717H CALL 37CAH ; Go tag all files on the LCD
371AH MVI A,01H ; Indicate last operation as "Tag All"
371CH STA FCCCH ; Last Tag/Untag operation code
371FH JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle Enter key from TS-DOS key scan - Change Directory
; =========================================================================================
3722H LDA FCCBH ; Get NADSBox/Desklink/TPDD2 flag
3725H CPI 02H ; Test if NADSBox current directory valid
3727H JNZ 365AH ; Back to keyscan if no "current directory" - Enter is meaningless
372AH LHLD FCE4H ; LCD Buffer address of current file selection
372DH LXI B,0007H ; Load offset of file extension
3730H DAD B ; Point to file extension of selected file
3731H MOV A,M ; Load the 1st byte of the file extension
3732H CPI 3CH ; Test if 1st byte of extension is "<"
3734H JNZ 365AH ; Jump to keyscan if current selection not directory entry
3737H CALL 4A3BH ; Initialize blank filename and attribute byte
373AH LHLD FCE4H ; LCD Buffer address of current file selection
373DH CALL 3D95H ; Copy filename at (HL) to TX buffer
3740H CALL 408AH ; Open TPDD file for Read Mode
3743H LXI H,0002H ; Load opcode to close currently opened file
3746H CALL 409BH ; Send Request in HL and await response
3749H LHLD FCE4H ; LCD Buffer address of current file selection
374CH LXI D,FCC0H ; NADSBox current directory storage
374FH LXI B,0009H ; Copy 9 bytes of NADSBox directory to the LCD
3752H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3755H XRA A ; Clear A to show 1st page of files
3756H JMP 378AH ; Branch to show the page of files in A

; =========================================================================================
; Handle "R" key from TS-DOS key scan
; =========================================================================================
3759H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
375CH ANA A ; Test if in Disk mode
375DH JNZ 362FH ; Jump to keyscan if in Disk mode
3760H LHLD FCE4H ; LCD Buffer address of current file selection
3763H CALL 4902H ; Copy filename at (HL) to current BASIC program
3766H CALL 4A51H ; Get RAM directory address of current BASIC program
3769H CPI C0H ; Test if filetype is .DO
376BH CZ 5000H ; Call routine to Compress / Decompress .DO files
376EH CALL 4C0FH ; Update system pointers
3771H CALL 3611H ; Print Copyright and files
3774H JMP 362FH ; Jump to keyscan

; =========================================================================================
; Handle "?" and Shift-Down key from TS-DOS key scan
; =========================================================================================
3777H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
377AH ANA A ; Test if RAM mode
377BH JZ 365AH ; Branch to keyscan if in RAM mode
377EH LDA FCD6H ; Count of files on screen
3781H CPI 14H ; Maximum number of files that fit on the screen
3783H JC 365AH ; Branch to keyscan if on last page
3786H LDA FCD4H ; Current Page of files being displayed
3789H INR A ; Increment to next page of files

; =========================================================================================
; Show the page of files indicated by A
; =========================================================================================
378AH STA FCD4H ; Current Page of files being displayed
378DH MVI A,01H ; Go to 1st file on the new page
378FH STA FCCDH ; Currently selected file index
3792H CALL 3611H ; Print copyright and files
3795H JMP 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Handle "]" and Shift-Up key from TS-DOS key scan
; =========================================================================================
3798H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
379BH ANA A ; Test if RAM mode
379CH JZ 365AH ; Branch to keyscan if in RAM mode
379FH LDA FCD4H ; Current Page of files being displayed
37A2H ANA A ; Test if current page is zero
37A3H JZ 365AH ; Branch to keyscan if already on page 0
37A6H DCR A ; Decrement the page number
37A7H JMP 378AH ; Show the page of files indicated by A

; =========================================================================================
; Handle Ctrl-Up key from TS-DOS key scan
; =========================================================================================
37AAH XRA A ; Go to page zero
37ABH JMP 378AH ; Show the page of files indicated by A

; =========================================================================================
; Handle "U" key from TS-DOS key scan - Remove all tags
; =========================================================================================
37AEH MVI A,20H ; Display ' ' as the tag marker
37B0H CALL 37CAH ; Go process tag for all files
37B3H XRA A ; Indicate last tag operation was untag
37B4H STA FCCCH ; Store as "last tag" operation
37B7H JMP 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Swap TPDD2 Bank number
; =========================================================================================
37BAH LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
37BDH DCR A ; Test if the flag = 1 (TPDD2)
37BEH JNZ 365AH ; Jump to keyscan if not 1
37C1H LDA FCCAH ; Get TPDD Bank Number
37C4H XRI 01H ; Switch to the other bank
37C6H STA FCCAH ; Save TPDD bank number
37C9H RET

; =========================================================================================
; Process Tag or Untag for all files on screen
; =========================================================================================
37CAH STA FCCCH ; Store tag/untag code for later
37CDH LDA FCD6H ; Get Maximum file count on screen
37D0H ANA A ; Test for zero
37D1H RZ ; Return if no files on screen
37D2H XRA A ; Clear A
37D3H INR A ; A=1 to selet 1st file
37D4H STA FCD5H ; Currently selected file index
37D7H CALL 3ACDH ; Calculate Row and Column of soon-to-be (newly) selected file
37DAH LHLD FCE4H ; LCD Buffer address of current file selection
37DDH DCX H ; Point to Tag location for the file
37DEH LDA FCCCH ; Get the tag/untag code
37E1H RST 4 ; Display A to the LCD
37E2H LDA FCD5H ; Get currently selected file index
37E5H LXI H,FCD6H ; Point to count of files on screen
37E8H CMP M ; Compare current selection with count of files on LCD
37E9H JC 37D3H ; Jump to process next file if more files left
37ECH ANA A ; Set zero flag to indicate files were tagged/untagged
37EDH RET

; =========================================================================================
; Handle "T" key key from TS-DOS key scan - TAG
; =========================================================================================
37EEH CALL 3ACDH ; Calculate Row and Column of soon-to-be (newly) selected file
37F1H CALL 4C2FH ; Start inverse character mode
37F4H LHLD FCE4H ; LCD Buffer address of current file selection
37F7H DCX H ; Point to the "Tag" area for the file
37F8H MVI A,3EH ; Load the code for ">"
37FAH CMP M ; Compare if file is already tagged
37FBH JNZ 3800H ; Skip ahead if already tagged
37FEH MVI A,20H ; Need to untag - load the untag code
3800H RST 4 ; Display the tag code on the LCD
3801H CALL 4C33H ; Cancel inverse character mode
3804H LXI H,FCCCH ; Point to "last tag" operation code
3807H MVI M,01H ; Indicate last operation was "tag"
3809H JMP 36CAH ; Move to next file - jump to Right Arrow key handler

; =========================================================================================
; 1st level Function Key Handler (handles F4 and F6)
; =========================================================================================
380CH CPI 08H ; Test for valid function key code
380EH JNC 365AH ; Branch back to scan loop if invalid
3811H CPI 05H ; Test for F6
3813H JZ 3833H ; Jump if F6 pressed
3816H CPI 03H ; Test for F4
3818H RNZ ; Return to "Main Loop" if not F4 pressed
3819H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
381CH XRI 01H ; Swap RAM/DISK mode
381EH STA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3821H XRA A ; Clear A to go to 1st page of files
3822H STA FCD4H ; Current Page of files being displayed
3825H MVI A,01H ; Select the 1st file in the page
3827H STA FCCDH ; Currently selected file index
382AH CALL 4C27H ; CLS statement
382DH CALL 3611H ; Print the title bar and files
3830H JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; F6 Function Key Handler
; =========================================================================================
3833H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3836H ANA A ; Test if in RAM or DISK mode
3837H RZ ; Return if RAM mode
3838H JMP 37AAH ; Jump to Ctrl-Up key handler

; =========================================================================================
; Draw the display. This takes care of RAM and Disk mode displays, handles
; skipping page number to the proper "Disk" page, displaying the Bank# or
; current directory for NADSBox/Desklink, showing free space, filling in
; empty slots with "-.-", etc.
; =========================================================================================
383BH LXI H,F685H ; Keyboard buffer
383EH SHLD FCDBH ; Initialize pointer to file length table (in keyboard buffer)
3841H XRA A ; Prepare to set 1st file lenght to zero
3842H MOV M,A ; Set LSB of length of 1st file to zero
3843H INX H ; Increment to MSB of length
3844H MOV M,A ; Set MSB of length of file to zero
3845H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3848H ANA A ; Test if RAM or DISK
3849H JZ 395DH ; Jump to show RAM files if in RAM mode
384CH XRA A ; Prepare to initialize the "page being processed" variable
384DH STA FCDAH ; Clear the "page being processed" variable
3850H CALL 4735H ; Clear #files displayed, init TPDD and send 1st file dir referene opcode
3853H JNZ 390FH ; Process unformated disk (empty slots and error message)
3856H LDA FCD4H ; Current Page of files being displayed
3859H ANA A ; Test if displaying page 0
385AH JZ 3871H ; Jump if showing page 0 - don't need to skikp any pages
385DH STA FCDAH ; Initialize the number of pages left to skip count
3860H CALL 4742H ; Read next page of files from server
3863H LDA FCDAH ; Get the "Pages left to skip" count
3866H DCR A ; Decrement the remaining skip page count
3867H JNZ 385DH ; Keep reading pages until we have skipped enough pages
386AH XRA A ; Prepare to clear the remaining skip page count
386BH STA FCDAH ; Clear the remaining skip page count
386EH STA FCD6H ; Count of files on screen
3871H CALL 4742H ; Read next page of files from server
3874H LDA FCD6H ; Count of files on screen
3877H CPI 14H ; Test if all file slots are full
3879H CC 39AAH ; Print "-.-" for all empty file slots (if any)

; =========================================================================================
; Print NADSBox directory or TPDD Bank number to LCD
; =========================================================================================
387CH LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
387FH ANA A ; Test if server is TPDD
3880H JZ 389FH ; Skip processing Bank # or Current Dir if TPDD
3883H DCR A ; Test if server is TPDD2
3884H JZ 388DH ; Jump to print bank number if TPDD2
3887H LXI H,FCC0H ; Load pointer to NADSBox current directory storage
388AH JMP 38A5H ; Jump to print the NADSBox / Desklink directory

; =========================================================================================
; Print the TPDD Bank number to LCD
; =========================================================================================
388DH LXI H,2401H ; Go to Row 1, column 24
3890H SHLD F639H ; Cursor row (1-8)
3893H CALL 4C2FH ; Start inverse character mode
3896H MVI A,23H ; ASCII code for '#'
3898H RST 4 ; Send character in A to the LCD
3899H LDA FCCAH ; Load TPDD Bank number
389CH ADI 30H ; Convert to ASCII digit
389EH RST 4 ; Send it to the LCD
389FH CALL 4C33H ; Cancel inverse character mode
38A2H JMP 38B8H ; Branch to print the function menu, RAM/Disk free, etc.

; =========================================================================================
; Print the NADSBox / Desklink current directory in title bar
; =========================================================================================
38A5H PUSH H ; Save address of the directory string
38A6H LXI H,2101H ; Prepare to position the cursor in the title bar
38A9H SHLD F639H ; Cursor row (1-8)
38ACH CALL 4C2FH ; Start inverse character mode
38AFH POP H ; Retrieve the directory string from the stack
38B0H MVI C,06H ; Prepare to redraw 6 chars with inverse video
38B2H CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
38B5H CALL 4C33H ; Cancel inverse character mode

; =========================================================================================
; Print funtion menu, RAM/Disk free & selected file length
; =========================================================================================
38B8H LXI H,3E97H ; Point to Disk function menu
38BBH LXI B,3936H ; Routine to print free disk space
38BEH LDA FCD9H ; RAM/Disk mode
38C1H ANA A ; Test if in Disk mode and skip ahead to print Disk FKeys
38C2H JNZ 38CBH ; Skip ahead if in disk mode to keep vectors
38C5H LXI H,3ED9H ; Point to RAM function menu
38C8H LXI B,3922H ; Routine to print free RAM space
38CBH PUSH B ; Save routine address to stack
38CCH PUSH H ; Save pointer to function text to stack
38CDH LDA FCCDH ; Currently selected file index
38D0H LXI H,FCD6H ; Count of files on screen
38D3H CMP M ; Compare selected file with count of files on screen
38D4H JC 38DDH ; Branch if within bounds
38D7H MOV A,M ; Get the file count
38D8H ANA A ; Test if #files = 0
38D9H JNZ 38DDH ; Skip ahead if not zero
38DCH INR A ; Don't allow a count of zero - must be 1
38DDH STA FCD5H ; Currently selected file index - temp
38E0H LXI H,0B07H ; Row & column of start of text
38E3H SHLD F639H ; Cursor row (1-8)
38E6H POP H ; Get address of text from the stack and display it
38E7H CALL 4A2CH ; Send buffer at M to screen
38EAH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
38EDH ANA A ; Test if in RAM mode
38EEH JZ 3905H ; Jump if in RAM mode (0 = RAM)
38F1H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
38F4H ANA A ; Test if server is TPDD
38F5H JZ 3905H ; Skip printing of "Bank" or "Mkdr" if TPDD
38F8H LXI H,3FE9H ; Point to text for "Bank"
38FBH DCR A ; Test if server is TPDD2
38FCH JZ 3902H ; Jump to print "Bank" if TPDD2
38FFH LXI H,3FD8H ; Point to text for "Mkdr"
3902H CALL 4A2CH ; Send buffer at M to screen
3905H CALL 3940H ; Display DISK ON/OFF status on LCD
3908H LXI H,1507H ; Point to location for "Free" space (RAM or DISK)
390BH SHLD F639H ; Cursor row (1-8)
390EH RET

; =========================================================================================
; Handle unformatted disks. Print message and show empty slots.
; =========================================================================================
390FH XRA A ; Starting with slot zero...
3910H CALL 39AAH ; Print "-.-" for all empty file slots
3913H LXI H,3E97H ; Point to Disk Function menu string
3916H LXI B,391CH ; Print NOT FORMATTED to the display
3919H JMP 38CBH ; Go process the print and jump to error handler

; =========================================================================================
; Print "NOT FORMATTED" on the LCD and return
; =========================================================================================
391CH LXI H,`H ; Point to "NOT FORMATTED" string
391FH JMP 4A2CH ; Send buffer at M to screen

; =========================================================================================
; Print RAM free space at current posiiton
; =========================================================================================
3922H LHLD FBB2H ; Start of variable data pointer
3925H XCHG ; HL <--> DE
3926H LHLD F678H ; BASIC string buffer pointer
3929H MOV A,L ; Prepare for 16 bit subtract
392AH SUB E ; Subtract LSB
392BH MOV L,A ; Save LSB of difference for printing
392CH MOV A,H ; Prepare for subtrating MSB
392DH SBB D ; Subtract MSB
392EH MOV H,A ; Save in H for printing
392FH LXI B,FFF2H ; Load signed number -14
3932H DAD B ; Subtract 14 from free memory
3933H JMP 4C3EH ; Print binary number in HL at current position

; =========================================================================================
; Display free space on disk
; =========================================================================================
3936H CALL 4A10H ; Calculate free space on disk
3939H CALL 4C3EH ; Print binary number in HL at current position
393CH MVI A,30H ; Prepare to add an extra '0' since calc is /10
393EH RST 4 ; Send A to the LCD
393FH RET

; =========================================================================================
; Display DISK ON/OFF status on LCD
; =========================================================================================
3940H LDA FCD9H ; DISK/RAM mode (0=RAM, 1=DISK)
3943H ANA A ; Test if in RAM mode
3944H RNZ ; Return if not in RAM mode
3945H LDA FB2CH ; DISK-OFF/ON status
3948H LXI D,3FF2H ; Load pointer to "OFF" text
394BH CPI DBH ; Test if DISK mode (vector LSB) indicates ON or OFF
394DH JZ 3953H ; Branch if in DISK-OFF mode
3950H LXI D,3FF6H ; Load pointer to "ON" text
3953H LXI H,1908H ; Location of DISK-OFF/ON indication on LCD
3956H SHLD F639H ; Cursor row (1-8)
3959H XCHG ; HL = pointer to text in DE
395AH JMP 4A2CH ; Send buffer at M to screen

; =========================================================================================
; Display RAM files to LCD and calculate file lengths
; =========================================================================================
395DH LXI H,F9BAH ; Load pointer to 1st available file slot in catalog
3960H XRA A ; Set count of RAM files on screen to zero
3961H STA FCD6H ; Count of files on screen
3964H MVI A,14H ; Get max # files that will fit on LCD
3966H DCR A ; Decrement the max file count
3967H PUSH PSW ; Save count to the stack
3968H MOV A,M ; Get file type
3969H XRI 80H ; Compliment ?active bit
396BH ANI 9FH ; Test if file is active and should be displayed
396DH JNZ 3996H ; Branch to test next file if not displayed
3970H PUSH H ; Save address of current catalog file
3971H INX H ; Point to file address
3972H MOV E,M ; Get LSB of file address
3973H INX H ; Point to MSB of address
3974H MOV D,M ; Get MSB of file address
3975H XTHL ; HL <--> (SP) Get address of file within catalog
3976H PUSH H ; Push pointer to MSB of address on stack
3977H CALL 3CD3H ; Calculate length of RAM file
397AH XCHG ; HL <--> DE DE has the length
397BH CALL 4791H ; Store next file length to keyboard buffer
397EH POP H ; Get catalog address of current file from stack
397FH XTHL ; HL <--> (SP) swap catalog address with pointer to MSB of file address
3980H INX H ; Increment to filename
3981H MVI C,06H ; Prepare to print 6 characters of filename
3983H CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
3986H MVI A,2EH ; Load code for '.'
3988H RST 4 ; Send A to the LCD
3989H MVI C,02H ; Prepare to print 2 ext bytes to LCD
398BH CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
398EH MVI A,20H ; Load code for space
3990H RST 4 ; Send A to the LCD
3991H LXI H,FCD6H ; Count of files on screen
3994H INR M ; Increment number of files displayed on LCD
3995H POP H ; Get catalog address of file from stack
3996H LXI D,000BH ; Load offset to next file locaion in catalog
3999H DAD D ; Offset HL to next file
399AH POP PSW ; Restore the file count from the stack
399BH DCR A ; Decrement the max file count on the LCD
399CH JNZ 3967H ; Branch to test and display next file until zero
399FH LDA FCD6H ; Get the count of files actually displayed on screen
39A2H CPI 14H ; Test if max number of files displayed
39A4H CC 39AAH ; Branch to display "-.-" for remaining empty slots if not max
39A7H JMP 387CH ; Print NADSBox directory or TPDD Bank number to LCD

; =========================================================================================
; Print "-.-" for all empty file slots
; =========================================================================================
39AAH PUSH PSW ; Save current file index count on stack
39ABH LXI H,3FCDH ; Point to "-.-" text
39AEH CALL 4A2CH ; Send buffer at M to screen
39B1H POP PSW ; Restore current count
39B2H INR A ; Increment file index number
39B3H CPI 14H ; Compare A with max files that fit on LCD
39B5H JNZ 39AAH ; Jump to print next "-.-" if not done
39B8H RET

; =========================================================================================
; Handle "D" key from TS-DOS key scan
; =========================================================================================
39B9H CALL 3AA8H ; Test if printer busy. Return if not busy or error
39BCH CALL 4C52H ; LCOPY statement
39BFH JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle "L", "P" and "O" keys from TS-DOS key scan - list or print .DO file contents
; =========================================================================================
39C2H STA FCDFH ; Save key pressed
39C5H LXI D,0007H ; Load offset of Extension bytes
39C8H LHLD FCE4H ; LCD Buffer address of current file selection
39CBH DAD D ; Point to extension bytes in LCD buffer
39CCH MOV A,M ; Get 1st extension byte
39CDH CPI 44H ; Compare byte with "D"
39CFH JNZ 362FH ; Print length of selected file using inverse video if not "D"
39D2H INX H ; Point to 2nd extension byte
39D3H MOV A,M ; Load 2nd extension byte for comparison
39D4H CPI 4FH ; Compare with "0"
39D6H JNZ 3A06H ; Jump to print compressed file
39D9H CALL 3A49H ; Prepare file for reading (open disk file, address of RAM file)
39DCH LDA FCDFH ; Restore key pressed
39DFH CPI 4CH ; Test if key was "L" - List to LCD
39E1H CZ 4C27H ; CLS statement if LCD
39E4H CNZ 3AA8H ; Test if printer busy. Return if not busy or error
39E7H CALL 3A24H ; Get next block of data to display/print (HL=address)
39EAH PUSH PSW ; Push Z flag indicating if a full 128 bytes was read
39EBH CALL 3A6BH ; Display / print file data bytes at HL, A has length
39EEH POP PSW ; Get Z flag indicating if 128 bytes read
39EFH JZ 39E7H ; Jump to process more if 128 bytes were read last time
39F2H LDA FCDFH ; Restore key pressed
39F5H CPI 4CH ; Test if key was "L"
39F7H JNZ 3A00H ; Skip beep if printing
39FAH MVI A,07H ; Load code for BELL
39FCH RST 4 ; Go print a BELL (beep)
39FDH CALL 3DF8H ; Process power-off logic and wait for a key from keyboard

; =========================================================================================
; Clear screen and perform Long Jump
; =========================================================================================
3A00H CALL 4C27H ; CLS statement
3A03H JMP 48B5H ; Branch to "Long Jump" operation

; =========================================================================================
; Handler for the "O" key - print a compressed file??
; =========================================================================================
3A06H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A09H ANA A ; Test if in Disk mode
3A0AH JNZ 362FH ; Jump to keyscan if in Disk mode
3A0DH LHLD FCE4H ; LCD Buffer address of current file selection
3A10H CALL 4902H ; Copy filename at (HL) to current BASIC program
3A13H CALL 4A51H ; Get RAM directory address of current BASIC program
3A16H CPI C0H ; Test if filetype is .DO
3A18H CZ 5004H ; Call routine to Compress / Decompress .DO files
3A1BH CALL 4C0FH ; Update system pointers
3A1EH CALL 3611H ; Print Copyright and files
3A21H JMP 362FH ; Jump to keyscan

; =========================================================================================
; Get next 128 bytes (or less) of data from RAM or disk file for display
; =========================================================================================
3A24H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A27H ANA A ; Test if RAM mode
3A28H JNZ 40B6H ; If not RAM mode, go send TPDD_READ data opcode and recieve response
3A2BH LHLD FCDDH ; Get length of file to be displayed / printed
3A2EH LXI B,0080H ; Prepare to subtract 128 from length
3A31H MOV A,C ; Save 128 to A
3A32H DSUB ; Subtract 128 from file length
3A33H JNC 3A3AH ; Branch if length >= 128
3A36H DAD B ; Add 128 back to length to print "partial" buffer
3A37H MOV A,L ; Move remainder of bytes to display/print
3A38H MOV L,H ; Clear LSB of remainder
3A39H MOV C,A ; Move LSB of remainder to C
3A3AH SHLD FCDDH ; Save new remaining file length
3A3DH LHLD FCE0H ; Load the address to be printed / saved
3A40H PUSH H ; Save on stack
3A41H DAD B ; Update address to be used for display/printing next time
3A42H SHLD FCE0H ; Save address to be displayed / printed
3A45H POP H ; Retrieve address to be printed this loop from stack
3A46H CPI 80H ; Compare length with maximum
3A48H RET

; =========================================================================================
; Initialize Selected file for display (RAM or Disk)
; =========================================================================================
3A49H CALL 4A3BH ; Initialize blank filename and attribute byte
3A4CH LHLD FCE4H ; LCD Buffer address of current file selection
3A4FH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A52H ANA A ; Test if in RAM mode
3A53H JNZ 3A65H ; Branch to process Disk files if in Disk mode
3A56H CALL 4A4BH ; Get RAM directory address of selected file
3A59H PUSH D ; Push file address to stack
3A5AH CALL 3CD3H ; Calculate length of RAM file, HL=address of catalog entry, DE=file address
3A5DH SHLD FCDDH ; Save length to FDC emulation sector storage area
3A60H POP H ; Pop address of file into H
3A61H SHLD FCE0H ; Save file address
3A64H RET

; =====================================================================================
; Send TPDD Open command to open selected file
; =====================================================================================
3A65H CALL 3D95H ; Copy filename at (HL) to TX buffer
3A68H JMP 408AH ; Open TPDD file for Read Mode

; =====================================================================================
; Display / print file data bytes at HL, A has length
; =====================================================================================
3A6BH XCHG ; HL <--> DE
3A6CH ORA A ; Test if length = 0
3A6DH RZ ; Return if length = 0
3A6EH MOV C,A ; Save length count in C
3A6FH LDA FCDFH ; Load key press value
3A72H CPI 4CH ; Test if key was "L"
3A74H JNZ 3A82H ; Jump to print contents if not "L"
3A77H CALL 3A8FH ; Check for CTRL-C
3A7AH LDAX D ; Load next byte from src pointer
3A7BH RST 4 ; Send A to LCD
3A7CH INX D ; Increment the pointer
3A7DH DCR C ; Decrement the length count
3A7EH JNZ 3A77H ; Keep looping until all data displayed
3A81H RET

; =====================================================================================
; Print file data bytes at HL, A has length
; =====================================================================================
3A82H CALL 3A8FH ; Test for CTRL-C, etc.
3A85H LDAX D ; Load next file byte from source poiner
3A86H CALL 4C42H ; Print A to printer, expanding tabs if necessary
3A89H INX D ; Increment pointer
3A8AH DCR C ; Decrement length count
3A8BH JNZ 3A82H ; Keep looping until all data printed
3A8EH RET

; =========================================================================================
; Test for ESC, CTRL-C or Space
; =========================================================================================
3A8FH CALL 4C4AH ; Check keyboard queue for pending characters
3A92H RZ ; Return if no pending characters
3A93H CALL 4BEBH ; Wait for key from keyboard
3A96H CPI 03H ; Test for F4 maybe?
3A98H JZ 3A00H ; Clear screen and perform Long Jump if F4 maybe?
3A9BH CPI 1BH ; Test for ESC key
3A9DH JZ 3A00H ; Clear screen and perform Long Jump if ESC
3AA0H CPI 20H ; Test for space key
3AA2H JNZ 3A8FH ; Branch back to wait for ESC, CTRL-C or space if not space
3AA5H JMP 4BEBH ; Wait for key from keyboard

; =========================================================================================
; Test if printer busy. Return if not busy, print error if it is
; =========================================================================================
3AA8H IN BBH ; Get printer port input
3AAAH ANI 06H ; Mask all but BUSY and /BUSY
3AACH XRI 02H ; Compliment /BUSY
3AAEH JNZ 487BH ; Printer not ready / FF error
3AB1H RET

; =========================================================================================
; Print currently selected file using inverse video
; =========================================================================================
3AB2H CALL 3ACDH ; Calculate Row and Column of newly selected file
3AB5H SHLD FCE4H ; LCD Buffer address of current file selection
3AB8H CALL 4C2FH ; Start inverse character mode
3ABBH DCX H ; Start drawing from left edge of selection (include space)
3ABCH MVI C,0AH ; Draw 10 characters
3ABEH CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
3AC1H JMP 4C33H ; Cancel inverse character mode

; =========================================================================================
; Print selected file using normal video to "unselect" it
; =========================================================================================
3AC4H CALL 4C33H ; Cancel inverse character mode
3AC7H CALL 3ACDH ; Calculate row and column of newly selected file
3ACAH JMP 3ABBH ; Print the file to the LCD

; =========================================================================================
; Calculate Row and Column of soon-to-be (newly) selected file
; =========================================================================================
3ACDH LDA FCD5H ; Currently selected file index
3AD0H DCR A ; Make selected file zero based
3AD1H MOV L,A ; Save index to 16-bit HL
3AD2H MVI H,00H ; Make MSB zero
3AD4H LXI D,000AH ; Prepare to multiply index * 10 cols
3AD7H CALL 4C1FH ; Signed integer muliply (FAC1=HL*DE)
3ADAH LXI D,FE28H ; Load address of line 2 in the LCD buffer
3ADDH DAD D ; Calculate starting LCD buffer address for this file
3ADEH INX H ; Skip the "tag" space on the LCD
3ADFH PUSH H ; Save address on the stack
3AE0H LXI B,FE00H ; Load starting address of LCD character buffer
3AE3H DSUB ; Calculate file start offset from start of LCD buffer
3AE4H LXI D,0028H ; Load 1 LCD line width
3AE7H XCHG ; HL <--> DE Prepare for divide
3AE8H CALL 4C1BH ; Signed integer divide (FAC1=DE/HL)
3AEBH MOV A,L ; Save selected file's row number to A
3AECH INR A ; Make row 1-based
3AEDH STA F639H ; Cursor row (1-8)
3AF0H XCHG ; HL <--> DE DE had remainder*2 from divide
3AF1H ASHR ; Divide HL by 2
3AF2H MOV A,L ; Prepare to save remainder as the column
3AF3H STA F63AH ; Cursor column (1-40)
3AF6H POP H ; Restore address of LCD buffer location from stack
3AF7H RET

; =========================================================================================
; F3 Function key handler for RAM mode - Rename
; =========================================================================================
3AF8H CALL 4A4BH ; Get RAM directory address of selected file
3AFBH SHLD FCE0H ; Save address of file being processed
3AFEH LXI H,3F4AH ; Address of "New name" string
3B01H CALL 3E1AH ; Get 6-byte input filename from keyboard
3B04H RZ ; Return if no input provided
3B05H CALL 4902H ; Copy filename at (HL) to current BASIC program
3B08H LHLD FCE0H ; Load RAM directory address of file being renamed
3B0BH LXI B,0009H ; Load offset of extension within catalog entry
3B0EH DAD B ; Point to extension bytes
3B0FH LXI D,FC99H ; Load address of extension field of current BASIC program name
3B12H MOV A,M ; Get 1st byte of extension of catalog file being renamed
3B13H STAX D ; Save extension byte in current BASIC program filename - preserve EXT
3B14H INX D ; Point to 2nd ext byte of BASIC program name
3B15H INX H ; Point to 2nd ext byte of catalog filename
3B16H MOV A,M ; Get 2nd extension byte from catalog filename
3B17H STAX D ; Save byte in current BASIC program filename area
3B18H CALL 4A51H ; Get RAM directory address of current BASIC program
3B1BH JNZ 487EH ; If found, jump to File Exists Error
3B1EH LHLD FCE0H ; Load catalog address of file being renamed
3B21H INX H ; Point to LSB of file address
3B22H INX H ; Point to MSB of file address
3B23H INX H ; Point to name
3B24H LXI D,FC93H ; Load address of filename of current BASIC program
3B27H LXI B,0006H ; Prepare to copy 6 bytes of filename (ext doesn't change)
3B2AH XCHG ; HL <--> DE
3B2BH JMP 4A05H ; Move BC bytes from M to (DE) with increment

; =========================================================================================
; F1 Function key handler for DISK mode - Load
; =========================================================================================
3B2EH CALL 4A3BH ; Initialize blank filename and attribute byte
3B31H LHLD FCE4H ; LCD Buffer address of current file selection
3B34H CALL 3D95H ; Copy filename at (HL) to TX buffer
3B37H LDA FCCCH ; Last Tag/Untag operation code
3B3AH ANA A ; Test if a tag operation is pending
3B3BH JNZ 3B56H ; Branch if doing tag load operation
3B3EH LXI H,3F7AH ; Point to "Load as:" text
3B41H CALL 3E1AH ; Get 6-byte filename input from keyboard
3B44H JZ 3B56H ; Jump to use existing disk name as filename
3B47H CALL 4902H ; Copy filename at (HL) to current BASIC program
3B4AH LXI B,0002H ; Prepare to copy 2 extension bytes to current BASIC program space
3B4DH LXI H,FCEFH ; Point to disk file extension in TX buffer
3B50H LXI D,FC99H ; Point to current BASIC program extension address
3B53H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3B56H CALL 4A51H ; Get RAM directory address of current BASIC program
3B59H JZ 3B69H ; Branch to load if file doesn't already exist
3B5CH LXI H,3FB0H ; Point to "File Exists, Replace?" text
3B5FH CALL 48F4H ; Print string at HL to col 1 on the bottom line
3B62H CALL 3DEEH ; Get key from keyboard and test for 'Y' or 'y'
3B65H RNZ ; Return if isn't 'y' or 'Y'
3B66H CALL 3C38H ; Kill file in current BASIC program space
3B69H LHLD FD1DH ; Get file size from RX buffer
3B6CH MOV A,H ; Swap bytes (big endian in RX buffer)
3B6DH MOV H,L ; Move LSB to MSB
3B6EH MOV L,A ; Move MSB to LSB
3B6FH SHLD FD1DH ; Save with little endian to RX buffer
3B72H LDA FCEFH ; Get 1st byte of extension from TX buffer
3B75H CPI 44H ; Test if 1st extension byte is "D"
3B77H JNZ 3B82H ; Jump if not "D" to check for "C" or "B"
3B7AH LHLD FBAEH ; Get start of DO files pointer for location of new file
3B7DH MVI A,C0H ; Load file type code for .DO files
3B7FH JMP 3BA3H ; Process the file load

; =========================================================================================
; Test file exension type in A for .CO files
; =========================================================================================
3B82H CPI 43H ; Test if A contains "C"
3B84H JNZ 3B95H ; Branch if not .CO file
3B87H LHLD FBB0H ; Start of CO files pointer
3B8AH SHLD FCD5H ; Save in currently selected file index storage area
3B8DH LHLD FBB2H ; Get Start of variable data pointer as location for new file
3B90H MVI A,A0H ; Load file type code for .CO files
3B92H JMP 3BA3H ; Process the file load

; =========================================================================================
; Process load of .BA file
; =========================================================================================
3B95H LHLD FD1DH ; Get file size from RX buffer
3B98H SHLD FCD5H ; Save in Currently selected file index storage
3B9BH LHLD F99AH ; Get BASIC program not saved pointer
3B9EH SHLD FCE0H ; Save as address of file being processed
3BA1H MVI A,80H ; Load file type code for .BA files

; =========================================================================================
; Process file load operation
; =========================================================================================
3BA3H STA FCDFH ; Save file type code for later
3BA6H SHLD FCE2H ; Save address for new file
3BA9H LHLD FD1DH ; Get file size from RX buffer
3BACH SHLD FCDDH ; Save in FDC emulation physical/logical sector storage area
3BAFH PUSH H ; Save file size on stack
3BB0H POP B ; Copy file size to BC
3BB1H LDA FCDFH ; Get file type code
3BB4H CPI A0H ; Test for .CO file
3BB6H JZ 3BC0H ; Skip increment if .CO file (.BA has trailing 0x0000, .DO a 0x1A)
3BB9H INX B ; Increment file length for .BA and .DO files
3BBAH CPI 80H ; Test if file is .BA
3BBCH JNZ 3BC0H ; Skip additional increment if .BA
3BBFH INX B ; Add 1 more to length for .BA files to account for both trailing 0's
3BC0H PUSH B ; Save updated length on stack
3BC1H CALL 3E48H ; Find empty catalog entry
3BC4H JC 4887H ; Generate system error 0x0A ("DD") if full
3BC7H POP B ; Get length from stack
3BC8H PUSH H ; Save new file catalog address on stack
3BC9H PUSH B ; Save new file length on stack
3BCAH LHLD FCE2H ; Get address for new contents of new file
3BCDH CALL 4C0BH ; Insert BC spaces at M - make room
3BD0H JC 488AH ; Branch if error - RAM full error
3BD3H LHLD FCE2H ; Restore address of new file contents
3BD6H POP B ; Get file length from stack
3BD7H MVI M,00H ; Fill newly created file space with zero's
3BD9H INX H ; Increment pointer
3BDAH DCX B ; Decrement count
3BDBH MOV A,C ; Move LSB to A to check for zero - could use JNX here!
3BDCH ORA B ; Or in MSB to check for zero
3BDDH JNZ 3BD7H ; Keep looping until all are zero
3BE0H DCX H ; Decrement pointer to last byte in new file
3BE1H POP D ; Get File catalog address from stack
3BE2H LDA FCDFH ; Load file type code byte
3BE5H CPI C0H ; Test for .DO file
3BE7H JNZ 3BF3H ; Branch if not .DO file
3BEAH MVI M,1AH ; Terminate .DO file with EOF marker
3BECH LHLD FCE2H ; Reload address of new file contents
3BEFH DCX H ; Decrement pointer to jump into middle of loop
3BF0H JMP 3C1BH ; Write file entry to catalog

; =========================================================================================
; Process end-of-file / file length for .CO and .BA files
; =========================================================================================
3BF3H CPI A0H ; Test if new file is .CO
3BF5H JNZ 3C04H ; Branch if not .CO - must be .BA
3BF8H LHLD FCD5H ; Get old start of CO files pointer
3BFBH SHLD FBB0H ; Save as current start of CO files pointer
3BFEH LHLD FCE2H ; Reload address of new file contents
3C01H JMP 3C1BH ; Write file entry to catalog

; =========================================================================================
; Process end-of-file for .BA files
; =========================================================================================
3C04H PUSH D ; Push file catalog address to stack
3C05H LHLD FBAEH ; Get start of DO files pointer
3C08H DCX H ; Decrement address by 1
3C09H SHLD F99AH ; Save as new BASIC program not saved pointer
3C0CH INX H ; Increment back to start of .DO files
3C0DH XCHG ; HL <--> DE DE has start of DO files
3C0EH LHLD FCD5H ; Get BA file size
3C11H INX H ; Increment file size to account for trailing 0's
3C12H INX H ; Increment file size to account for trailing 0's
3C13H DAD D ; Add new length to start of DO files pointer
3C14H SHLD FBAEH ; Save new start of DO files pointer
3C17H POP D ; Retrieve file catalog address from stack
3C18H LHLD FCE0H ; Reload address of new file contents

; =========================================================================================
; Write file entry to catalog
; =========================================================================================
3C1BH XCHG ; HL <--> DE DE has file address, HL has catalog address
3C1CH CALL 4C17H ; Write new entry to catalog (A=type, DE=file address,HL=catalog address)
3C1FH CALL 4127H ; Open TPDD file and read data to file address being processed
3C22H CALL 4C0FH ; Update system pointers
3C25H LXI H,0002H ; Load TPDD_READ opcode in HL
3C28H JMP 409BH ; Send Request in HL and await response

; =========================================================================================
; F2 Function key handler for RAM mode - Kill
; =========================================================================================
3C2BH LDA FCCCH ; Get last Tag/Untag operation code
3C2EH ANA A ; Test if there is a pending tag operation
3C2FH CZ 3DE1H ; Display "Sure ?", validate and return if validated if no tag
3C32H LHLD FCE4H ; LCD Buffer address of current file selection
3C35H CALL 4902H ; Copy filename at (HL) to current BASIC program

; =========================================================================================
; Kill file in current BASIC program space
; =========================================================================================
3C38H CALL 4A51H ; Get RAM directory address of current BASIC program
3C3BH CPI C0H ; Test if file is .DO
3C3DH JZ 4BFFH ; Kill .DO file
3C40H CPI A0H ; Test if file is .CO
3C42H JZ 4C07H ; Kill .CO file
3C45H CPI 80H ; Test if file is .BA
3C47H JZ 4C03H ; Kill .BA file
3C4AH RET

; =========================================================================================
; F1 Function key handler for RAM mode - Save
; =========================================================================================
3C4BH CALL 4A3BH ; Initialize blank filename and attribute byte
3C4EH CALL 4A4BH ; Get RAM directory address of selected file
3C51H PUSH D ; Push file address to stack
3C52H PUSH H ; Push file catalog address to stack
3C53H INX H ; Point to LSB of file address
3C54H INX H ; Point to MSB of file address
3C55H INX H ; Point to filename in catalog
3C56H LXI D,FCE8H ; Point to TX buffer data area (payload)
3C59H LXI B,0006H ; Prepare to copy 6 filename bytes to TX packet data
3C5CH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C5FH MVI A,2EH ; Load code for '.'
3C61H STAX D ; Store '.' separator in TX packet data
3C62H INX D ; Increment TX packet data pointer
3C63H LXI B,0002H ; Prepare to copy 2 extention bytes from catalog
3C66H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C69H LDA FCCCH ; Last Tag/Untag operation code
3C6CH ANA A ; Test if a tag save operation is being performed
3C6DH JNZ 3C88H ; Jump ahead if doing a tag save - skip filename questioning
3C70H LXI H,3F71H ; Point to "Save as:" text
3C73H CALL 3E1AH ; Get 6-byte input filename from keyboard
3C76H JZ 3C88H ; Skip ahead to use catalog name if no input given
3C79H CALL 4902H ; Copy filename at (HL) to current BASIC program
3C7CH LXI B,0006H ; Prepare to copy 6 filename bytes from input string
3C7FH LXI D,FCE8H ; Point to filename area in TX buffer
3C82H LXI H,FC93H ; Filename of current BASIC program
3C85H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C88H POP H ; Restore file catalog address from stack
3C89H POP D ; Restore file address from stack
3C8AH PUSH D ; Save file address on stack
3C8BH CALL 3CD3H ; Calculate length of RAM file, HL=address of catalog entry, DE=file address
3C8EH MOV A,H ; Test for zero length file - move H to A
3C8FH ORA L ; OR LSB to test for zero
3C90H JZ 4884H ; Branch if empty - File Empty Error
3C93H PUSH H ; Save file address to stack
3C94H MVI A,01H ; Set file open mode to new file
3C96H STA FCD6H ; Save open mode to pass to open routine
3C99H CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3C9CH CALL 4A72H ; Send Dir Reference opcode
3C9FH JZ 3CCEH ; Jump to write data if file doesn't exist (size = 0)
3CA2H LXI H,3F8BH ; Point to "File Exists, A)ppend R)eplace Q)uit" text
3CA5H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3CA8H CALL 3DF8H ; Process power-off logic and wait for a key from keyboard
3CABH ANI DFH ; Make key uppercase
3CADH RST 4 ; Display key on LCD
3CAEH CPI 52H ; Test if key is 'R'
3CB0H JNZ 3CBCH ; Jump if not 'R'eplace
3CB3H CALL 431AH ; Issue TPDD Delete file Opcode
3CB6H CALL 4A72H ; Send Dir Reference opcode
3CB9H JMP 3CCEH ; Go write data to the file

; =========================================================================================
; F1-Save: Test for 'A'ppend
; =========================================================================================
3CBCH POP H ; Get file length from stack
3CBDH POP D ; Get file address from stack
3CBEH CPI 41H ; Test if response is 'A'ppend
3CC0H RNZ ; Return if not 'A'
3CC1H LDA FCEFH ; Load 1st byte of extension from TX buffer
3CC4H CPI 44H ; Test if file is "D"O file
3CC6H RNZ ; Don't allow appending non DO files
3CC7H MVI A,02H ; Set open mode to open existing (append)
3CC9H STA FCD6H ; Save mode to pass to open routine
3CCCH PUSH D ; Save file address on stack
3CCDH PUSH H ; Save file length on stack

; =========================================================================================
; Save function - Replace or new file, write data to file
; =========================================================================================
3CCEH POP H ; Retrieve file length from stack
3CCFH POP D ; Retrieve file address from stack
3CD0H JMP 40C8H ; Write HL bytes of data from (DE) to TPDD

; =========================================================================================
; Calculate length of RAM file, HL=address of catalog entry, DE=file address
; =========================================================================================
3CD3H MOV A,M ; Get RAM file type from catalog
3CD4H CPI C0H ; Test for .DO file
3CD6H JZ 3CE6H ; Jump to calculate length if .DO file
3CD9H CPI A0H ; Test for .CO file
3CDBH JZ 3CF5H ; Jump to calculate length if .CO file
3CDEH PUSH D ; Save address of start of BASIC program to stack
3CDFH CALL 4C13H ; Call ROM routine to find BASIC end of program
3CE2H POP B ; Get BASIC program start address from stack
3CE3H DSUB ; Subtract starting address from end address
3CE4H DCX H ; Don't count trailing 0x00 as part of BASIC program length
3CE5H RET

; =========================================================================================
; Calculate length of .DO file, HL=Catalog address, DE=file address
; =========================================================================================
3CE6H XCHG ; HL <--> DE Get file address in HL
3CE7H LXI D,0000H ; Clear file length
3CEAH MOV A,M ; Get next byte from .DO file
3CEBH INX H ; Increment pointer
3CECH INX D ; Increment length
3CEDH CPI 1AH ; Test for EOF marker
3CEFH JNZ 3CEAH ; Branch to next byte if not EOF
3CF2H DCX D ; Subtract EOF marker from file length
3CF3H XCHG ; HL <--> DE HL=length
3CF4H RET

; =========================================================================================
; Calculate length of .CO file, HL=Catalog address, DE=file address
; =========================================================================================
3CF5H XCHG ; HL <--> DE Get file address in HL
3CF6H INX H ; Increment past .CO load address
3CF7H INX H ; Increment past MSB of load address
3CF8H MOV C,M ; Get LSB of length
3CF9H INX H ; Increment to MSB of length
3CFAH MOV B,M ; Get MSB of length
3CFBH LXI H,0006H ; Prepare to add 6-byte header to length
3CFEH DAD B ; Add 6-byte header to length
3CFFH RET

; =========================================================================================
; F7 Function key handler for DISK mode - Mkdir
; =========================================================================================
3D00H LDA FCCBH ; NADSBox / TPDD2 / Desklink flag
3D03H ANA A ; Test if server is TPDD
3D04H RZ ; Return if not NADSBox or TPDD2
3D05H DCR A ; Test if TPDD2
3D06H JZ 37BAH ; Go Swap TPDD Bank Number if TPDD2
3D09H CALL 4A3BH ; Must be NADSBOx Initialize blank filename
3D0CH LXI H,3F61H ; Load pointer to "Directory name:" text
3D0FH CALL 3E1AH ; Get 6-byte input filename from keyboard
3D12H RZ ; Return if no input given
3D13H CALL 4902H ; Copy filename at (HL) to current BASIC program
3D16H LXI H,FC93H ; Filename of current BASIC program
3D19H LXI D,FCE8H ; Point to TX buffer data area (payload)
3D1CH LXI B,0006H ; Prepare to copy 6 filename bytes to TX buffer
3D1FH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3D22H LXI H,3E3CH ; Load code for "<>"
3D25H SHLD FCEFH ; Save "<>" extension bytes in TX buffer - NADSBox Mkdir
3D28H MVI A,2EH ; Load code for '.' extension separator
3D2AH STA FCEEH ; Save "." to TX buffer
3D2DH CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D30H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
3D33H CPI 02H ; Test if we have NADSBox current directory
3D35H RNZ ; Return if we don't have current directory
3D36H CALL 4A72H ; Send Directory Reference opcode
3D39H JNZ 3D4DH ; If the file exists, branch to open it for READ mode
3D3CH MVI A,01H ; Load OPEN_WRITE mode into A to create the directory
3D3EH STA FCE8H ; Save A in TX data storage mode field
3D41H LXI H,0101H ; Load opcode to open a file
3D44H CALL 409BH ; Send Request in HL and await response
3D47H LXI H,0002H ; Load opcode to close the file
3D4AH JMP 409BH ; Send Request in HL and await response

; =========================================================================================
; Open and close a directory file (from above)
; =========================================================================================
3D4DH CALL 408AH ; Open TPDD file for Read Mode
3D50H JMP 3D47H ; Branch to close the directory open request

; =========================================================================================
; F5 Function key handler for DISK mode - Format
; =========================================================================================
3D53H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
3D56H CPI 02H ; Test if we have "current directory" name
3D58H RZ ; Return if server is NADSBox / Desklink - No format supported
3D59H LXI H,3F1BH ; Load pointer to "Insert Disk" string
3D5CH CALL 48F4H ; Print string at HL to col 1 on the bottom line
3D5FH CALL 3DEEH ; Get key from keyboard and test for 'Y' or 'y'
3D62H RNZ ; Return if response not 'Y'
3D63H CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D66H CALL 49E3H ; Delay routine - about 3ms
3D69H LXI H,0006H ; Load TPDD_FORMAT opcode in HL
3D6CH CALL 409BH ; Send Request in HL and await response
3D6FH MVI A,07H ; Load code for BELL
3D72H RET ; Go beep to indicate format

; =========================================================================================
; F2 Function key handler for DISK mode - Kill
; =========================================================================================
3D73H LDA FCCCH ; Last Tag/Untag operation code
3D76H ANA A ; Test if there's an active tag group
3D77H CZ 3DE1H ; Display "Sure ?", validate and return if validated if no tag
3D7AH CALL 4A3BH ; Initialize blank filename and attribute byte
3D7DH CALL 3D83H ; Copy selected filename to TX buffer and init TPDD/NADSBox
3D80H JMP 431AH ; Issue TPDD Delete file Opcode

; =========================================================================================
; Copy selected filename to TX buffer and init TPDD/NADSBox
; =========================================================================================
3D83H LXI B,0009H ; Prepare to copy 9 filename bytes
3D86H LHLD FCE4H ; LCD Buffer address of current file selection
3D89H LXI D,FCE8H ; Address of TX packet data
3D8CH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3D8FH CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D92H JMP 4A72H ; Send Dir Reference opcode

; =========================================================================================
; Copy filename at (HL) to TX buffer
; =========================================================================================
3D95H CALL 4902H ; Copy filename at (HL) to current BASIC program
3D98H LXI H,FC93H ; Filename of current BASIC program
3D9BH CALL 4A57H ; Send Dir Reference for filename at (HL)
3D9EH RET

; =========================================================================================
; F3 Function key handler for DISK mode - Name
; =========================================================================================
3D9FH CALL 4A3BH ; Initialize blank filename and attribute byte
3DA2H CALL 3D83H ; Copy selected filename to TX buffer and init TPDD/NADSBox
3DA5H LXI H,FCE8H ; Point to TX buffer data area (payload)
3DA8H LXI D,FC9CH ; Filename of last program loaded from tape
3DABH LXI B,0009H ; Prepare to copy 9 bytes to "last program loaded" filename
3DAEH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3DB1H LHLD FD1DH ; Get file size from RX buffer
3DB4H MOV C,H ; Save file size MSB to C (swap endian)
3DB5H MOV B,L ; Save file size LSB to B (swap endian)
3DB6H LXI H,7CC0H ; ? Load HL with 31936
3DB9H DSUB ; ? Compare file length with 31936
3DBAH LXI H,3F4AH ; Address of "New name" string
3DBDH JNZ 3DD7H ; Branch to change filename if not 30656
3DC0H LXI B,0009H ; Allow a 9-byte filename input string
3DC3H CALL 3E1DH ; Get max BC length input for filename and convert to uppercase
3DC6H RZ ; Return if no input provided
3DC7H PUSH H ; Save pointer to input string to stack
3DC8H PUSH PSW ; Save string length to stack
3DC9H CALL 4A3BH ; Initialize blank filename and attribute byte
3DCCH POP PSW ; Get string length from stack
3DCDH POP H ; Get string address from stack
3DCEH LXI D,FCE8H ; Point to TX buffer data area (payload)
3DD1H MOV C,A ; Copy length to BC
3DD2H MVI B,00H ; Make MSB of length = 0
3DD4H JMP 41B0H ; Rename the TPDD file whose name is in (HL)

; =========================================================================================
; Get filename from keyboard and rename Disk file, filename in "current BASIC program"
; =========================================================================================
3DD7H CALL 3E1AH ; Get 6-byte input filename from keyboard
3DDAH RZ ; Return if no input provided
3DDBH CALL 4902H ; Copy filename at (HL) to current BASIC program
3DDEH JMP 41A7H ; Rename the TPDD file whose name is in "current BASIC program"

; =========================================================================================
; Display "Sure ?", validate and return if validated
; =========================================================================================
3DE1H LXI H,3F83H ; Load pointer to "Sure ?" string
3DE4H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3DE7H CALL 3DEEH ; Get key and test for 'Y' or 'y'
3DEAH JNZ 48B5H ; Branch to "Long jump" operation to abort if not 'y'
3DEDH RET

; =========================================================================================
; Get key from keyboard and test for 'Y' or 'y'
; =========================================================================================
3DEEH CALL 3DF8H ; Process power-off logic and wait for a key from keyboard
3DF1H RST 4 ; Display the key on the LCD
3DF2H CPI 59H ; Test if key pressed was 'Y'
3DF4H RZ ; Return if key pressed was 'Y'
3DF5H CPI 79H ; Test if key pressed was 'y'
3DF7H RET

; =========================================================================================
; Process power-off logic and wait for a key from keyboard
; =========================================================================================
3DF8H CALL 3DFEH ; Process automatic poweroff logic
3DFBH JMP 4BEBH ; Wait for key from keyboard

; =========================================================================================
; Process automatic power-off logic during key scan loop
; =========================================================================================
3DFEH XRA A ; Clear A
3DFFH DCR A ; Set A to 0xFF
3E00H STA F656H ; Power off exit condition switch
3E03H CALL 4C4AH ; Check keyboard queue for pending characters
3E06H JZ 3DFEH ; Branch back if no keyboard characters in queue - wait for key
3E09H XRA A ; Clear A
3E0AH STA F656H ; Power off exit condition switch
3E0DH LXI H,F932H ; Load address of "Renew Automatic Poweroff Counter Flag"
3E10H ORA M ; Test if auto poweroff counter should be renewed
3E11H JZ 4BF7H ; Renew automatic power-off counter if enabled
3E14H CALL 4BF3H ; Turn off the computer
3E17H JMP 3DFEH ; Branch back to continue processing power off logic

; =========================================================================================
; Get max 6-byte input for filename and convert to uppercase
; =========================================================================================
3E1AH LXI B,0006H ; Get maximum 6 characters of input

; =========================================================================================
; Get max BC length input for filename and convert to uppercase
; =========================================================================================
3E1DH CALL 3E2FH ; Get max BC length input string from keyboard
3E20H RZ ; Return if no input provided
3E21H PUSH H ; Preserve pointer to input string
3E22H PUSH PSW ; Preserve flags from input
3E23H CALL 4C5EH ; Get char at M and convert to uppercase
3E26H MOV M,A ; Save uppercase char back to string
3E27H INX H ; Point to next byte in input
3E28H ANA A ; Test for NULL - end of string
3E29H JNZ 3E23H ; Keep looping until end of string
3E2CH POP PSW ; Restore flags from input routine
3E2DH POP H ; Restore pointer to input string
3E2EH RET

; =========================================================================================
; Get maximum BC length input character string from keyboard
; =========================================================================================
3E2FH PUSH B ; Save maximum input length to stack
3E30H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3E33H CALL 4C46H ; Input and display (no "?") line and store
3E36H JC 48B5H ; Branch to "Long jump" if CTRL-C
3E39H INX H ; Point to start of input string
3E3AH MOV A,B ; Get string length (counting NULL)
3E3BH DCR A ; Remove NULL from count
3E3CH POP D ; Restore maximum input length
3E3DH RZ ; Return if string length is zero
3E3EH CMP E ; Compare expected length with actual length
3E3FH RC ; Return if string is shorter than expected
3E40H PUSH H ; Save pointer to start of string on stack
3E41H DAD D ; Add Expected length to pointer
3E42H MVI M,00H ; Truncate the string to the max length
3E44H POP H ; Restore pointer to input string
3E45H MOV A,E ; Update length to reflect maximum
3E46H ORA A ; Clear zero flag to indicate input provided
3E47H RET

; =========================================================================================
; Find Empty catalog entry (only 9 instructions...Don't bother with Main ROM)
; =========================================================================================
3E48H LXI H,F9AFH ; Point to the "RickY" catalog entry (start of valid entries)
3E4BH LXI B,000BH ; Load length of each catalog entry
3E4EH DAD B ; Point to next catalog entry to test if empty
3E4FH MOV A,M ; Get file attribute byte from catalog entry
3E50H CPI FFH ; Test if at end of catalog
3E52H JZ 3E5AH ; Jump to report directory full if at end
3E55H ADD A ; Test if MSB is set (entry being used)
3E56H JC 3E4EH ; Jump to test next enry if MSB set
3E59H RET ; Entry found...return with Carry clear

; =========================================================================================
; Empty catalog entry not found...set Carry and exit
; =========================================================================================
3E5AH STC ; Indicate empty entry not found
3E5BH RET

; =========================================================================================
; F5 Function key handler for RAM mode - DOS ON/OF
; =========================================================================================
3E5CH LHLD FB2CH ; Get LFILES statement hook address
3E5FH LXI B,08DBH ; Load address of default (DOS-OFF) hook for LFILES
3E62H DSUB ; Test if in DOS-OFF mode
3E63H JZ 401FH ; Jump to add our custom RST 7 hooks if in DOS-OFF mode
3E66H JMP 3FFAH ; Must be in DOS-ON mode, jump to turn it off

; =========================================================================================
; Strings
; =========================================================================================
3E69H DB 0x1B, "p TS-DOS (100 v4.00) (c)87,TSI. ",0x1B,'q',0x00
3E97H DB "DISK Free: File:",0DH,0AH,"Load Kill Name Ram Frmt Log Menu",00H
3ED9H DB " RAM Free: File:",0DH,0AH,"Save Kill Name Disk DOS- Menu",00H
3F1BH DB "Insert Disk, Press \"Y\" to begin ",00H
3F3CH DB "NOT FORMATTED",00H
3F4AH DB "New Name:",00H
3F54H DB "System name:",00H
3F61H DB "Directory name:",00H
3F71H DB "Save as:",00H
3F7AH DB "Load as:",00H
3F83H DB "Sure ? ",00H
3F8BH DB "File exists, A)ppend R)eplace Q)uit:",00H
3FB0H DB "File exists, Replace? (Y/N):",00H
3FCDH DB "-.- ",00H
3FD8H DB 0x1B,"Y74 ",1BH,"Y7>MkDr",00H ; TODO: Check this
3FE9H DB 0x1B,"Y7>Bank",00H ; TODO: Check this
3FF2H DB "OFF",00H
3FF6H DB "ON ",00H
</pre>

Navigate to:
* [[Dissasembly of RAM and ROM versions of TS-DOS]]
* [[M100 TS-DOS ROM OptROM Support]]
* [[M100 TS-DOS ROM RST 7 Handlers]]
* [[M100 TS-DOS ROM TPDD Protocol]]
* [[M100 TS-DOS ROM Compression]]
* [[M100 TS-DOS ROM Cold Boot Recovery]]

M100 TS-DOS ROM Cold Boot Recovery

2009-04-03T08:16:34Z

Kpettit: New page: == TS-DOS Model 100/102 ROM Cold Start Recovery Routines This source, as you can see, has not been commented yet. <pre> ; ================================================================...

== TS-DOS Model 100/102 ROM Cold Start Recovery Routines

This source, as you can see, has not been commented yet.

<pre>
; =========================================================================================
; Cold Start File Recovery routine
; =========================================================================================
7000H (21H) LXI H,7065H
7003H (11H) LXI D,FC93H ; Filename of current BASIC program
7006H (01H) LXI B,0008H
7009H (CDH) CALL 705AH
700CH (2AH) LHLD FBAEH ; Start of DO files pointer
700FH (44H) MOV B,H
7010H (4DH) MOV C,L
7011H (21H) LXI H,E5F0H
7014H (08H) DSUB
7015H (50H) MOV D,B
7016H (59H) MOV E,C
7017H (EBH) XCHG
7018H (D5H) PUSH D
7019H (7EH) MOV A,M
701AH (FEH) CPI 0AH
701CH (CAH) JZ 7030H
701FH (FEH) CPI 0DH
7021H (CAH) JZ 7030H
7024H (FEH) CPI 7FH
7026H (D2H) JNC 702EH
7029H (FEH) CPI 20H
702BH (D2H) JNC 7030H
702EH (3EH) MVI A,20H
7030H (77H) MOV M,A
7031H (23H) INX H
7032H (1BH) DCX D
7033H (7AH) MOV A,D
7034H (B3H) ORA E
7035H (C2H) JNZ 7019H
7038H (C1H) POP B
7039H (E5H) PUSH H
703AH (2AH) LHLD FBAEH ; Start of DO files pointer
703DH (CDH) CALL 7081H
7040H (E1H) POP H
7041H (36H) MVI M,1AH
7043H (2BH) DCX H
7044H (36H) MVI M,1AH
7046H (CDH) CALL 706DH
7049H (EBH) XCHG
704AH (2AH) LHLD FBAEH ; Start of DO files pointer
704DH (2BH) DCX H
704EH (EBH) XCHG
704FH (3EH) MVI A,C0H
7051H (CDH) CALL 7089H
7054H (CDH) CALL 7085H
7057H (C3H) JMP 708DH

705AH (7EH) MOV A,M
705BH (12H) STAX D
705CH (23H) INX H
705DH (13H) INX D
705EH (0BH) DCX B
705FH (78H) MOV A,B
7060H (B1H) ORA C
7061H (C2H) JNZ 705AH
7064H (C9H) RET

7065H (52H) MOV D,D
7066H (45H) MOV B,L
7067H (43H) MOV B,E
7068H (4FH) MOV C,A
7069H (56H) MOV D,M
706AH (52H) MOV D,D
706BH (44H) MOV B,H
706CH (4FH) MOV C,A
706DH (21H) LXI H,F9AFH
7070H (01H) LXI B,000BH
7073H (09H) DAD B
7074H (7EH) MOV A,M
7075H (FEH) CPI FFH
7077H (CAH) JZ 707FH
707AH (87H) ADD A
707BH (DAH) JC 7073H
707EH (C9H) RET

707FH (37H) STC
7080H (C9H) RET

7081H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
7082H DW 6B6DH
7084H (C9H) RET

7085H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
7086H DW 2146H
7088H (C9H) RET

7089H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
708AH DW 2239H)
708CH (C9H) RET

708BH (CFH) RST 1 ; Call main ROM at address in following 2 bytes
708EH DW 0000H
7090H (C9H) RET
</pre>

Navigate to:
* [[Dissasembly of RAM and ROM versions of TS-DOS]]
* [[M100 TS-DOS ROM OptROM Support]]
* [[M100 TS-DOS ROM UI Code]]
* [[M100 TS-DOS ROM RST 7 Handlers]]
* [[M100 TS-DOS ROM TPDD Protocol]]
* [[M100 TS-DOS ROM Compression]]

M100 TS-DOS ROM Compression

2009-04-03T08:14:17Z

Kpettit: New page: == TS-DOS Model 100/102 ROM Compression Routines == This code, as you can see, has not been disassembled yet. <pre> ; ====================================================================...

== TS-DOS Model 100/102 ROM Compression Routines ==

This code, as you can see, has not been disassembled yet.

<pre>
; =========================================================================================
; Compress / Decompress a file a .DO file
; =========================================================================================
5000H CALL 5008H
5003H RET

5004H CALL 500FH
5007H RET

5008H XRA A
5009H STA F69EH
500CH JMP 5018H

; =========================================================================================
; Perform compression / decompression
; =========================================================================================
500FH (3EH) MVI A,0CH
5011H (32H) STA F69EH
5014H (E7H) RST 4 ; Send character in A to screen/printer
5015H (CDH) CALL 5347H
5018H (22H) SHLD F69BH
501BH (21H) LXI H,534BH
501EH (11H) LXI D,F685H ; Keyboard buffer
5021H (01H) LXI B,0015H
5024H (CDH) CALL 5318H
5027H (3EH) MVI A,50H
5029H (32H) STA F69DH
502CH (AFH) XRA A
502DH (32H) STA F69FH
5030H (CDH) CALL 533BH
5033H (2AH) LHLD F69BH
5036H (CDH) CALL 5333H
5039H (EBH) XCHG
503AH (D5H) PUSH D
503BH (CDH) CALL 52ABH
503EH (00H) NOP
503FH (2EH) MVI L,7EH
5041H (C2H) JNZ 5046H
5044H (2EH) MVI L,80H
5046H (01H) LXI B,0000H
5049H (1AH) LDAX D
504AH (BDH) CMP L
504BH (DAH) JC 504FH
504EH (03H) INX B
504FH (13H) INX D
5050H (FEH) CPI 1AH
5052H (C2H) JNZ 5049H
5055H (E1H) POP H
5056H (3AH) LDA F69EH
5059H (D6H) SUI 0CH
505BH (C2H) JNZ 5060H ; Generate IE error
505EH (47H) MOV B,A
505FH (4FH) MOV C,A
5060H (CDH) CALL 533FH
5063H (D8H) RC
5064H (2BH) DCX H
5065H (E5H) PUSH H
5066H (CDH) CALL 52A5H
5069H (C2H) JNZ 5098H
506CH (CDH) CALL 52ABH
506FH (DCH) CC 5307H
5072H (C3H) JMP 521AH

5075H (CDH) CALL 5323H
5078H (DAH) JC 5075H
507BH (CDH) CALL 5337H
507EH (C9H) RET

507FH (4FH) MOV C,A
5080H (FEH) CPI 3AH
5082H (D0H) RNC
5083H (FEH) CPI 20H
5085H (37H) STC
5086H (C8H) RZ
5087H (FEH) CPI 2FH
5089H (C8H) RZ
508AH (3FH) CMC
508BH (C9H) RET

508CH (D6H) SUI 2FH
508EH (D0H) RNC
508FH (3EH) MVI A,0BH
5091H (C9H) RET

5092H (FEH) CPI 3AH
5094H (C0H) RNZ
5095H (3EH) MVI A,20H
5097H (C9H) RET

5098H (D5H) PUSH D
5099H (00H) NOP
509AH (00H) NOP
509BH (01H) LXI B,0000H
509EH (C5H) PUSH B
509FH (E1H) POP H
50A0H (03H) INX B
50A1H (13H) INX D
50A2H (1AH) LDAX D
50A3H (FEH) CPI 5BH
50A5H (D2H) JNC 50A0H
50A8H (FEH) CPI 1AH
50AAH (CAH) JZ 50B7H
50ADH (FEH) CPI 41H
50AFH (DAH) JC 50A1H
50B2H (00H) NOP
50B3H (23H) INX H
50B4H (C3H) JMP 50A1H

50B7H (C5H) PUSH B
50B8H (D1H) POP D
50B9H (DFH) RST 3 ; Compare DE and HL
50BAH (D1H) POP D
50BBH (DAH) JC 50C6H
50BEH (CDH) CALL 5307H
50C1H (3EH) MVI A,43H
50C3H (32H) STA F69DH
50C6H (AFH) XRA A
50C7H (32H) STA F69FH
50CAH (CDH) CALL 520AH
50CDH (CDH) CALL 518AH
50D0H (D2H) JNC 515EH
50D3H (CDH) CALL 507FH
50D6H (00H) NOP
50D7H (D2H) JNC 5117H
50DAH (13H) INX D
50DBH (1AH) LDAX D
50DCH (CDH) CALL 5080H
50DFH (1BH) DCX D
50E0H (47H) MOV B,A
50E1H (79H) MOV A,C
50E2H (D2H) JNC 5117H
50E5H (C2H) JNZ 50EEH
50E8H (B8H) CMP B
50E9H (CAH) JZ 5136H
50ECH (00H) NOP
50EDH (00H) NOP
50EEH (13H) INX D
50EFH (21H) LXI H,F69FH
50F2H (00H) NOP
50F3H (7EH) MOV A,M
50F4H (B7H) ORA A
50F5H (C2H) JNZ 50FFH
50F8H (3EH) MVI A,7EH
50FAH (77H) MOV M,A
50FBH (E1H) POP H
50FCH (77H) MOV M,A
50FDH (23H) INX H
50FEH (E5H) PUSH H
50FFH (79H) MOV A,C
5100H (CDH) CALL 508CH
5103H (00H) NOP
5104H (4FH) MOV C,A
5105H (78H) MOV A,B
5106H (CDH) CALL 508CH
5109H (C6H) ADI 0BH
510BH (0DH) DCR C
510CH (C2H) JNZ 5109H
510FH (C6H) ADI 7AH
5111H (E1H) POP H
5112H (77H) MOV M,A
5113H (E5H) PUSH H
5114H (C3H) JMP 50CAH

5117H (E1H) POP H
5118H (FEH) CPI 0DH
511AH (C2H) JNZ 512AH
511DH (13H) INX D
511EH (1AH) LDAX D
511FH (FEH) CPI 0AH
5121H (1BH) DCX D
5122H (3EH) MVI A,0DH
5124H (C2H) JNZ 512AH
5127H (13H) INX D
5128H (3EH) MVI A,80H
512AH (77H) MOV M,A
512BH (E5H) PUSH H
512CH (3AH) LDA F69FH
512FH (B7H) ORA A
5130H (C2H) JNZ 50C6H
5133H (00H) NOP
5134H (00H) NOP
5135H (7EH) MOV A,M
5136H (21H) LXI H,F684H
5139H (06H) MVI B,07H
513BH (05H) DCR B
513CH (CAH) JZ 50CAH
513FH (23H) INX H
5140H (BEH) CMP M
5141H (C2H) JNZ 513BH
5144H (0EH) MVI C,15H
5146H (CDH) CALL 518AH
5149H (D2H) JNC 515EH
514CH (21H) LXI H,F685H ; Keyboard buffer
514FH (BEH) CMP M
5150H (CAH) JZ 517BH
5153H (0DH) DCR C
5154H (CCH) CZ 520AH
5157H (CAH) JZ 5184H
515AH (23H) INX H
515BH (C3H) JMP 514FH

515EH (32H) STA F69AH
5161H (AFH) XRA A
5162H (32H) STA F69FH
5165H (78H) MOV A,B
5166H (FEH) CPI 07H
5168H (D2H) JNC 516EH
516BH (CDH) CALL 520AH
516EH (E1H) POP H
516FH (36H) MVI M,FFH
5171H (E5H) PUSH H
5172H (3AH) LDA F69AH
5175H (CDH) CALL 5195H
5178H (C3H) JMP 50CAH

517BH (79H) MOV A,C
517CH (C6H) ADI 15H
517EH (05H) DCR B
517FH (C2H) JNZ 517CH
5182H (C6H) ADI 6BH
5184H (E1H) POP H
5185H (77H) MOV M,A
5186H (E5H) PUSH H
5187H (C3H) JMP 50CAH

518AH (13H) INX D
518BH (1AH) LDAX D
518CH (FEH) CPI 1AH
518EH (CAH) JZ 52BAH
5191H (FEH) CPI 7EH
5193H (C9H) RET

5194H (7EH) MOV A,M
5195H (4FH) MOV C,A
5196H (3AH) LDA F69EH
5199H (B7H) ORA A
519AH (79H) MOV A,C
519BH (C1H) POP B
519CH (E1H) POP H
519DH (23H) INX H
519EH (C2H) JNZ 51A2H
51A1H (77H) MOV M,A
51A2H (E5H) PUSH H
51A3H (C5H) PUSH B
51A4H (C8H) RZ
51A5H (E7H) RST 4 ; Send character in A to screen/printer
51A6H (D5H) PUSH D
51A7H (6FH) MOV L,A
51A8H (3AH) LDA F63AH ; Cursor column (1-40)
51ABH (2FH) CMA
51ACH (C6H) ADI 2CH
51AEH (67H) MOV H,A
51AFH (7DH) MOV A,L
51B0H (CDH) CALL 51D7H
51B3H (00H) NOP
51B4H (00H) NOP
51B5H (3FH) CMC
51B6H (CAH) JZ 51C4H
51B9H (D2H) JNC 51C7H ; Print current STAT settings
51BCH (13H) INX D
51BDH (1AH) LDAX D
51BEH (CDH) CALL 51D7H
51C1H (C3H) JMP 51B6H

51C4H (CDH) CALL 532FH
51C7H (CDH) CALL 5075H
51CAH (00H) NOP
51CBH (D1H) POP D
51CCH (C8H) RZ
51CDH (FEH) CPI 20H
51CFH (DAH) JC 52BAH
51D2H (CCH) CZ 5327H
51D5H (00H) NOP
51D6H (C9H) RET

51D7H (25H) DCR H
51D8H (C8H) RZ
51D9H (FEH) CPI 21H
51DBH (3FH) CMC
51DCH (D0H) RNC
51DDH (FEH) CPI FEH
51DFH (3DH) DCR A
51E0H (D0H) RNC
51E1H (D6H) SUI 7FH
51E3H (CAH) JZ 5200H
51E6H (D8H) RC
51E7H (25H) DCR H
51E8H (00H) NOP
51E9H (C8H) RZ
51EAH (F5H) PUSH PSW
51EBH (3AH) LDA F69FH
51EEH (B7H) ORA A
51EFH (01H) LXI B,050BH
51F2H (C2H) JNZ 51F8H
51F5H (01H) LXI B,0015H
51F8H (F1H) POP PSW
51F9H (90H) SUB B
51FAH (90H) SUB B
51FBH (00H) NOP
51FCH (D8H) RC
51FDH (3CH) INR A
51FEH (FEH) CPI 6AH
5200H (3DH) DCR A
5201H (D0H) RNC
5202H (80H) ADD B
5203H (91H) SUB C
5204H (D8H) RC
5205H (C2H) JNZ 5203H
5208H (3CH) INR A
5209H (C9H) RET

520AH (C1H) POP B
520BH (E1H) POP H
520CH (23H) INX H
520DH (E5H) PUSH H
520EH (C5H) PUSH B
520FH (C9H) RET

5210H (AFH) XRA A
5211H (32H) STA F69FH
5214H (CDH) CALL 518AH
5217H (C3H) JMP 522FH ; TELCOM CALL instruction routine

521AH (CDH) CALL 52ABH
521DH (C2H) JNZ 5210H
5220H (CDH) CALL 518AH
5223H (DAH) JC 522FH ; TELCOM CALL instruction routine
5226H (C2H) JNZ 5239H
5229H (32H) STA F69FH
522CH (C3H) JMP 521AH

522FH (CDH) CALL 5195H
5232H (AFH) XRA A
5233H (32H) STA F69FH
5236H (C3H) JMP 521AH

5239H (FEH) CPI 80H
523BH (C2H) JNZ 5248H
523EH (3EH) MVI A,0DH
5240H (CDH) CALL 5195H
5243H (3EH) MVI A,0AH
5245H (C3H) JMP 522FH ; TELCOM CALL instruction routine

5248H (FEH) CPI FEH
524AH (CAH) JZ 5281H
524DH (D2H) JNC 5210H
5250H (4FH) MOV C,A
5251H (3AH) LDA F69FH
5254H (B7H) ORA A
5255H (79H) MOV A,C
5256H (CAH) JZ 5281H
5259H (D6H) SUI 86H
525BH (DAH) JC 521AH
525EH (01H) LXI B,0000H
5261H (0CH) INR C
5262H (D6H) SUI 0BH
5264H (D2H) JNC 5261H
5267H (C6H) ADI 3BH
5269H (CDH) CALL 5092H
526CH (32H) STA F69AH
526FH (79H) MOV A,C
5270H (C6H) ADI 2FH
5272H (CDH) CALL 5092H
5275H (CDH) CALL 5195H
5278H (3AH) LDA F69AH
527BH (CDH) CALL 5195H
527EH (C3H) JMP 521AH

5281H (D6H) SUI 81H
5283H (21H) LXI H,F68BH
5286H (2BH) DCX H
5287H (D6H) SUI 15H
5289H (D2H) JNC 5286H
528CH (C6H) ADI 16H
528EH (32H) STA F69AH
5291H (CDH) CALL 5194H
5294H (3AH) LDA F69AH
5297H (21H) LXI H,F69AH
529AH (2BH) DCX H
529BH (3DH) DCR A
529CH (C2H) JNZ 529AH
529FH (CDH) CALL 5194H
52A2H (C3H) JMP 521AH

52A5H (3AH) LDA F69EH
52A8H (FEH) CPI 0CH
52AAH (C8H) RZ
52ABH (2AH) LHLD F69BH
52AEH (01H) LXI B,000AH
52B1H (09H) DAD B
52B2H (7EH) MOV A,M
52B3H (FEH) CPI 50H
52B5H (C8H) RZ
52B6H (FEH) CPI 43H
52B8H (37H) STC
52B9H (C9H) RET

52BAH (32H) STA F69AH
52BDH (C5H) PUSH B
52BEH (CDH) CALL 52A5H
52C1H (C1H) POP B
52C2H (D1H) POP D
52C3H (E1H) POP H
52C4H (FEH) CPI 0CH
52C6H (C2H) JNZ 52D6H
52C9H (3AH) LDA F69AH
52CCH (FEH) CPI 1AH
52CEH (CCH) CZ 5327H
52D1H (CDH) CALL 532BH
52D4H (BFH) CMP A
52D5H (C9H) RET

52D6H (D6H) SUI 43H
52D8H (CAH) JZ 52E6H
52DBH (D6H) SUI 0FH
52DDH (CAH) JZ 52E6H
52E0H (78H) MOV A,B
52E1H (FEH) CPI 07H
52E3H (D2H) JNC 52E7H
52E6H (23H) INX H
52E7H (E5H) PUSH H
52E8H (2BH) DCX H
52E9H (01H) LXI B,FFFFH
52ECH (3EH) MVI A,1AH
52EEH (03H) INX B
52EFH (23H) INX H
52F0H (BEH) CMP M
52F1H (C2H) JNZ 52EEH
52F4H (E1H) POP H
52F5H (CDH) CALL 5343H
52F8H (CDH) CALL 52ABH
52FBH (CAH) JZ 5304H
52FEH (3AH) LDA F69DH
5301H (77H) MOV M,A
5302H (BFH) CMP A
5303H (C9H) RET

5304H (36H) MVI M,4FH
5306H (C9H) RET

5307H (21H) LXI H,F686H
530AH (3EH) MVI A,14H
530CH (F5H) PUSH PSW
530DH (7EH) MOV A,M
530EH (E6H) ANI DFH
5310H (77H) MOV M,A
5311H (F1H) POP PSW
5312H (3DH) DCR A
5313H (C8H) RZ
5314H (23H) INX H
5315H (C3H) JMP 530CH

5318H (7EH) MOV A,M
5319H (12H) STAX D
531AH (23H) INX H
531BH (13H) INX D
531CH (0BH) DCX B
531DH (78H) MOV A,B
531EH (B1H) ORA C
531FH (C2H) JNZ 5318H
5322H (C9H) RET

5323H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
5324H DW 7283H
5326H (C9H) RET

5327H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
5328H DW 12CBH
532AH (C9H) RET

532BH (CFH) RST 1 ; Call main ROM at address in following 2 bytes
532CH DW 4231H
532EH (C9H) RET

532FH (CFH) RST 1 ; Call main ROM at address in following 2 bytes
5330H DW 4222H
5332H (C9H) RET

5333H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
5334H DW 5AE3H
5336H (C9H) RET

5337H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
5338H DW 7242H
533AH (C9H) RET

533BH (CFH) RST 1 ; Call main ROM at address in following 2 bytes
533CH DW 2146H
533EH (C9H) RET

533FH (CFH) RST 1 ; Call main ROM at address in following 2 bytes
5340H DW 6B6DH)
5342H (C9H) RET

5343H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
5344H DW 6B9FH
5346H (C9H) RET

5347H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
5348H DW 4244H
534AH (C9H) RET

; =========================================================================================
; Keystoke buffer contents (for performing compression?)
; =========================================================================================
534BH DB "etaoinrshdlfcmugypwb"
</pre>

Navigate to:
* [[Dissasembly of RAM and ROM versions of TS-DOS]]
* [[M100 TS-DOS ROM OptROM Support]]
* [[M100 TS-DOS ROM UI Code]]
* [[M100 TS-DOS ROM RST 7 Handlers]]
* [[M100 TS-DOS ROM TPDD Protocol]]
* [[M100 TS-DOS ROM Cold Boot Recovery]]

M100 TS-DOS ROM TPDD Protocol

2009-04-03T08:10:24Z

Kpettit: New page: == TS-DOS Model 100/102 ROM TPDD Protocol routines == <pre> ; ========================================================================================= ; Flush the RX output buffer to the...

== TS-DOS Model 100/102 ROM TPDD Protocol routines ==

<pre>
; =========================================================================================
; Flush the RX output buffer to the TPDD file
; =========================================================================================
46DDH LHLD FCCEH ; Get address of FD control
46E0H LXI B,0007H ; Load offset of write buffer length
46E3H DAD B ; Calculate address of write buffer length within FD control
46E4H MOV A,M ; Load the write buffer length
46E5H PUSH H ; Save pointer to write buffer length in FD control on stack
46E6H INX H ; Skip the LSB of the write buffer pointer
46E7H INX H ; Skip the MSB of the write buffer pointer
46E8H INX H ; Point to the actual data in the file write buffer
46E9H LXI D,FD04H ; DE points to the data area in RX buffer
46ECH MOV C,A ; Load buffer length into BC
46EDH MVI B,00H ; Make MSB of BC zero
46EFH PUSH PSW ; Save write buffer length to stack
46F0H CALL 4A05H ; Move BC bytes from M to (DE) with increment
46F3H POP PSW ; Retrieve write buffer length from stack
46F4H ANA A ; Test if write buffer is empty
46F5H CNZ 4095H ; Send TPDD Write File opcode using RX buffer with length in A if not empty
46F8H POP H ; Retrieve pointer to write buffer length in FD control from stack
46F9H MVI M,00H ; Set length of write buffer to zero - it is flushed
46FBH INX H ; Increment to address in FD control of write buffer
46FCH MOV D,H ; Save HL to DE for storage of new buffer pointer address
46FDH MOV E,L ; Save MSB of HL to DE
46FEH INX H ; Increment to MSB of address in FD conrol of write buffer
46FFH INX H ; Increment to actual write buffer address
4700H SHLX ; Save new write buffer pointer to FD control
4701H RET

; =========================================================================================
; Appears to be unused code
; =========================================================================================
4702H POP PSW
4703H RET

; =========================================================================================
; Display or print all disk files and free space
; =========================================================================================
4704H LXI H,F685H ; Keyboard buffer
4707H SHLD FCDBH ; Initialize pointer to File Length table
470AH CALL 4735H ; Clear #files displayed, init TPDD and send 1st file dir referene opode
470DH JNZ 486AH ; Communication Error
4710H XRA A ; Prepare to initialize "skip page" count to zero
4711H STA FCDAH ; Load the "skip page" count
4714H STA FCD4H ; Current Page of files being displayed
4717H DCR A ; Set A to 0xFF
4718H STA FCD7H ; Save as Page size to print (print 255 files per page)
471BH MVI A,01H ;
471DH STA F63AH ; ???
4720H CALL 4747H ; Get next page of files from server (NADSBox) with page size = 255
4723H JMP 4C23H ; Send CRLF to screen or printer

; =========================================================================================
; Display Disk free space on LCD at current position
; NOT CALLED!
; Old function - reporting of Free space was merged into the printing of the function
; key display routine.
; =========================================================================================
4726H CALL 4A10H ; Multiply TPDD free sectors len x 128 = free space
4729H CALL 4C3EH ; Print binary number in HL at current position
472CH LXI H,4AD1H ; Point to "0 Bytes free" text
472FH CALL 4A2CH ; Send buffer at M to screen
4732H JMP 4C23H ; Send CRLF to screen or printer

; =========================================================================================
; Clear #files displayed, init TPDD and send 1st file dir referene opode
; =========================================================================================
4735H XRA A ; Indicate zero files being displayed
4736H STA FCD6H ; Count of files on screen
4739H CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
473CH LXI H,0146H ; Load code for "F" attribute and First File dir reference
473FH JMP 476FH ; Send Directory Reference opcode with HL=access mode

; =========================================================================================
; Get next page of files from server (NADSBox / TPDD)
; =========================================================================================
4742H MVI A,14H ; Maximum files that will fit on the display
4744H STA FCD7H ; Save for comparison of file count
4747H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
474AH ANA A ; Test if TPDD
474BH JNZ 4757H ; Skip 1st invocation of "Next file" if NADSBox or TPDD2??
474EH LXI H,02F6H ; Load access mode code for "Next entry" dir reference
4751H CALL 476FH ; Send Directory Reference opcode with HL=access mode
4754H JNZ 47F8H ; Check RX packet for Noraml Response & report errors
4757H LDA FD04H ; 1st filename byte
475AH ANA A ; Test if 1st filename byte is zero
475BH RZ ; Return if last file retrieved
475CH LDA FCDAH ; Load the "skip page" count
475FH ANA A ; Test if this is a "skip page"
4760H CZ 4781H ; Call routine to display file if not a skip page
4763H LXI H,FCD6H ; Count of files on screen
4766H INR M ; Increment #files displayed on LCD
4767H LDA FCD7H ; Load count of max files that will fit on LCD
476AH CMP M ; Compare with current file count
476BH JNZ 474EH ; Jump back to get next file from TPDD if not full
476EH RET

; =========================================================================================
; Send Directory Reference opcode with HL=access mode
; =========================================================================================
476FH SHLD FD00H ; Save file attrib and reference mode to TX buffer
4772H LXI H,1A00H ; Load code and length for Directory Reference opcode
4775H CALL 4822H ; Send TPDD Command/Len in HL
4778H CALL 47CCH ; Receive a packet
477BH LDA FD02H ; Storage for RX packet - response byte
477EH CPI 11H ; Test if response was 0x11 (valid Dir Ref response)
4780H RET

; =========================================================================================
; Print filename in RX buffer to LCD and save length info
; =========================================================================================
4781H MVI C,09H ; Prepare to draw 9 bytes of filename to LCD
4783H LXI H,FD04H ; Location of filename in RX packet
4786H CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
4789H MVI A,20H ; Prepare to draw a trailing space
478BH RST 4 ; Send char in A to LCD
478CH LHLD FD1DH ; Get file size parameter from RX buffer
478FH MOV E,H ; Save file size LSB in E
4790H MOV D,L ; Save file size MSB in D

; =========================================================================================
; Store next file length to keyboard buffer
; =========================================================================================
4791H LHLD FCDBH ; Next storage location for file size info
4794H XCHG ; HL <--> DE
4795H SHLX ; Store file length at address of next file save
4796H XCHG ; HL <--> DE
4797H INX H ; Increment storage address of next file length
4798H INX H ; Increment again (2 byte length)
4799H SHLD FCDBH ; Save new address for lenght storage for next file
479CH RET

; =========================================================================================
; Receive an RX packet. This routine gets copied into RAM and executed from there while
; the Main ROM is selected. This allows the RX packet to be recieved without
; switching to and from the Main ROM to receive each individual byte. The jump
; addresses represent the RAM execution locations.
; =========================================================================================
479DH LXI H,FD02H ; Storage for RX packet
47A0H PUSH H ; Save start of packet address on stack
47A1H CALL FDB2H ; Get next byte from RX into HL
47A4H CALL FDB2H ; Get next byte from RX into HL
47A7H MOV C,A ; Move length byte into C
47A8H CALL FDB2H ; Get next byte from RX into HL
47ABH MOV B,C ; Move length byte to B
47ACH MOV A,C ; Move length byte to A for zero test
47ADH ANA A ; Test if length is zero
47AEH JZ FDA4H ; Skip reading payload if zero length
47B1H CALL FDB2H ; Get next byte from RX into HL
47B4H DCR C ; Decrement length byte
47B5H JNZ FD9DH ; Keep looping until all data received
47B8H POP H ; Restore start of RX packet address
47B9H INR B ; Add opcode byte to length for checksum
47BAH INR B ; Add length byte to length for checksum
47BBH XRA A ; Clear A for checksum calculation
47BCH SIM ; ?Clear Interrupts
47BDH ADD M ; Add next byte to checksum
47BEH INX H ; Increment RX data pointer
47BFH DCR B ; Decrement length counter
47C0H JNZ FDA9H ; Keep looping until all bytes added
47C3H CMA ; Compliment the checksum
47C4H CMP M ; Compare with received checksum
47C5H RET ; Branch if no match - Communication Error

; =========================================================================================
; Get next RX byte and store at HL, test for drive ready & print errors
; This routine (and the one above) get copied into RAM and then executed
; when the Main ROM is selected, so a direct call to the Main ROM address
; is allowed.
; =========================================================================================
47C6H CALL 6D7EH ; Get a character from RS232 receive queue
47C9H MOV M,A ; Save byte at HL
47CAH INX H ; Increment HL
47CBH RET

; =========================================================================================
; Copy the 2 Receive RX Packet routines above to RAM and execute
; =========================================================================================
47CCH LXI H,479DH ; Point to Receive RX Packet routine
47CFH LXI D,FD89H ; Point to target destination in RAM
47D2H LXI B,002FH ; Length of the routine
47D5H CALL 4A05H ; Move BC bytes from M to (DE) with increment
47D8H CALL 4862H ; Test if DSR is set - drive ready, error otherwise
47DBH CALL 4BDBH ; Call Main ROM's Set interrupt to 1DH routine.
47DEH RST 1 ; Switch to Main ROM and execute "Receive RX Pakcet" routine
47DFH DW FD89H ; Address of our RX routine we just copied to RAM
47E1H JNZ 486AH ; Communication Error if no /DSR
47E4H RET

; =========================================================================================
; Get next RX byte and store at HL, test for drive ready & print errors
; =========================================================================================
47E5H CALL 47EBH ; Test drive and get byte from RX
47E8H MOV M,A ; Save byte at HL
47E9H INX H ; Increment HL
47EAH RET

; =========================================================================================
; Test drive ready and get byte from RX, Report error if not ready
; =========================================================================================
47EBH CALL 4862H ; Test if DSR is set - Drive Ready
47EEH CALL 4BE7H ; Get a character from RS232 receive queue
47F1H JC 488DH ; Empty Error Text
47F4H JNZ 486AH ; Communication Error
47F7H RET

; =========================================================================================
; Check RX packet for Normal Response & report errors
; =========================================================================================
47F8H LDA FD02H ; Storage for RX packet
47FBH CPI 12H ; Test for normal return code
47FDH JNZ 486AH ; Communication Error
4800H LDA FD04H ; Location of error code in RX packet
4803H ANA A ; Test if error code is zero
4804H RZ ; Return if no error
4805H CPI 10H
4807H JZ 487EH ; File Exists Error
480AH CPI 50H
480CH JZ 486DH ; Write Protect Error
480FH CPI 60H
4811H JZ 4881H ; Disk Full Error
4814H JC 486AH ; Communication Error
4817H JZ 4873H ; Disk not in drive error
481AH CPI 80H
481CH JC 4873H ; Disk not in drive error
481FH JMP 4870H ; Drive Trouble Error

; =========================================================================================
; Send TPDD Command/Len in HL, H=len, L=Cmd. 0XED8A already has data
; =========================================================================================
4822H SHLD FCE6H ; Store TDD CMD/Len passed in HL
4825H LXI H,FCE6H ; Point to Command/Len storage location

4828H PUSH H ; Save Cmd/Len storage address to stack
4829H LDA FCCAH ; TPDD Bank Numbere
482CH ANA A ; Test if reading from side zero
482DH JZ 4837H ; Skip ahead if reading from side zero
4830H ANI 01H ; Mask off all but LSB (only side 1 allowed)
4832H RAR ; Move the "1" to C
4833H RAR ; Move the "1" to bit 7
4834H RAR ; Move the "1" to bit 6 (could just do MVI 0x40 !!)
4835H ORA M ; OR the 0x40 with Cmd to access Disk Bank 1
4836H MOV M,A ; Save the updated cmd value back at (HL)
4837H MOV A,M ; Get the command value / modified value
4838H INX H ; Point to length parameter passed in
4839H ADD M ; Add the length parameter (checksum)
483AH MOV B,A ; Store checksum in B
483BH MOV A,M ; Get the Length parameter
483CH PUSH PSW ; Save length on stack
483DH INX H ; Point to data (already loaded before invocation)
483EH ANA A ; Test if length is zero
483FH JZ 484BH ; Skip data checksum if length zero
4842H MOV C,A ; Save current count
4843H MOV A,B ; Get running checksum value
4844H ADD M ; Add this byte to checksum
4845H INX H ; Point to next data byte
4846H DCR C ; Decrement count
4847H JNZ 4844H ; Keep looping until count is zero
484AH MOV B,A ; Save updated checksum in B
484BH MOV A,B ; Get Checksum from B
484CH CMA ; Compliment the checksum (protocol thing)
484DH MOV D,A ; Save complimented checksum in D
484EH LXI B,5A5AH ; Load "ZZ" header signature into BC
4851H CALL 49DBH ; Send BC to the serial port using XON/XOFF
4854H POP B ; Get the length from stack into BC
4855H MOV C,B ; Move the length into C
4856H MVI B,00H ; Clear upper MSB of count
4858H INX B ; Add Opcode byte to the TX length
4859H INX B ; Add length byte to the TX length
485AH POP H ; Get address of TX packet from stack
485BH CALL 48D9H ; Send BC bytes to RS-232 from (HL) using XON/XOFF
485EH MOV A,D ; Get checksum byte for TX

; =========================================================================================
; Send A to RS-232 using XON/XOFF and check DSR when done
; =========================================================================================
485FH CALL 4BE3H ; Call Main ROM's Send A to RS-232 using XON/XOFF routine

; =========================================================================================
; Test if DSR is set - drive ready, error otherwise
; =========================================================================================
4862H IN BBH ; Get I/O port with /DSR bit
4864H ANI 20H ; Mask all but the /DSR bit
4866H RZ ; Return if /DSR is asserted (low = asserted)

; =========================================================================================
; Error jump table. Loads A with error number and prints
; =========================================================================================
4867H (3EH) MVI A,01H
DB 0x21 ; Filler - looks like "LXI H,XXXX"
486AH MVI A,02H ; Communication Error
DB 0x21
486DH MVI A,03H ; Write Protect Error
DB 0x21
4870H MVI A,04H ; Drive Trouble Error
DB 0x21
4873H MVI A,05H ; Disk not in drive Error

; =========================================================================================
; For any of the errors above, change the RAM/Disk mode back to RAM
; =========================================================================================
4875H LXI H,FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
4878H MVI M,00H ; Go back to RAM mode
DB 0x21 ; Filler - looks like "LXI H,XXXX"

487BH MVI A,06H ; Printer Not Ready Error
DB 0x21
487EH MVI A,07H ; File Exists Error
DB 0x21
4881H MVI A,08H ; Disk Full Error
DB 0x21
4884H MVI A,09H ; File Empty Error
DB 0x21
4887H MVI A,0AH ; Directory Full Error
DB 0x21
488AH MVI A,0BH ; Ram Full Error
DB 0x21
488DH MVI A,0CH ; ID Error (No text...runtime error only)
DB 0x21
4890H MVI A,0DH ; Bad File Name Error

; =========================================================================================
; Generate the error loaded in A above
; =========================================================================================
4892H LXI H,4B02H ; Pointer to error string table
4895H MOV C,A ; Save error number for loop counting
4896H DCR C ; Decrement error counter to test if string found
4897H JZ 48A4H ; String found in table
489AH MOV A,M ; Get next byte of error string
489BH INX H ; Inrcrement pointer
489CH CPI 00H ; Test if end of string
489EH JNZ 489AH ; Loop until end of string found
48A1H JMP 4896H ; Branch back to decrement string counter

; =========================================================================================
; Print error string at HL from error table
; =========================================================================================
48A4H LDA FCD2H ; Get the "Print error messages" flag
48A7H ANA A ; Test if printing allowed
48A8H JZ 48D0H ; Jump to generate system error if not allowed to print
48ABH MVI A,07H ; Print BELL to cause a beep
48ADH RST 4 ; Send A to the LCD
48AEH INX H ; Skip the error code
48AFH CALL 48F4H ; Print string at HL to col 1 on the bottom line
48B2H CALL 48C7H ; Display "Press any key" and wait for key

; =========================================================================================
; Perform Long jump
; =========================================================================================
48B5H LHLD FCCEH ; Stack pointer upon entry
48B8H SPHL ; Restore stack frame
48B9H LHLD FCD0H ; Get return vector after error
48BCH PUSH H ; Prepare to return to return vector
48BDH RET

; =========================================================================================
; Draw "Press any key" text with pre&post CR and wait for key press
; =========================================================================================
48BEH CALL 4C23H ; Send CRLF to screen or printer
48C1H CALL 48C7H ; Display "Press any key" and wait for key
48C4H JMP 4C23H ; Send CRLF to screen or printer

; =========================================================================================
; Draw "Press any key" text and wait for key press
; =========================================================================================
48C7H LXI H,4BBBH ; Point to "Press any key" text
48CAH CALL 4A2CH ; Send buffer at M to screen
48CDH JMP 4BEBH ; Wait for key from keyboard

; =========================================================================================
; Generate system error from code saved at (HL). This is called in liu of printing when
; the print/generate system error flag is set. The 1st byte of each error entry
; contains the system error number to generate.
; =========================================================================================
48D0H MOV E,M ; Get the error code
48D1H LHLD FCCEH ; Stack pointer upon entry
48D4H MVI M,00H ; Indicate all arguments (none) processed
48D6H JMP 4C37H ; Generate error in E

; =========================================================================================
; Send BC bytes to RS-232 from (HL) using XON/XOFF
; =========================================================================================
48D9H MOV A,M ; Get next byte from (HL)
48DAH CALL 485FH ; Send A to RS-232 using XON/XOFF
48DDH INX H ; Increment poiner
48DEH DCX B ; Decrement byte count
48DFH MOV A,C ; Get C for zero comparison
48E0H ORA B ; Or in MSB of count
48E1H JNZ 48D9H ; Jump to send next byte if not zero
48E4H RET

; =========================================================================================
; Draw C characters to LCD from buffer at HL using current video mode
; =========================================================================================
48E5H MOV A,M ; Get next byte from LCD buffer
48E6H CPI 20H ; Test if it is a space
48E8H JNC 48EDH ; Test if it's less than space, jump if not to redraw
48EBH MVI A,20H ; Draw a space for "illegal" values
48EDH RST 4 ; Draw byte with current regular/inverse video mode
48EEH INX H ; Increment to next byte in LCD buffer
48EFH DCR C ; Decrement the loop counter
48F0H JNZ 48E5H ; Branch if not done to process next character
48F3H RET ; Done

; =========================================================================================
; Print string at HL to col 1 on the bottom line
; =========================================================================================
48F4H PUSH H ; Save pointer to error text on stack
48F5H LXI H,0108H ; Position cursor on col 1 of row 16
48F8H SHLD F639H ; Cursor row (1-8)
48FBH CALL 4C2BH ; Erase from cursor to end of line
48FEH POP H ; Restore pointer to error text from stack
48FFH JMP 4A2CH ; Send buffer at M to screen

; =========================================================================================
; Copy filename at (HL) to current BASIC program
; =========================================================================================
4902H PUSH H ; Save pointer to filename on stack
4903H MVI A,20H ; Load A with code for SPACE
4905H LXI H,FC93H ; Filename of current BASIC program
4908H MVI B,08H ; Prepare to fill current BASIC program with 8 spaces
490AH CALL 4A34H ; Fill (HL) with B bytes of A
490DH POP H ; Retrieve filename pointer from stack
490EH LXI D,FC93H ; Filename of current BASIC program
4911H MVI B,06H ; Prepare to copy 6 bytes of filename before ext
4913H MOV A,M ; Get next byte of filename from source
4914H CPI 41H ; Compare byte with 'A' to test validity
4916H JC 4890H ; Bad Filename Error if invalid char
4919H MOV A,M ; Get next byte again
491AH CPI 2EH ; Compare with '.'
491CH JZ 492BH ; Branch if '.' to fill remaining with ' '
491FH ORA A ; Test for zero (NULL term)
4920H RZ ; Return if done copying filename (NULL term)
4921H STAX D ; Store next filename byte at (DE)
4922H INX H ; Increment source pointer
4923H INX D ; Increment dest pointer
4924H DCR B ; Decrement counter
4925H JNZ 4919H ; Keep looping until all bytes copied
4928H JMP 4933H ; Jump to copy 2 extension bytes

; =========================================================================================
; Fill remainder of filename at (DE) with spaces, B has count
; =========================================================================================
492BH MVI A,20H ; Load code for ' '
492DH STAX D ; Save next byte as ' '
492EH INX D ; Increment pointer
492FH DCR B ; Decrement count
4930H JNZ 492DH ; Keep looping until full

; =========================================================================================
; Copy 2 extention bytes from (HL) to (DE)
; =========================================================================================
4933H MVI B,02H ; Setup count = 2
4935H INX H ; Skip the '.' in the source name
4936H MOV A,M ; Load next extension byte from source
4937H ORA A ; Test for NULL termination
4938H RZ ; Return if NULL terminated
4939H STAX D ; Store in destination
493AH INX D ; Increment destination
493BH DCR B ; Decrement the counter
493CH JNZ 4935H ; Keep looping until done
493FH MVI A,00H ; Load NULL termination byte
4941H STAX D ; Add NULL termination to filename
4942H RET

; =========================================================================================
; Configure baud, test for NADSBox, get NADSBox dir
; =========================================================================================
4943H CALL 4A94H ; Configure baud (19200 for NADSBox/Desklink, 9600 otherwise)
4946H CALL 49A2H ; Send M1 and test for NADSBox/Desklink response
4949H CALL 47CCH ; Receive a packet
494CH CALL 47F8H ; Check RX packet for Normal Response & report errors
494FH LDA FCCBH ; NADSBo / Desklink / TPDD2 flag
4952H ANA A ; Test if server is NADSBox / Desklink
4953H RZ ; Return if not NADSBox / Desklink
4954H LXI H,0008H ; Load opcode 0x08 - FDC Emulation mode
4957H CALL 4822H ; Send TPDD Command/Len in HL
495AH CALL 47CCH ; Receive a packet - should be the current directory name
495DH LDA FD03H ; Load length byte from the RX payload area
4960H CPI 01H ; Test if length 1
4962H JZ 4977H ; Jump to send mystery opcodes if length = 1
4965H DCR A ; Subtract 1 from length (skip reserved 0x00 in filename)
4966H MOV C,A ; Save count in C
4967H MVI A,02H ; Prepare to indicate we have a NADSBox / Desklink directory name
4969H STA FCCBH ; NADSBox / Desklink flag = HAVE_NADS_DIR
496CH MVI B,00H ; Clear MSB of count
496EH LXI H,FD05H ; Point to filename in RX payload (skip 1st byte)
4971H LXI D,FCC0H ; Storage area for NADSBox directory
4974H JMP 4A05H ; Move BC bytes from M to (DE) with increment

; =========================================================================================
; Send mystery opcodes
; =========================================================================================
4977H LXI H,0023H ; Load mystery opcode 23
497AH CALL 4822H ; Send TPDD Command/Len in HL
497DH CALL 47CCH ; Receive a packet
4980H LXI H,4AE7H ; Point to mystery opcode 0x31
4983H CALL 498FH ; Send 9-byte protocol packet at HL
4986H LXI H,4AF0H ; Point to 2nd mystery opcode 0x31
4989H CALL 498FH ; Send 9-byte protocol packet at HL
498CH LXI H,4AF9H ; Point to 3rd mystery opcode 0x31

; =========================================================================================
; Send 9-byte protocol packet at HL
; =========================================================================================
498FH LXI B,0009H ; Load byte counter to send 9 bytes
4992H CALL 48D9H ; Send BC bytes at (HL) to RS-232 using XON/XOFF
4995H JMP 47CCH ; Receive a packet

; =========================================================================================
; Flush the RX queue & discard
; =========================================================================================
4998H CALL 4BDFH ; Check RS232 queue for pending characters
499BH RZ ; Return if RS232 queue is empty
499CH CALL 47EBH ; Test drive ready and get byte from RX.
499FH JMP 4998H ; Branch to get next byte from RX

; =========================================================================================
; Send M1 and test for NADSBox / Desklink response
; =========================================================================================
49A2H CALL 4862H ; Test if DSR set - drive ready
49A5H CALL 49CDH ; Send "M1",0x0D to TX and delay about 3ms
49A8H CALL 4998H ; Flush the RX queue & discard
49ABH CALL 419BH ; Send Opcode 0x08 - FDC emulation mode
49AEH CALL 49D3H ; Send 0x0D to RS-232 and Delay 3ms
49B1H CALL 4BDFH ; Check RS232 queue for pending characters
49B4H MVI A,00H ; NADSBox / Desklink / TPDD2 flag
49B6H JNZ 49BAH ; Skip setting NADSBox / Desklink flag if no response
49B9H INR A ; Indicate response from "M1" command = NADSBox / Desklink
49BAH STA FCCBH ; Store NADSBox / Desklink / TPDD2 flag
49BDH CALL 4998H ; Flush the RX queue & discard
49C0H CALL 49CDH ; Send "M1" to TX and delay about 3ms
49C3H CALL 4998H ; Flush the RX queue & discard
49C6H LXI H,0007H ; Load opcode for Drive Status
49C9H CALL 4822H ; Send TPDD Command/Len in HL
49CCH RET

; =========================================================================================
; Send "M1",0x0D to RS-232 and delay about 3ms
; =========================================================================================
49CDH LXI B,4D31H ; Load code for "M1"
49D0H CALL 49DBH ; Send BC to RS-232 using XON/XOFF
49D3H MVI A,0DH ; Load code for CR (0x0D)
49D5H CALL 485FH ; Send A to RS-232 using XON/XOFF
49D8H JMP 49E3H ; Delay routine - about 3ms

; =========================================================================================
; Send BC to RS-232 using XON/XOFF
; =========================================================================================
49DBH MOV A,B ; Get first byte to send
49DCH CALL 485FH ; Send A to RS-232 using XON/XOFF
49DFH MOV A,C ; Get 2nd byte to send
49E0H JMP 485FH ; Send A to RS-232 using XON/XOFF

; =========================================================================================
; Delay routine - about 72000 cycles = 2.9ms
; =========================================================================================
49E3H MVI H,14H ; 7 Cycles
49E5H MVI L,FFH ; 7 Cycles
49E7H DCR L ; 4 Cycles
49E8H JNZ 49E7H ; 10 Cycles to Jump back. 14 * 255 = 3570 cycles inner loop
49EBH DCR H ; 4 Cycles. But we save 3 cycles from the final JNZ, so 1 cycle
49ECH JNZ 49E5H ; 10 Cycles to jump back. (3570+1+7)*20+7 = 71567 cycles
49EFH RET ; 71567 * 403.877ns = 2.8904ms

; =========================================================================================
; Wait for drive to be ready for (0xFF50) counts of 2.9ms.
; Report error if no data received.
; =========================================================================================
49F0H LXI B,FF50H ; Get count of delay times to wait
49F3H CALL 49E3H ; Delay 2.9ms
49F6H CALL 4BDFH ; Check RS232 queue for pending characters
49F9H RNZ ; Return if data available
49FAH DCR B ; Decrement inner loop count
49FBH JNZ 49F3H ; Branch to delay and test again
49FEH DCR C ; Decrement outer loop count
49FFH JNZ 49F3H ; Branch to delay and test again
4A02H JMP 4867H ; No data received - Drive Not Ready error

; =========================================================================================
; Move BC bytes from M to (DE) with increment
; =========================================================================================
4A05H MOV A,M ; Get next byte from (HL)
4A06H STAX D ; Store next byte at (DE)
4A07H INX H ; Increment source pointer
4A08H INX D ; Increment destination poiner
4A09H DCX B ; Decrement loop control
4A0AH MOV A,B ; Prepare to test for zero
4A0BH ORA C ; OR in LSB to test for zero
4A0CH JNZ 4A05H ; Keep looping until done
4A0FH RET

; =========================================================================================
; Multiply TPDD free sectors len x 128 = free space. A '0' is added to LCD to convert this
; multiplication to x1280 (the TPDD sector size).
; =========================================================================================
4A10H LDA FD1FH ; Get number of free sectors reported from server (TPDD)
4A13H MOV L,A ; Move #free sectors into HL for multiply
4A14H MVI H,00H ; Clear MSB of HL
4A16H LXI D,0080H ; Prepare to multiply #sectors x 128
4A19H JMP 4C1FH ; Signed integer muliply (FAC1=HL*DE)

; =========================================================================================
; Compare (HL) with (DE), C bytes long
; =========================================================================================
4A1CH PUSH D ; Save pointer to 1st buffer
4A1DH PUSH H ; Save pointer to 2nd buffer
4A1EH LDAX D ; Load next byte from 1st buffer
4A1FH SUB M ; Compare with nex byte from 2nd buffer
4A20H JNZ 4A29H ; Jump to exit if no match
4A23H INX H ; Increment 2nd buffer pointer
4A24H INX D ; Increment 1st buffer pointer
4A25H DCR C ; Decrement length
4A26H JNZ 4A1EH ; Jump to compare next byte if not at end
4A29H POP H ; Restore pointer to 2nd buffer
4A2AH POP D ; Restore pointer to 1st buffer
4A2BH RET

; =========================================================================================
; Send buffer at M to screen
; =========================================================================================
4A2CH (7EH) MOV A,M ; Get next byte to send to LCD
4A2DH (A7H) ANA A ; Test for end of string
4A2EH (C8H) RZ ; Return if end of string (NULL terminated)
4A2FH (E7H) RST 4 ; Send character in A to screen/printer
4A30H (23H) INX H ; Increment to next byte
4A31H (C3H) JMP 4A2CH ; Branch to test next byte for zero and print

; =========================================================================================
; Fill (HL) with B bytes of A
; =========================================================================================
4A34H MOV M,A ; Load next byte at (HL) with A
4A35H INX H ; Increment pointer
4A36H DCR B ; Decrement counter
4A37H JNZ 4A34H ; Keep looping until B bytes copied
4A3AH RET

; =========================================================================================
; Initialize blank filename and attribute byte
; =========================================================================================
4A3BH MVI A,20H ; Prepare to fill TX packet with spaces
4A3DH MVI B,18H ; Fill TX buffer with 24 spaces
4A3FH LXI H,FCE8H ; Address of TX packet data
4A42H CALL 4A34H ; Fill (HL) with B bytes of A
4A45H MVI A,46H ; Load "F" TPDD file attribute flag
4A47H STA FD00H ; Store in TX packet data location
4A4AH RET

; =========================================================================================
; Get RAM directory address of selected file into HL
; =========================================================================================
4A4BH LHLD FCE4H ; LCD Buffer address of current file selection
4A4EH CALL 4902H ; Copy filename at (HL) to current BASIC program

; =========================================================================================
; Get RAM directory address of current BASIC program
; =========================================================================================
4A51H CALL 4C0FH ; Update system pointers
4A54H JMP 4BFBH ; Find catalog entry address of current BASIC program

; =========================================================================================
; Send Dir Reference for filename at (HL)
; =========================================================================================
4A57H PUSH H ; Save filename address on stack
4A58H CALL 4A3BH ; Initialize blank filename and attribute byte
4A5BH POP H ; Restore filename address
4A5CH LXI D,FCE8H ; Address of TX packet data
4A5FH LXI B,0006H ; Prepare to copy 6 bytes of TX data
4A62H CALL 4A05H ; Move BC bytes from M to (DE) with increment
4A65H MVI A,2EH ; Load code for '.'
4A67H STAX D ; Add '.' between name and extension
4A68H INX D ; Increment TX pkt address pointer
4A69H LXI B,0002H ; Prepare to copy extension from filename
4A6CH CALL 4A05H ; Move BC bytes from M to (DE) with increment
4A6FH CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir

; =========================================================================================
; Send Dir Reference opcode
; =========================================================================================
4A72H MVI A,00H ; Set dir reference type to "reference" for open
4A74H STA FD01H ; Save in dir reference location in TX buffer
4A77H LXI H,1A00H ; Load opcode for directory reference
4A7AH CALL 4822H ; Send TPDD Command/Len in HL
4A7DH CALL 47CCH ; Receive a packet
4A80H LDA FD1CH ; Load attribute byte
4A83H ANA A ; Test attribute byte for zero
4A84H RET

; =========================================================================================
; Save OS's baud rate string to storage area, A = "Print error messages" flag
; =========================================================================================
4A85H STA FCD2H ; Store "Print error messages" flag
4A88H LXI D,F9A8H ; Storage area for previous baud setting
4A8BH LXI H,F65BH ; RS232 parameter setting table
4A8EH LXI B,0005H ; Copy 7 bytes of parameter data
4A91H JMP 4A05H ; Move BC bytes from M to (DE) with increment

; =========================================================================================
; Configure baud, check for Desklink/NADSBox. Set to 9600 if not Desklink/NADSBox
; =========================================================================================
4A94H CALL 4BD7H ; Wait for TX empty and Reset UART to accept mode bits
4A97H LXI H,4ADEH ; Baud rate string for "98N1D"
4A9AH LXI D,F65BH ; RS232 parameter setting table
4A9DH LXI B,0005H ; Prepare to copy 5 bytes to Baud Parameter table
4AA0H CALL 4A05H ; Move BC bytes from M to (DE) with increment
4AA3H LXI H,F65BH ; Point to RS232 parameter setting table
4AA6H STC ; Indicate Baud rate is part of string
4AA7H CALL 4BD3H ; Set RS232 parameters from string at M
4AAAH CALL 4998H ; Flush the RX queue & discard
4AADH CALL 49A2H ; Send M1 and test for NADSBox / Desklink response
4AB0H CALL 49E3H ; Delay routine - about 3ms
4AB3H CALL 4BDFH ; Check RS232 queue for pending characters
4AB6H JNZ 4998H ; Jump to flush RX and keep 19200 if NADSBox / Desklink found
4AB9H CALL 4BD7H ; Wait for TX empty and Reset UART to accept mode bits
4ABCH LXI H,F65BH ; Baud rate string for "98N1D"
4ABFH DCR M ; Set baud rate to '8' = 9600 baud
4AC0H STC ; Indicate Baud rate is part of string
4AC1H JMP 4BD3H ; Set RS232 parameters from string at M - change to 9600 Baud

; =========================================================================================
; Restore original baud settings
; =========================================================================================
4AC4H LXI H,F9A8H ; Storage for OS's baud settings
4AC7H MOV A,M ; Get 1st byte of setting
4AC8H SUI 3AH ; Test if 1st byte is numeric
4ACAH JC 4BD3H ; Set RS232 parameters from string at M
4ACDH INX H ; Skip setting baud if 1st byte is "M"odem
4ACEH JMP 4BD3H ; Set RS232 parameters from string at M

; =========================================================================================
; Strings and table data
; =========================================================================================
4AD1H DB "0 Bytes free",0x00 ; Old Text - NOT USED in ROM version, only RAM version
4ADEH DB "98N1DNN", 0x00 ; Parameters for setting baud rate
4ADFH DB "8N1D",0x00
4AE4H DB 0x02,0x03,0x01 ; RST 7,30h open mode to TPDD Open mode mapping

4AE9H DB "ZZ1",0x04,0x01,0x00,0x84,0xFF,"F"
4AF0H DB "ZZ1",0x04,0x01,0x00,0x96,0x0F,0x24
4AF9H DB "ZZ1",0x04,0x01,0x00,0x94,0x0F,0x26

4B02H DB 0x12,"Drive Not Ready",0x00
DB 0x12,"Communication Error",0x00
DB 0x12,"Write Protect",0x00
DB 0x12,"Drive Trouble",0x00
DB 0x12,"Disk not in drive",0x00
DB 0x34,"Printer not ready",0x00
DB 0x05,"File Exists",0x00
DB 0x39,"Disk Full",0x00
DB 0x1A,"File Empty",0x00
DB 0x39,"Directory Full",0x00
DB 0x07,"Ram Full",0x00
DB 0x36,0x00
DB 0x37,"Bad File Name",0x00
4BBBH DB " Press any key.",0x00

; =========================================================================================
; RST 1 Vectors to Main ROM. At places in the code where a call is needed to the Main ROM,
; a RST 1 followed by a 2-byte address is issued. The routines will jump to one of
; the handler functions below to perform that RST 1 operation.
; =========================================================================================

4BCBH RST 1 ; Call main ROM at address in following 2 bytes
4BCCH DW 340AH
4BCEH RET

; =========================================================================================
; Call Main ROM's Evaluate expressino at M-1 routine
; =========================================================================================
4BCFH RST 1 ; Call main ROM at address in following 2 bytes
4BD0H DW 1113H
4BD2H RET

; =========================================================================================
; Call Main ROM's Set RS232 parameters from string at M routine
; =========================================================================================
4BD3H RST 1 ; Call main ROM at address in following 2 bytes
4BD4H DW 17E6H
4BD6H RET

; =========================================================================================
; Call Main ROM's Wait for TX empty and Reset UART routine
; =========================================================================================
4BD7H RST 1 ; Call main ROM at address in following 2 bytes
4BD8H DW 6ECBH
4BDAH RET

; =========================================================================================
; Call Main ROM's Set interrupt to 1DH routine.
; Seems like it would be easy enough to just do it in this ROM!
; =========================================================================================
4BDBH RST 1 ; Call main ROM at address in following 2 bytes
4BDCH DW 765CH
4BDEH RET

; =========================================================================================
; Call Main ROM's Check RS232 queue for pending characters routine
; =========================================================================================
4BDFH RST 1 ; Call main ROM at address in following 2 bytes
4BE0H DW 6D6DH
4BE2H RET

; =========================================================================================
; Call Main ROM's Send A to RS-232 using XON/XOFF routine
; =========================================================================================
4BE3H RST 1 ; Call main ROM at address in following 2 bytes
4BE4H DW 6E32H
4BE6H RET

; =========================================================================================
; Call Main ROM's Get a character from RS232 receive queue routine
; =========================================================================================
4BE7H RST 1 ; Call main ROM at address in following 2 bytes
4BE8H DW 6D7EH
4BEAH RET

; =========================================================================================
; Call Main ROM's Wait for key from keyboard routine
; =========================================================================================
4BEBH RST 1 ; Call main ROM at address in following 2 bytes
4BECH DW 12CBH
4BEEH RET

; =========================================================================================
; Call Main ROM's Scan keyboard for character (CTRL-BREAK ==> CTRL-C) routine
; =========================================================================================
4BEFH RST 1 ; Call main ROM at address in following 2 bytes
4BF0H DW 7242H
4BF2H RET

; =========================================================================================
; Call Main ROM's Power Down routine
; =========================================================================================
4BF3H RST 1 ; Call main ROM at address in following 2 bytes
4BF4H DW 13B5H
4BF6H RET

; =========================================================================================
; Call Main ROM's Renew automatic power-off counter routine
; =========================================================================================
4BF7H RST 1 ; Call main ROM at address in following 2 bytes
4BF8H DW 1BB1H
4BFAH RET

; =========================================================================================
; Call Main ROM's Find Catalog Entry Address of current BASIC program routine
; =========================================================================================
4BFBH RST 1 ; Call main ROM at address in following 2 bytes
4BFCH DW 20AFH
4BFEH RET

; =========================================================================================
; Call Main ROM's Kill .DO file routine
; =========================================================================================
4BFFH RST 1 ; Call main ROM at address in following 2 bytes
4C00H DW 1FBFH
4C02H RET

; =========================================================================================
; Call Main ROM's Kill .BA file routine
; =========================================================================================
4C03H RST 1 ; Call main ROM at address in following 2 bytes
4C04H DW 2017H
4C06H RET

; =========================================================================================
; Call Main ROM's Kill .CO file routine
; =========================================================================================
4C07H RST 1 ; Call main ROM at address in following 2 bytes
4C08H DW 1FD9H
4C0AH RET

; =========================================================================================
; Call Main ROM's Insert BC spaces at M routine
; =========================================================================================
4C0BH RST 1 ; Call main ROM at address in following 2 bytes
4C0CH DW 6B6DH
4C0EH RET

; =========================================================================================
; Call Main ROM's Update system pointers routine
; =========================================================================================
4C0FH RST 1 ; Call main ROM at address in following 2 bytes
4C10H DW 2146H
4C12H RET

; =========================================================================================
; Call Main ROM's Find BASIC end of program routine
; =========================================================================================
4C13H RST 1 ; Call main ROM at address in following 2 bytes
4C14H DW 05F4H
4C16H RET

; =========================================================================================
; Call Main Rom's Write new entry to catalog routine
; =========================================================================================
4C17H RST 1 ; Call main ROM at address in following 2 bytes
4C18H DW 2239H
4C1AH RET

; =========================================================================================
; Call Main ROM's Signed integer divide (FAC1=DE/HL) routine
; =========================================================================================
4C1BH RST 1 ; Call main ROM at address in following 2 bytes
4C1CH DW 377EH
4C1EH RET

; =========================================================================================
; Call Main ROM's Signed integer muliply (FAC1=HL*DE) routine
; =========================================================================================
4C1FH RST 1 ; Call main ROM at address in following 2 bytes
4C20H DW 3725H
4C22H RET

; =========================================================================================
; Call Main ROM's Send CRLF to LCD routine
; =========================================================================================
4C23H RST 1 ; Call main ROM at address in following 2 bytes
4C24H DW 4222H
4C26H RET

; =========================================================================================
; Call Main ROM's CLS statement routine
; =========================================================================================
4C27H RST 1 ; Call main ROM at address in following 2 bytes
4C28H DW 4231H
4C2AH RET

; =========================================================================================
; Call Main ROM's Erase from cursor to end of line routine
; =========================================================================================
4C2BH RST 1 ; Call main ROM at address in following 2 bytes
4C2CH DW 425DH
4C2EH RET

; =========================================================================================
; Call Main ROM's Start inverse character mode routine
; =========================================================================================
4C2FH RST 1 ; Call main ROM at address in following 2 bytes
4C30H DW 4269H
4C32H RET

; =========================================================================================
; Call Main ROM's Cancel inverse video routine
; =========================================================================================
4C33H RST 1 ; Call main ROM at address in following 2 bytes
4C34H DW 426EH
4C36H RET

; =========================================================================================
; Call Main ROM's Generate error in E routine
; =========================================================================================
4C37H LXI H,045DH ; Load address of Main ROM's Generate Error in E routine
4C3AH PUSH H ; Push routine to the stack
4C3BH JMP 00A6H ; Jump to Main ROM

; =========================================================================================
; Call Main ROM's Print binary number in HL at current position routine
; =========================================================================================
4C3EH RST 1 ; Call main ROM at address in following 2 bytes
4C3FH DW 39D4H
4C41H RET

; =========================================================================================
; Call Main ROM's Print A to printer, expanding tabs if necessary routine
; =========================================================================================
4C42H RST 1 ; Call main ROM at address in following 2 bytes
4C43H DW 4B55H
4C45H RET

; =========================================================================================
; Call Main ROM's Input and display (no "?") line and store routine
; =========================================================================================
4C46H RST 1 ; Call main ROM at address in following 2 bytes
4C47H DW 4644H
4C49H RET

; =========================================================================================
; Call Main ROM's Check keyboard queue for pending characters routine
; =========================================================================================
4C4AH RST 1 ; Call main ROM at address in following 2 bytes
4C4BH DW 13DBH
4C4DH RET

; =========================================================================================
; Call Main ROM's Move BC bytes from M to (DE) with decrement routine
; =========================================================================================
4C4EH RST 1 ; Call main ROM at address in following 2 bytes
4C4FH DW 6BE6H
4C51H RET

; =========================================================================================
; Call Main ROM's LCOPY statement routine
; =========================================================================================
4C52H RST 1 ; Call main ROM at address in following 2 bytes
4C53H DW 1E5EH
4C55H RET

; =========================================================================================
; Call Main ROM's Stop automatic scrolling routine
; =========================================================================================
4C56H RST 1 ; Call main ROM at address in following 2 bytes
4C57H DW 423FH
4C59H RET

; =========================================================================================
; Call Main ROM's Resume Automatic Scrolling routine
; =========================================================================================
4C5AH RST 1 ; Call main ROM at address in following 2 bytes
4C5BH DW 4244H
4C5DH RET

; =========================================================================================
; Call Main ROM's Get char at M and convert to uppercase routine
; =========================================================================================
4C5EH RST 1 ; Call main ROM at address in following 2 bytes
4C5FH DW 0FE8H
4C61H RET

; =========================================================================================
; Call Main ROM's Get file descriptor for file in A routine
; NOT CALLED
; =========================================================================================
4C62H RST 1 ; Call main ROM at address in following 2 bytes
4C63H DW 4C81H
4C65H RET

; =========================================================================================
; Call Main ROM's Update line addresses for current BASIC program routine
; =========================================================================================
4C66H RST 1 ; Call main ROM at address in following 2 bytes
4C67H DW 05F0H
4C69H RET

; =========================================================================================
; Call Main ROM's Copy CO header bytes (6) from (HL) to "active" CO Header storage area routine
; =========================================================================================
4C6AH RST 1 ; Call main ROM at address in following 2 bytes
4C6BH DW 253DH
4C6DH RET

; =========================================================================================
; Call Main ROM's print CO address, length and invocation address to LCD routine
; =========================================================================================
4C6EH RST 1 ; Call main ROM at address in following 2 bytes
4C6FH DW 25A4H
4C71H RET

; =========================================================================================
; Call Main ROM's Process SAVEM arguments for address, length and entry point routine
; =========================================================================================
4C72H RST 1 ; Call main ROM at address in following 2 bytes
4C73H DW 2346H
4C75H RET
</pre>

Navigate to:
* [[Dissasembly of RAM and ROM versions of TS-DOS]]
* [[M100 TS-DOS ROM OptROM Support]]
* [[M100 TS-DOS ROM UI Code]]
* [[M100 TS-DOS ROM RST 7 Handlers]]
* [[M100 TS-DOS ROM Compression]]
* [[M100 TS-DOS ROM Cold Boot Recovery]]

M100 TS-DOS ROM RST 7 Handlers

2009-04-03T08:01:34Z

Kpettit: New page: == TS-DOS Model 100/102 ROM RST 7 Handlers == This is the code for the DOS-ON RST 7 Hooks, along with the TPDD1 Rename functionality. <pre> ; ============================================...

== TS-DOS Model 100/102 ROM RST 7 Handlers ==

This is the code for the DOS-ON RST 7 Hooks, along with the TPDD1 Rename functionality.

<pre>
; =========================================================================================
; Load default RST 7 vector table values
; =========================================================================================
3FFAH LXI 7FF3H ; Address of a RET opcode in ROM
3FFDH SHLD FAE6H ; Save as hook for RST 7,0Ch?? We didn't modify this one
4000H SHLD FB08H ; Save as hook for RST 7,2Eh - DSKI$ function
4003H SHLD FB0AH ; Save as hook for RST 7,30h - OPEN/CLOSE/PRINT/LINE INPUT
4006H SHLD FAF0H ; Save as hook for RST 7,16h - SAVE
4009H SHLD FAF4H ; Save as hook for RST 7,1Ah - RUN
400CH LXI H,08DBH ; Load address of "Generate FC Error" in Main ROM
400FH SHLD FB2CH ; Save as hook for RST 7,52h - LFILES
4012H SHLD FB32H ; Save as hook for RST 7,58h - KILL
4015H SHLD FB34H ; Save as hook for RST 7,5Ah - NAME
4018H SHLD FB36H ; Save as hook for RST 7,5Ch - SAVEM
401BH SHLD FB38H ; Save as hook for RST 7,5Eh - LOADM and RUNM
401EH RET

; =========================================================================================
; Install our RST 7 hook for all RST 7 calls we are interested in. This uses the "ON TIME"
; time storage location to copy a 6-byte routine to switch to OptROM and call our
; RST 7 "switch" statement in our ROM. This means ON TIME can't be used when using
; the DOS-ON feature.
; =========================================================================================
401FH CALL 3FFAH ; Load default RST 7 vector table values
4022H LXI H,4084H ; Point to RST 7 RAM hook routine
4025H LXI D,F93DH ; Point Time for ON TIME interrupt to use as our hook routine
4028H LXI B,0006H ; Copy our RST 7 hood to the "ON TIME" time location
402BH CALL 4A05H ; Move BC bytes from HL to DE - copy our hook to RAM
402EH LXI H,F93DH ; Load address of "ON TIM" time where our hook was copied
4031H SHLD FAF4H ; Use our RAM RST 7 Hook for RST 7,1Ah - RUN
4034H SHLD FAF0H ; Use our RAM RST 7 Hook for RST 7,16h - SAVE
4037H SHLD FB38H ; Use our RAM RST 7 Hook for RST 7,5Eh - LOADM and RUNM
403AH SHLD FB36H ; Use our RAM RST 7 Hook for RST 7,5Ch - SAVEM
403DH SHLD FB08H ; Use our RAM RST 7 Hook for RST 7,2Eh - DSKI$
4040H SHLD FB0AH ; Use our RAM RST 7 Hook for RST 7,30h - OPEN/CLOSE/PRINT/INPUT
4043H SHLD FB2CH ; Use our RAM RST 7 Hook for RST 7,52h - LFILES
4046H SHLD FB32H ; Use our RAM RST 7 Hook for RST 7,58h - KILL
4049H SHLD FB34H ; Use our RAM RST 7 Hook for RST 7,5Ah - NAME
404CH RET

; =========================================================================================
; Process jump to custom RST 7 Hook routine from Main ROM
; =========================================================================================
404DH PUSH PSW ; Preserve PSW
404EH LDA FAC9H ; Get address of last RST 38H call argument
4051H CPI 1AH ; RST 7,1Ah Hook - RUN statement
4053H JZ 4451H
4056H CPI 16H ; RST 7,16h Hook - SAVE statement
4058H JZ 44E7H
405BH CPI 5EH ; RST 7,5Eh Hook - LOADM and RUNM statement
405DH JZ 43C1H
4060H CPI 5CH ; RST 7,5Ch Hook - SAVEM statement
4062H JZ 440DH
4065H CPI 2EH ; RST 7,2Eh Hook - DSKI$ function
4067H JZ 4324H
406AH CPI 30H ; RST 7,30h Hook - OPEN/CLOSE/PRINT/LINE INPUT satement
406CH JZ 451DH
406FH CPI 52H ; RST 7,52h Hook - LFILES
4071H JZ 4346H
4074H CPI 58H ; RST 7,58h Hook - KILL
4076H JZ 4377H
4079H CPI 5AH ; RST 7,5Ah Hook - NAME statement
407BH JZ 4396H
407EH POP PSW ; Restore stack frame
407FH MVI E,02H ; Prepare to generate "SN" error
4081H JMP 4C37H ; Generate error in E

; =========================================================================================
; RST 7 Handler copied to RAM for DOS-ON
; =========================================================================================
4084H CALL FAA4H ; Call RAM hook to switch to OptROM
4087H JMP 404DH ; Jump to TS-DOS RST 7 handler in OptROM

; =========================================================================================
; Open TPDD file for Read Mode. File already stored in TX buffer.
; =========================================================================================
408AH LXI H,0101H ; Load "Open file" opcode
408DH MVI A,03H ; Load OPEN_READ mode into A
408FH STA FCE8H ; Save A in TX data storage (mode location)
4092H JMP 409BH ; Send Request in HL and await response - Open File

; =========================================================================================
; Send TPDD Write File opcode using RX buffer with length in A
; =========================================================================================
4095H MOV H,A ; Move length to H
4096H MVI L,04H ; Load TPDD_WRITE opcode to L
4098H JMP 40A7H ; Send TX packet using RX buffer

; =========================================================================================
; Send Request in HL and await response
; =========================================================================================
409BH CALL 4822H ; Send TPDD Command/Len in HL
409EH CALL 49F0H ; Wait for data to be ready
40A1H CALL 47CCH ; Copy Receive RX packet routine to RAM and execute it
40A4H JMP 47F8H ; Check RX packet for Normal Response & report errors

; =========================================================================================
; Use RX buffer to send a TX packet (used to send data). Opcode/len in HL
; =========================================================================================
40A7H SHLD FD02H ; Save Opcode/len to RX buffer
40AAH LXI H,FD02H ; Storage for RX packet
40ADH CALL 4828H ; Send TPDD pointed to by HL
40B0H CALL 47CCH ; Receive a packet
40B3H JMP 47F8H ; Check RX packet for Normal Response & report errors

; =========================================================================================
; Send TPDD_READ data opcode and recieve response
; =========================================================================================
40B6H LXI H,0003H ; Load TPDD_READ opcode
40B9H CALL 4822H ; Send TPDD Command/Len in HL
40BCH CALL 47CCH ; Receive a packet
40BFH LDA FD03H ; Get length byte from RX buffer
40C2H LXI H,FD04H ; Point to return data addres in RX buffer
40C5H CPI 80H ; Test for maximum read length
40C7H RET

; =========================================================================================
; Write HL bytes of data from (DE) to TPDD
; =========================================================================================
40C8H PUSH D ; Push address of write-data to stack
40C9H PUSH H ; Push length of data to the stack
40CAH CALL 4101H ; Test free Disk space and issue TPDD_OPEN request
40CDH POP H ; Get address of data from stack
40CEH SHLD FCD5H ; Save length as remaining length to write
40D1H POP H ; Get address of data to write to TPDD from stack
40D2H LXI D,FD04H ; Point to RX buffer to copy write data
40D5H LXI B,0080H ; Prepare to copy 128 bytes of data to the RX buffer

; =========================================================================================
; Write BC bytes of data from (HL) to (DE) and write to TPDD, DE=RX buffer data pointer
; =========================================================================================
40D8H CALL 4A05H ; Move BC bytes from M to (DE) with increment
40DBH PUSH H ; Push the updated address to the stack
40DCH LHLD FCD5H ; Get the remaining lenth left to write
40DFH LXI B,0080H ; Prepare to subtract 128 from the length
40E2H DSUB ; Subtract 128 bytes from remaining length to write
40E3H JC 40F4H ; Jump out of loop if less than 128 bytes remaining
40E6H JZ 40F4H ; Jump out of loop if exactly 128 bytes remaining
40E9H SHLD FCD5H ; Save updated length left to write for next pass
40ECH MVI A,80H ; Prepare to write 128 bytes to TPDD
40EEH CALL 4095H ; Send TPDD Write File opcode using RX buffer with length in A
40F1H JMP 40D1H ; Jump to send next packet of 128 bytes

; =========================================================================================
; Write remaining bytes (128 or less from above) to TPDD
; =========================================================================================
40F4H POP H ; Clear stack of unneeded updated source address
40F5H LDA FCD5H ; Load A with remainder of bytes to be sent
40F8H CALL 4095H ; Send TPDD Write File opcode using RX buffer with length in A
40FBH LXI H,0002H ; Load TPDD_CLOSE opcode in HL
40FEH JMP 409BH ; Send Request in HL and await response

; =========================================================================================
; Test if enough space on disk for HL bytes and issue Open request, error if disk full
; =========================================================================================
4101H LXI D,0500H ; Load decimal 1280 to calculate sector number
4104H XCHG ; Swap HL/DE to perform size/bytes_per_sector
4105H CALL 4C1BH ; Signed integer divide (FAC1=DE/HL)
4108H LDA FD1FH ; Get number of free sectors on disk
410BH SUB L ; Compare required sectors with free space to see if enough room
410CH JC 4881H ; Disk Full Error
410FH JZ 4881H ; Disk Full Error
4112H LDA FCD6H ; Load open mode (new, append, etc.)
4115H STA FCE8H ; Save file open mode to TX buffer
4118H LXI H,0101H ; Load TPDD_OPEN opcode
411BH JMP 409BH ; Send Request in HL and await response

; =========================================================================================
; Insert BC spaces at address of RAM file being loaded/run
; =========================================================================================
411EH LHLD FCE2H ; Load address of file being processed
4121H CALL 4C0BH ; Insert BC spaces at M
4124H JC 488AH ; RAM full error

; =========================================================================================
; Open TPDD file and read data to file address being processed
; =========================================================================================
4127H LHLD FCE2H ; Get address of file being processed
412AH PUSH H ; Save address on stack
412BH CALL 408AH ; Open TPDD file for Read Mode
412EH CALL 40B6H ; Send TPDD_READ data opcode and recieve response
4131H MOV C,A ; Move read length to C
4132H MVI B,00H ; Clear MSB of copy length
4134H POP D ; Restore address to write data

; =========================================================================================
; Write BC bytes from M to DE and subtract BC from total file size
; =========================================================================================
4135H CALL 4A05H ; Move BC bytes from M to (DE) with increment
4138H PUSH D ; Save updated address to stack
4139H LDA FD03H ; Get length byte from RX buffer
413CH LHLD FCDDH ; Get total file size from storage
413FH MOV C,A ; Load count of bytes transfered this block
4140H MVI B,00H ; Clear MSB of count
4142H DSUB ; Subtract this block from total file length
4143H SHLD FCDDH ; Save remaining bytes to be read back to temp storage
4146H JC 414EH ; Branch if too many bytes read
4149H MOV A,L ; Load LSB to A to test for zero
414AH ORA H ; OR MSB to test for zero
414BH JNZ 412EH ; Branch to read more data if not zero
414EH POP D ; Pop address from stack - cleanup
414FH RET

; =========================================================================================
; Write data to FDC Emulation mode physical/logical sector
; =========================================================================================
4150H LDA FCDDH ; Get physical sector number
4153H CPI 01H ; Test if physical sector is #1
4155H RZ ; Return if trying to write to sector 1 - reserved!!!
4156H CALL 4998H ; Flush RX queue and discard
4159H MVI A,57H ; Load FDC opcode for "W"rite sector
415BH STA FCD3H ; Save the FDC emulation mode opcode
415EH CALL 42CEH ; Send FDC emulation mode opcode
4161H CALL 4998H ; Flush RX queue and discard
4164H CALL 4176H ; Increment to next logical/physical sector
4167H LHLD FCE4H ; FDC Emulation data pointer address
416AH CALL 48D9H ; Send BC bytes to RS-232 from (HL) using XON/XOFF
416DH SHLD FCE4H ; LCD Buffer address of current file selection
4170H CALL 42EEH ; Read FDC Emulation mode response
4173H JMP 4150H ; Jump to write next sector ???

; =========================================================================================
; Increment to next logical/physical sector
; =========================================================================================
4176H LDA FD09H ; Get byte 7 from the RX buffer (logical sector length)
4179H CALL 4191H ; Get FDC Emulation RAM buffer sector length based on response
417CH CPI 35H ; Test if RAM Buffer logical sector length is "500" (1280)
417EH JZ 4189H ; Just update physical sector if RAM length = physical sector len
4181H LXI H,FCDEH ; Load pointer to logical sector value
4184H INR M ; Increment to next logical sector
4185H MOV A,M ; Get the next logical sector value
4186H CPI 14H ; Test if logical sector = 20 (There are 20 64-byte logical sectors)
4188H RNZ ; Return if not paat end of physical sector
4189H LXI H,FCDDH ; Point to physical sector storage
418CH INR M ; Increment to next physical sector - we "rolled over"
418DH INX H ; Point to logical sector
418EH MVI M,01H ; Start with logical sector #1 in new physical sector
4190H RET

; =========================================================================================
; Get FDC Emulation RAM buffer sector length based on response code in A
; =========================================================================================
4191H LXI B,0500H ; Initialize to 1280 byte sector length
4194H CPI 35H ; Compare response to test for "500"
4196H RZ ; Return if match
4197H LXI B,0040H ; Sector lenth not 1280, must be 64 bytes
419AH RET

; =========================================================================================
; Send TPDD opcode 0x08 - Go to FDC emulation mode
; =========================================================================================
419BH LXI H,0008H ; Prepare to send Opcode 0x08 (FDC Emulation Mode)
419EH CALL 4822H ; Send TPDD Command/Len in HL
41A1H CALL 49D3H ; Send 0x0D to RS-232 and Delay 3ms
41A4H JMP 4998H ; Flush RX queue and discard

; =========================================================================================
; Rename the TPDD file whose name is in "current BASIC program"
; =========================================================================================
41A7H LXI H,FC93H ; Filename of current BASIC program
41AAH LXI D,FCE8H ; Point to data area in TX buffer
41ADH LXI B,0006H ; Move 6 bytes of filename data

; =========================================================================================
; Rename the TPDD file whose name is in (HL)
; =========================================================================================
41B0H CALL 4A05H ; Move BC bytes from M to (DE) with increment
41B3H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
41B6H ANA A ; Test for TPDD server
41B7H JNZ 4258H ; Send TPDD_RENAME opcode and check response

; =========================================================================================
; Rename on a TPDD. I'm guessing the drive will allow changing a name to something
; that already exists, or there is no "rename", so TS-DOS is reading sector 1 and doing
; the rename opertaion manually, then writing sector 1 back to the disk.
; =========================================================================================
41BAH CALL 4A72H ; Send Dir Reference opcode
41BDH JNZ 487EH ; File Exists Error
41C0H LXI D,0500H ; Prepare to test for 1280 bytes of free ram (1 sector)
41C3H CALL 4308H ; Test if at least DE bytes of RAM free
41C6H LXI H,0100H ; Load HL with physical sector 1, logical sector 0
41C9H SHLD FCDDH ; Save in FDC Emulation sector storage
41CCH CALL 419BH ; Send opcode 0x08 - go to FDC emulation mode
41CFH CALL 427EH ; Load Physical sector 1 to (HL) (HL=Unused memory pointer)
41D2H LHLD FBB6H ; Get pointer to data - Unused memory pointer
41D5H PUSH H ; Push data pointer to the stack
41D6H MVI B,28H ; Prepare to test up to 40 filenames (max for TPDD)
41D8H LXI D,FC9CH ; Filename of last program loaded from tape
41DBH CALL 4269H ; Compare "Last program loaded" filename with all files on TPDD
41DEH JC 487BH ; Printer not ready / FF error
41E1H MOV A,B ; Get index in TPDD Sector 1 of filename that matches the old filename
41E2H ANA A ; Test if old filename exists
41E3H JZ 487BH ; Jump to error if filename not found in sector 1 - FF error
41E6H PUSH H ; Save address within Sector 1 of matching filename to stack
41E7H LXI D,FCE8H ; Point to TX buffer data area (payload)
41EAH XCHG ; HL <--> DE Prepare to copy new filename to Sector 1 data
41EBH LXI B,0009H ; Prepare to copy 9 bytes of filename
41EEH CALL 4A05H ; Move BC bytes from M to (DE) with increment - copy new filename to sector 1
41F1H POP H ; Restore pointer to filename address within sector 1
41F2H PUSH H ; Save it to the stack again
41F3H LXI D,FD20H ; Load address of data byte 28 in RX buffer
41F6H LXI B,001FH ; Prepare to copy 31 bytes to RX buffer from Sector 1 data
41F9H CALL 4A05H ; Move BC bytes from M to (DE) with increment - Save File data in RX buffer

; ==========================================================================================
; Now we will "remove" the renamed file from sector 1 by copying over it with the remaining
; files in the sector. Filenames in sector 1 must be in alphabetical order, so we have to
; remove it and reinsert it at the new location based on the new name.
; ==========================================================================================

41FCH POP D ; Restore pointer to filename address within sector 1
41FDH PUSH D ; Save it to the stack again
41FEH LXI H,001FH ; Prepare to add 31 bytes to the sector 1 pointer (go to next file)
4201H DAD D ; Point to next file after rename file within sector 1
4202H PUSH H ; Save address of next file after rename file to stack
4203H LHLD FBB6H ; Unused memory pointer
4206H LXI B,0500H ; Load size of 1 TPDD sector (1280 bytes)
4209H DAD B ; Point to end of sector 1 data in free memory region
420AH POP B ; Restore address of next file after rename file from stack
420BH PUSH B ; Save it back to the stack
420CH DSUB ; Calculate number of bytes from next file after rename to end of sector 1
420DH XTHL ; HL <--> (SP) Prepare to move HL to BC, HL now has address of next file
420EH POP B ; Get byte count to end of sector 1
420FH CALL 4A05H ; Move BC bytes from M to (DE) with increment - shift bytes "left" in buffer
4212H LHLD FBB6H ; Unused memory pointer - point to beginning of Sector 1 data
4215H MVI B,27H ; Prepare to search throuh 39 files (we just deleted one)
4217H LXI D,FD20H ; Load address of data byte 28 in RX buffer (our saved file)
421AH CALL 4269H ; Search Sector-1 files at (HL) for filename at (DE)
421DH PUSH H ; Save address of location where file should be inserted in Sector 1
421EH LHLD FBB6H ; Unused memory pointer - point to beginning of Sector 1
4221H LXI B,04FFH ; Prepare to move bytes "right" to end of sector (1280 bytes - 1)
4224H DAD B ; Point to end of sector 1 data
4225H PUSH H ; Save end of sector 1 address to stack
4226H LXI B,001FH ; Prepare to subtract 1 file entry length from end of sector 1 address
4229H DSUB ; Shorten the copy operation by 1 file entry so we don't overflow memory
422AH POP D ; Get end of sector 1 address from stack as our "copy to" address
422BH POP B ; Get address where file needs to be inserted from the stack
422CH PUSH B ; Save it back to the stack for later
422DH PUSH H ; Save address of end of Sector 1 minus one file entry length to stack
422EH DSUB ; Calculate the copy lenght of data from insertion point to end of sector-1 file
422FH PUSH H ; Save copy length to the stack to copy it to BC
4230H POP B ; Get copy length into BC
4231H INX B ; Increment length by 1 so the last byte is inclusive
4232H POP H ; Get address of file insertion point from stack
4233H CALL 4C4EH ; Move BC bytes from M to (DE) with decrement - shift files "right" in sector 1
4236H LXI H,FD20H ; Get address of our saved file info in the RX buffer
4239H POP D ; Get address in Sector 1 of file insertion point
423AH LXI B,001FH ; Prepare to copy 1 file entry size (31 bytes)
423DH CALL 4A05H ; Move BC bytes from M to (DE) with increment

; ===============================================================================
; Seems like the next two lines don't do anything. The value being loaded in HL
; *appears* to mean "Logical sector 20, physical sector 1", but only if the SHLD
; target address is FCCDH. Then 5 instructions further down, the value in
; ED80h is overwritten with logical sector 0.
; ===============================================================================
4240H LXI H,1401H ; Set L = logical sector 1, H=File type 0x14?
4243H SHLD FCDEH ; Save logical sector & filetype

4246H POP H ; POP stale address within Sector 1 of matching filename from stack
4247H POP H ; Get address of unused memory (Sector 1 data storage) from stack
4248H SHLD FCE4H ; Save in FDC Emulation data pointer address
424BH LXI H,0100H ; Load HL= logical sector 1, physical sector 0
424EH SHLD FCDDH ; Save in FDC Emulation physical/logical sector storage
4251H CALL 4150H ; Write data to FDC Emulation mode physical/logical sector
4254H CALL 49CDH ; Send "M1",0x0D to RS-232 and delay about 3ms - go to Standard mode
4257H RET

; =========================================================================================
; Send TPDD_RENAME opcode and check response for errors
; =========================================================================================
4258H LXI H,190DH ; Load TPDD_RENAME opcode
425BH CALL 4822H ; Send TPDD Command/Len in HL
425EH CALL 47CCH ; Receive a packet
4261H LDA FD04H ; Get response error code
4264H ANA A ; Check for errors
4265H JNZ 487EH ; Report File Exists Error if not zero
4268H RET

; =========================================================================================
; Search Sector-1 files at (HL) for filename at (DE), maximum of "B" entries searched
; =========================================================================================
4269H MVI C,09H ; Prepare to compare 9 bytes
426BH CALL 4A1CH ; Compare (HL) with (DE), C bytes long (HL & DE preserved)
426EH RZ ; Return if they are the same
426FH RC ; Return if filename is less (files are sorted on TPDD)
4270H MOV A,M ; Get 1st byte of filename to test for NULL
4271H ORA A ; Test if A is 0
4272H RZ ; Return if string is NULL
4273H PUSH B ; Save BC on stack
4274H LXI B,001FH ; Prepare to add 31 to HL
4277H DAD B ; Add 31 to HL
4278H POP B ; Restore original BC
4279H DCR B ; Decrement loop counter
427AH RZ ; Return if no more items to compare
427BH JMP 4269H ; Jump to compare next entry

; =========================================================================================
; Read FDC sectors to New File Address (Free memory)
; =========================================================================================
427EH LHLD FCE2H ; Get pointer for TPDD read data
4281H CALL 4298H ; Read sector A into (HL)
4284H LDA FCDDH ; Load current FDC Emulation physical sector number
4287H DCR A ; Decrement to previous sector
4288H RZ ; Return if sector number is zero
4289H JMP 4281H ; Jump to read another sector (what breaks the loop? - A not saved)

; =========================================================================================
; Receive RX bytes to (HL) routine copied to RAM
; =========================================================================================
428CH CALL 6D7EH ; Get a character from RS232 receive queue
428FH MOV M,A ; Save next byte to (HL)
4290H INX H ; Increment pointer
4291H DCX B ; Decrement counter
4292H MOV A,C ; Prepare to test or zero
4293H ORA B ; OR in MSB of coutner
4294H JNZ FD89H ; Jump back to receive next character (RAM address)
4297H RET

; =========================================================================================
; Read FDC sector A to (HL), BC has length
; =========================================================================================
4298H PUSH H ; Save target address for RX data stack
4299H MVI A,52H ; Load FDC Emulation opcode for "R"ead
429BH STA FCD3H ; Save as FDC Emulation opcode to send
429EH CALL 42CEH ; Send FDC emulation mode opcode
42A1H CALL 4176H ; Increment to next logical/physical sector
42A4H CALL 4862H ; Test if DSR is set - drive ready, error otherwise
42A7H PUSH B ; Save length of RX to the stack
42A8H LXI H,428CH ; Load address of RX routine to copy to RAM
42ABH LXI B,000CH ; Size of the RX routine to be copied to RAM
42AEH LXI D,FD89H ; Target address of RX routine (in ALTLCD buffer)
42B1H CALL 4A05H ; Move BC bytes from M to (DE) with increment
42B4H MVI A,0DH ; Prepare to send CR to RS-232
42B6H CALL 485FH ; Send A to RS-232 using XON/XOFF
42B9H CALL 4BDBH ; Call Main ROM's Set interrupt to 1DH routine.
42BCH POP B ; Restore count of bytes to receive
42BDH POP H ; Restore target address for RX data
42BEH RST 1 ; Call main ROM at address in following 2 bytes
42BFH DW FD89H ; Switch to Main ROM and call our RAM based RX routine
42C1H RET

; =========================================================================================
; Convert decimal value in A to base 10 ASCII value in BC
; =========================================================================================
42C2H MVI B,2FH ; Start with '0' - 1
42C4H SUI 0AH ; Subtract 10 from A
42C6H INR B ; Increment B (10's position)
42C7H JNC 42C4H ; Keep looping until A negative
42CAH ADI 3AH ; Convert negative remainder to positive ASCII '0'-'9'
42CCH MOV C,A ; Store LSB ASCII value in C
42CDH RET

; =========================================================================================
; Send FDC emulation mode opcode
; =========================================================================================
42CEH LDA FCDDH ; Get physical sector number
42D1H CALL 42C2H ; Convert A to 10-based ASCII
42D4H LDA FCD3H ; Load the FDC emulation mode opcode to send
42D7H CALL 485FH ; Send A to RS-232 using XON/XOFF
42DAH CALL 49DBH ; Send BC to RS-232 using XON/XOFF - send physical sector #
42DDH LDA FCDEH ; Get logical sector number
42E0H CALL 42C2H ; Convert A to 10-based ASCII
42E3H MVI A,2CH ; Load code for ','
42E5H CALL 485FH ; Send A to RS-232 using XON/XOFF
42E8H CALL 49DBH ; Send BC to RS-232 using XON/XOFF - send logical sector #
42EBH CALL 49D3H ; Send 0x0D to RS-232 and Delay 3ms

; =========================================================================================
; Read FDC Emulation mode response
; =========================================================================================
42EEH LXI H,FD04H ; Point to RX buffer data area
42F1H PUSH H ; Save RX buffer address on stack
42F2H MVI C,08H ; Prepare to read 8 bytes from RX - standard FDC response length
42F4H CALL 47E5H ; Get next byte from RX into HL
42F7H DCR C ; Decrement loop counter
42F8H JNZ 42F4H ; Keep looping until 8 bytes read
42FBH POP H ; Get start of RX buffer address from stack
42FCH MOV A,M ; Get first response byte
42FDH CPI 30H ; Test if response error code is '0' - no error
42FFH RZ ; Return if no error
4300H CPI 42H ; Test for FDC Emulation mode "write protect" error code
4302H JZ 486DH ; Write Protect Error
4305H JMP 4867H ; Drive Not Ready Error

; =========================================================================================
; Test if at least DE bytes of RAM left
; =========================================================================================
4308H LHLD FBB6H ; Unused memory pointer
430BH PUSH H ; Push unused memory location on stack
430CH SHLD FCE2H ; Save unused memory location locally
430FH LXI H,FFC0H ; Prepare to subtract 64 from stack pointer
4312H DAD SP ; Add SP to HL (-64) (need some call space to run program)
4313H POP B ; Restore unused memory location in BC
4314H DSUB ; Subtract stack from unused memory pointer
4315H RST 3 ; Compare DE and HL - check if enough free RAM
4316H JC 488AH ; RAM full error
4319H RET

; =========================================================================================
; Issue TPDD Delete file Opcode
; =========================================================================================
431AH XRA A ; Prepare to indicate we can't use Next Dir feature
431BH STA FD01H ; Save in dir reference location in TX buffer
431EH LXI H,0005H ; Load Delete File opcode into HL
4321H JMP 409BH ; Send Request in HL and await response

; =========================================================================================
; RST 7,2Eh Hook - DSKI$ function
; =========================================================================================
4324H POP PSW ; Pop return address - we will return manually to Main ROM
4325H CPI 30H ; Test A against '0' to check for bounds (only allow '0' and '1')
4327H JC 00A6H ; Return to Main ROM if less than '0' - not our's
432AH CPI 32H ; Test A against '2' to check for bounds
432CH JNC 00A6H ; Return to Main ROM if >= '2'
432FH SUI 30H ; Convert ASCII bank number to binary
4331H STA FCCAH ; Save the target bank number in TPDD2 Bank number space
4334H INX H ; Point to next byte to ensure it is ':'
4335H DCR E ; ? Maybe length
4336H MOV A,M ; Get next byte of filename
4337H CPI 3AH ; Test if it is ':'
4339H JNZ 00A6H ; Return if not ':'
433CH INX H ; Increment to filename portion
433DH DCR E ; ? Maybe length
433EH XTHL ; Put pointer to filename on stack so we don't lose it when we pop
433FH POP H ; Pop so we return to our caller's return address
4340H MVI A,09H ; Load A with a value we will test for later to see if it's our file
4342H ORA A ; Set return flags
4343H JMP 00A6H ; Return to Main ROM

; =========================================================================================
; RST 7,52h Hook - LFILES function
; =========================================================================================
4346H POP PSW ; POP return address from stack...we will return manually
4347H PUSH D ; Preserve DE on STACK
4348H PUSH H ; Preserve HL on STACK
4349H PUSH PSW ; Preserve A on STACK
434AH XRA A ; Flag to generate system errors vs. printing
434BH CALL 4A85H ; Save OS's baud rate string to storage area
434EH LDES 02H ; DE = SP + 2
4350H LHLX ; Get value of HL pushed to stack above - LFILES argument pointer
4351H MOV A,M ; Get 1st byte of argument
4352H ANA A ; Test if arguement is zero
4353H JZ 436AH ; Jump to display files from current TPDD bank number if zero
4356H CPI 3AH ; Test if 1st byte is ':'
4358H JZ 436AH ; Jump to display files from current TPDD bank number if ':"
435BH CALL 4BCFH ; Evaluate expression at M-1 - Convert "0:" or "1:" to decimal
435EH MOV A,E ; Get result of evaluation
435FH CPI 02H ; Compare result for bounds
4361H JNC 4370H ; Jump to exit routine if not 0 or 1
4364H STA FCCAH ; Save as TPDD2 Bank number
4367H LDES 02H ; DE = SP + 2
4369H SHLX ; Save updated expression pointer to stack location prior to RST 7
436AH CALL 4704H ; Display / print all files and free space
436DH CALL 4AC4H ; Restore original baud settings

; =========================================================================================
; RST 7 Hook exit routine
; =========================================================================================
4370H POP PSW ; Get preserved A from stack
4371H POP H ; Get preserved HL from stack
4372H POP D ; Get preserved DE from stack
4373H POP B ; B isn't PUSHed in the Hook routines, POP the return address
4374H JMP 00A6 ; Return to the Main ROM

; =========================================================================================
; RST 7,58h Hook - KILL statement
; =========================================================================================
4377H POP PSW ; POP the return address - we will return manually
4378H CPI 09H ; Test if we found "0:" or "1:" in the DSKI$ function
437AH JNZ 4516H ; Generate FC error
437DH PUSH D ; Preserve DE on the stack
437EH PUSH H ; Preserve HL on the stack
437FH PUSH PSW ; Preserve A on the stack
4380H XRA A ; Flag to generate system errors vs. printing
4381H CALL 4A85H ; Save OS's baud rate string to storage area
4384H LXI H,FC93H ; Filename of current BASIC program
4387H CALL 4A57H ; Send Dir Reference for filename at (HL)
438AH JZ 487BH ; "FF" error if attribute byte is zero
438DH CALL 431AH ; Issue TPDD Delete file Opcode
4390H CALL 4AC4H ; Restore original baud settings
4393H JMP 4370H ; RST 7 Hook exit routine

; =========================================================================================
; RST 7,5Ah Hook - NAME statement
; =========================================================================================
4396H POP PSW ; POP the return address - we will return manually
4397H CPI 09H ; Test if we found "0:" or "1:" in the DSKI$ function
4399H JNZ 4516H ; Generate FC error
439CH PUSH D ; Preserve DE on the stack
439DH PUSH H ; Preserve HL on the stack
439EH PUSH PSW ; Preserve A on the stack
439FH XRA A ; Flag to generate system errors vs. printing
43A0H CALL 4A85H ; Save OS's baud rate string to storage area
43A3H LXI H,FC9CH ; Filename of last program loaded from tape
43A6H CALL 4A57H ; Send Dir Reference for filename at (HL)
43A9H JZ 487BH ; "FF" error if attribut byte is zero
43ACH LXI H,FCE8H ; Point to TX buffer data area (payload)
43AFH LXI D,FC9CH ; Filename of last program loaded from tape
43B2H LXI B,0009H ; Prepare to copy 9 bytes of filename
43B5H CALL 4A05H ; Move BC bytes from M to (DE) with increment
43B8H CALL 41A7H ; Rename the TPDD file whose name is in "current BASIC program"
43BBH CALL 4AC4H ; Restore original baud settings
43BEH JMP 4370H ; RST 7 Hook exit routine

; =========================================================================================
; RST 7,5Eh Hook - LOADM and RUNM statement
; =========================================================================================
43C1H POP PSW
43C2H CPI 09H ; Test if we found "0:" or "1:" in the DSKI$ function
43C4H JNZ 00A6H ; Return if not a TPDD file
43C7H POP B ; Pop return address from stack - we will jump manually to exit
43C8H PUSH H ; Preserve HL on the stack
43C9H LXI B,4F43H ; Load code for "CO" filename extension
43CCH CALL 44BAH ; Compare extension in current BASIC program filename with value in BC
43CFH JZ 487BH ; "FF" Printer not ready error
43D2H CALL 408AH ; Open TPDD file for Read Mode
43D5H LHLD FD1DH ; Get file size parameter from RX buffer
43D8H MOV A,L ; Swap endianness of file size
43D9H MOV L,H ; Move MSB to LSB
43DAH MOV H,A ; Move LSB to MSB
43DBH SHLD FCDDH ; Save endian modified length back to storage
43DEH CALL 40B6H ; Send TPDD_READ data opcode and recieve response, HL=RX buf upon return
43E1H CALL 4C6AH ; Copy CO header bytes (6) from (HL) to "active" CO Header storage area
43E4H PUSH H ; Push updated (+6) RX data pointer to stack
43E5H CALL 4C6EH ; Go print CO address, length and invocation address to LCD
43E8H LHLD FACEH ; Address of CO Header - get CO load address
43EBH PUSH H ; Push CO load address to stack
43ECH PUSH H ; Push another copy to the stack to preserve value during XTHL/POP
43EDH LHLD F5F4H ; RST 5.5 RAM Vector
43F0H XTHL ; HL <--> (SP) Load RST 5.5 RAM vector as return address
43F1H POP B ; BC now has RST 5.5 RAM Vector, HL= CO load address
43F2H DSUB ; Test if CO load address is less that RST 5.5 RAM address
43F3H JC 488AH ; Trying to clober RST5.5 RAM vectors - generate RAM full error
43F6H POP D ; Get CO load address saved on stack
43F7H POP H ; Get Updated (+6) RX data pointer from stack
43F8H LDA FD03H ; Load RX Length byte from RX data buffer
43FBH SUI 06H ; Subtract CO header length from packet data length
43FDH MOV C,A ; Save packet data length in BC
43FEH MVI B,00H ; Make MSB of BC zero
4400H CALL 4135H ; Write BC bytes from M to DE and subtract BC from total file size
4403H CALL 4AC4H ; Restore original baud settings
4406H LXI H,251AH ; Load new return address in Main ROM
4409H PUSH H ; Push new return address to stack
440AH JMP 00A6H ; Jump to Main ROM

; =========================================================================================
; RST 7,5Ch Hook - SAVEM statement
; =========================================================================================
440DH POP PSW ; POP the return address - we will return elsewhere
440EH CPI 09H ; Test if we found "0:" or "1:" in the DSKI$ function
4410H JNZ 00A6H ; Return if not a TPDD file
4413H CALL 4C72H ; Process SAVEM arguments for address, length and entry point
4416H LXI B,4F43H ; Load code for "CO" file extension
4419H CALL 44BAH ; Compare ext. in current BASIC program with BC, send dir ref. if match
441CH JNZ 487EH ; Jump to generate File Exists Error if found
441FH MVI A,01H ; Set open mode for new file
4421H STA FCD6H ; Save open mode to input variable
4424H LHLD FAD0H ; Length of last program loaded/saved to tape
4427H LXI B,0006H ; Prepare to add CO header size (6 bytes) to required length
442AH PUSH B ; Push CO header length to stack
442BH DAD B ; Add CO header size to required length
442CH PUSH H ; Push updated file length to stack
442DH CALL 4101H ; Test free Disk space and issue TPDD_OPEN request
4430H POP H ; Get updated file length from stack
4431H SHLD FCD5H ; Save as lenght of file being saved / loaded
4434H POP B ; Get CO header length from stack
4435H LXI H,FACEH ; Load address of "active" CO header block
4438H LXI D,FD04H ; DE points to the data area in RX buffer
443BH CALL 4A05H ; Move BC bytes from M to (DE) with increment
443EH LHLD FD04H ; DE points to the data area in RX buffer
4441H LXI B,007AH ; Prepare to write 122 bytes of data to next location in RX buffer
4444H CALL 40D8H ; Write 122 bytes from (HL) and send TPDD_WRITE to TPDD
4447H CALL 4AC4H ; Restore original baud settings
444AH LXI H,0501H ; Load return address in Main ROM - vector to BASIC ready
444DH PUSH H ; Push return address to stack
444EH JMP 00A6H ; Return to Main ROM

; =========================================================================================
; RST 7,1Ah Hook - RUN statement
; =========================================================================================
4451H POP PSW
4452H CPI 09H ; Test if we found "0:" or "1:" in the DSKI$ function
4454H JNZ 00A6H ; Return if not TPDD file
4457H POP B ; Get return address from stack
4458H POP PSW ; Get 1st byte of RUN statement argument
4459H PUSH PSW ; Put back the data we stole
445AH PUSH B ; Put back the return address
445BH JZ 00A6H ; Return if there were no arguments to the RUN statement
445EH SBB A ; Clear zero flag (C is set and A=0xFF)
445FH STA FC92H ; Save in flag to execute BASIC program (non-zero = execute)
4462H LXI B,4142H ; Load code for "BA" BASIC file extension
4465H CALL 44BAH ; Compare ext. in current BASIC program with BC, send dir ref. if match
4468H JZ 487BH ; Jump to error if not "BA" or " " - generate "FF" error
446BH LHLD FD1DH ; Get file size parameter from RX buffer
446EH MOV C,H ; Swap endianness of file size
446FH MOV B,L ; Swap LSB to MSB
4470H MOV H,B ; Copy file size parameter back to HL
4471H MOV L,C ; Copy LSB of file size to HL
4472H SHLD FCDDH ; Store length of file
4475H CALL 44ABH ; Call NEW statement, upon return HL=address of last variable assigned
4478H INX H ; Increment to free memory space
4479H SHLD FCE2H ; Save as address of file being loaded/saved/etc.
447CH LHLD FCDDH ; Get disk file length
447FH PUSH H ; Save file length on stack
4480H PUSH H ; Push file length to stack to copy to BC
4481H POP B ; Pop file length to BC
4482H CALL 411EH ; Insert BC spaces at address of RAM file being loaded/run
4485H POP D ; Get length of disk file from stack
4486H LHLD FBAEH ; Load Start of DO files pointer
4489H DAD D ; Increment Start of DO files pointer by disk file length
448AH SHLD FBAEH ; Save updated Start of DO files pointer
448DH LHLD FAD8H ; Load pointer to address used for RAM Input processing
4490H DAD D ; Increment pointer by disk file length
4491H SHLD FAD8H ; Save updated RAM Input processing pointer
4494H CALL 4AC4H ; Restore original baud settings
4497H XRA A ; Clear zero flag and A
4498H LXI H,23F5 ; Load address in Main ROM to configure and execute current BASIC programH
449BH PUSH H ; Push return address to stack
449CH JMP 00A6H ; Return to Main ROM

; =========================================================================================
; Call "BASIC NEW" helper routine. This get's copied to RAM below.
; =========================================================================================
449FH XRA A ; Prepare to switch to Main ROM
44A0H OUT E0H ; Switch to Main ROM
44A2H CALL 20FFH ; Call BASIC NEW statement
44A5H CALL FAA4H ; Switch back to OptROM
44A8H JMP 4478H ; Jump back into RST 7,1Ch Hook - RUN statement

; =========================================================================================
; Copy "BASIC NEW" helper routine to RAM and Jump to it --- Call Main ROM's NEW statement
; =========================================================================================
44ABH LXI H,449FH ; Point to helper function to copy to RAM
44AEH LXI D,FD89H ; RAM destination
44B1H LXI B,000CH ; Length of helper funciton
44B4H CALL 4A05H ; Copy helper to RAM
44B7H JMP FD89H ; Branch to helper function

; =========================================================================================
; Compare current BASIC program file extension with value in BC or " "
; =========================================================================================
44BAH PUSH PSW ; Preserve A on Stack
44BBH PUSH H ; Preserve HL on Stack
44BCH PUSH D ; Preserve DE on Stack
44BDH PUSH B ; Preserve comparison file extension on Stack
44BEH LHLD FC99H ; Load 2 extension field bytes of current BASIC program name
44C1H LXI D,2020H ; Load 2 spaces (0x20) into DE
44C4H RST 3 ; Test if filename extension in current BASIC program is " "
44C5H JZ 44D6H ; Jump if current BASIC program filename extension is " "
44C8H POP D ; Get comparison file extension from stack into DE
44C9H PUSH D ; Push file extension back to stack for storage
44CAH RST 3 ; Test if current BASIC program filename extension matches BC
44CBH JZ 44D6H ; Jump if current BASIC program filename extension matches BC
44CEH POP B ; Get BC back off stack
44CFH POP D ; Recover DE from stack
44D0H POP H ; Recover HL from stack
44D1H POP PSW ; Recover A & flags from stack
44D2H POP B ; Pop return address - File extension doesn't match so don't run
44D3H JMP 00A6H ; Return to Main ROM

; =========================================================================================
; Store expected extension (on stack) to current BASIC program and send dir reference for
; the disk file
; =========================================================================================
44D6H POP H ; Get expected file extension "BA" or "CO" from stack
44D7H SHLD FC99H ; Save to 2 extension field bytes of current BASIC program name
44DAH POP D ; Restore DE from stack
44DBH POP H ; Restore HL from stack
44DCH POP PSW ; Restore A from stack
44DDH XRA A ; Flag to generate system errors vs. printing
44DEH CALL 4A85H ; Save OS's baud rate string to storage area
44E1H LXI H,FC93H ; Filename of current BASIC program
44E4H JMP 4A57H ; Send Dir Reference for filename at (HL)

; =========================================================================================
; RST 7,16h Hook - SAVE statement
; =========================================================================================
44E7H POP PSW ; POP return address, we will return manually
44E8H CPI 09H ; Test if we found "0:" or "1:" in the DSKI$ function
44EAH JNZ 00A6H ; Return if not a TPDD file
44EDH LXI B,4142H ; Load code for "BA" basic extension
44F0H CALL 44BAH ; Compare extension in current BASIC program filename with value in BC
44F3H JNZ 487EH ; File Exists Error
44F6H CALL 4C66H ; Update line addresses for current BASIC program
44F9H LHLD F67CH ; Start of BASIC program pointer
44FCH XCHG ; HL <--> DE DE=BASIC program strt, HL=BASIC program end
44FDH RST 3 ; Compare DE and HL
44FEH JZ 450FH ; Vector to BASIC ready - print Ok if BASIC start=BASIC end
4501H PUSH D ; Save start of BASIC program to stack
4502H POP B ; POP start of BASIC program from stack
4503H DSUB ; Subtract BASIC start address from BASIC end address
4504H MVI A,01H ; Set file open mode for new file
4506H STA FCD6H ; Save open mode to pass to function
4509H CALL 40C8H ; Write HL bytes of data from (DE) to TPDD
450CH CALL 4AC4H ; Restore original baud settings
450FH LXI H,0502H ; Load address in Main ROM of Vector to BASIC ready - print Ok
4512H PUSH H ; Push new return address to stack
4513H JMP 00A6H ; Return to Main ROM

; =========================================================================================
; Return to Main ROM's Generate FC Error routine
; =========================================================================================
4516H LXI H,08DBH ; Load address of Generate FC error routine
4519H PUSH H ; Push return address to the stack
451AH JMP 00A6H ; Return to Main ROM

; =========================================================================================
; RST 7,30h Hook - OPEN/CLOSE/READ/WRITE/LINE INPUT statement
; =========================================================================================
451DH XRA A ; Clear A to set print error flag
451EH STA FCD2H ; Set flag to generate system errors vs. print
4521H POP PSW ; POP return address ... returning manually
4522H SHLD FCCEH ; Save HL in Stack pointer upon entry location
4525H PUSH D ; Preserve DE on stack
4526H PUSH H ; Preserve HL on stack
4527H PUSH PSW ; Preserve A on stack
4528H LXI D,0004H ; Offset of the file descriptor address MSB
452BH DAD D ; Point to the file descriptor address MSB
452CH MOV A,M ; Get MSB address of FD
452DH CPI 09H ; Test if we found "0:" or "1:" in the DSKI$ function
452FH JZ 4538H ; Jump to process the sub-operation code if it's a TPDD file

; =========================================================================================
; RST 7,30h Hook exit routine
; =========================================================================================
4532H POP PSW ; Restore A from stack
4533H POP H ; Restore HL from stack
4534H POP D ; Restore DE from stack
4535H JMP 00A6H ; Return to Main ROM

; =========================================================================================
; Test the RST 7,30h sub-operation code and vector to the proper handler function
; =========================================================================================
4538H POP PSW ; Retrieve A from the stack - contains sub-operation code
4539H PUSH PSW ; Restore to stack
453AH CPI 00H ; Test for OPEN sub-operation
453CH JZ 455CH
453FH CPI 02H ; Test for CLOSE sub-operation
4541H JZ 45E8H
4544H CPI 04H ; Test for PRINT # sub-operation
4546H JZ 46B0H
4549H CPI 06H ; Test for EOF sub-operation
454BH JZ 4607H
454EH CPI 08H ; Test for LINE INPUT sub-operation
4550H JNZ 4532H
4553H LDES 06H ; Get stack location upon entry (we pushed 3 times = 6 bytes) in DE
4555H LXI H,161BH ; Not an operation we care about, load address for "Special RAM IO" routine
4558H SHLX ; Replace our return address so we return to "Special RAM IO" routine instead
4559H JMP 4532H ; Jump to RST 7,32h exit routine

; =========================================================================================
; RST 7,30h OPEN sub-operation
; =========================================================================================
455CH XRA A ; Generate system errors vs. printing
455DH CALL 4A85H ; Save OS's baud rate string to storage area
4560H LXI H,FC99H ; Load address of 1st extension byte of current BASIC program filename
4563H MOV A,M ; Get 1st byte of file extension from current BASIC program
4564H CPI 20H ; Test if opening a file with no extension
4566H JZ 456EH ; Branch to proivde "DO" default extension if non provided
4569H CPI 44H ; Test if A is 'D' - opening a "DO" file
456BH JNZ 488DH ; Generate system error 0x0C - ID Error
456EH MVI M,44H ; Change 1st extension byte to 'D'
4570H INX H ; Increment to 2nd extension byte
4571H MVI M,4FH ; Change 2nd extension byte to 'O'
4573H LXI H,FC93H ; Filename of current BASIC program
4576H CALL 4A57H ; Send Dir Reference for filename at (HL)
4579H MOV C,A ; Move attribute byte to C
457AH CALL 465BH ; Calculate offset of BASIC instruction file # EOF marker
457DH MVI M,00H ; Set EOF marker to zero - not EOF
457FH POP H ; POP PSW and discard
4580H POP H ; Restore address of FD control
4581H POP D ; Restore DE
4582H PUSH D ; Save DE back to stack
4583H PUSH H ; Save FD control address back to stack
4584H MOV D,C ; Save TPDD file attribute byte to D
4585H MOV A,E ; Move open mode to A (8=Append,1=Read,2=Write)
4586H ANI 07H ; Mask all but lower 3 bits so we get 0, 1, or 2
4588H LXI H,4AE4H ; Get address of RST 7,32h open mode to TPDD Open mode mapping
458BH MOV C,A ; Save mapping mode table offset to C
458CH MVI B,00H ; Clear MSB of offset for 16-bit add
458EH DAD B ; Calculate index address into mapping table
458FH MOV A,M ; Load TPDD open mode from mapping
4590H DCR A ; Test if TPDD open mode is Write
4591H JZ 45CDH ; Jump if opening for write mode
4594H DCR A ; Test if TPDD open mode is Append
4595H JNZ 45E0H ; Jump to open TPDD for Read mode if not zero
4598H LDA FD1CH ; Load attribute byte from RX buffer
459BH ANA A ; Opening for Append, test if file already exists
459CH JNZ 45A1H ; Jump to perform open for append if file already exists
459FH INX H ; Opening for append but file doesn't exist, increment mapping to Write
45A0H INX H ; Increment again to skip "read" mapping in table

; =========================================================================================
; Open TPDD file with open mode as specified by RST 7,32h mapping table
; =========================================================================================
45A1H MOV A,M ; Reload the TPDD open mode from the mapping table
45A2H STA FCE8H ; Point to TX buffer data area (payload)
45A5H LXI H,0101H ; Load TPDD_OPEN opcode in HL
45A8H CALL 409BH ; Send Request in HL and await response
45ABH LHLD FCCEH ; Get address of FD control
45AEH LXI D,0007H ; Load offset of write buffer length within FD control
45B1H DAD D ; Point to write buffer length within FD control
45B2H XRA A ; Clear A
45B3H MOV M,A ; Set the write buffer length to zero - just opened the file
45B4H INX H ; Increment to write buffer output pointer address
45B5H MOV D,H ; Save HL to DE to update write buffer output pointer
45B6H MOV E,L ; Save LSB of HL to DE
45B7H INX H ; Increment to MSB of write buffer output pointer
45B8H INX H ; Increment to write buffer location
45B9H SHLX ; Reset write buffer output poiner to beginning of buffer
45BAH POP H ; Restore address of FD control
45BBH POP D ; Restore DE from stack
45BCH MOV A,E ; Load RST 7,32h open mode into A
45BDH CPI 08H ; Test if open mode is Append
45BFH JNZ 45C4H ; Jump to retain open mode if not append
45C2H MVI E,02H ; Change Append open mode value to "Write"
45C4H MOV M,E ; Save open status to FD control
45C5H XTHL ; HL <--> (SP) Prepare to change our return address, saving HL
45C6H LXI H,14DEH ; Load new return address in ROM "LCD and PRT file open" routine
45C9H XTHL ; Put return address back to stack, restoring HL
45CAH JMP 00A6H ; Return to the new address in LCD and PRT file open routine in Main ROM

; =========================================================================================
; RST 7,30h open file for write mode. The Attribute byte from the Dir Ref opcode is in D
; =========================================================================================
45CDH MOV A,D ; Get the File attribute byte from the Dir Reference operation
45CEH ORA A ; Test if the file exists (will be 'F' if the file exists)
45CFH JZ 45A1H ; Jump to create the file if it doesn't already exist
45D2H PUSH H ; Save HL to the stack for restoration
45D3H CALL 431AH ; Issue TPDD Delete file Opcode - Overwriting existing file
45D6H LXI H,FC93H ; Filename of current BASIC program
45D9H CALL 4A57H ; Send Dir Reference for filename at (HL) - Need new Dir Ref
45DCH POP H ; Restore HL from stack
45DDH JMP 45A1H ; Open TPDD file with open mode as specified by RST 7,32h mapping table

; =========================================================================================
; RST 7,30h open file for read mode. Ensure the file exists via the attribute byte in D
; =========================================================================================
45E0H MOV A,D ; Load the file attribute byte from the Dir Ref opcode
45E1H ORA A ; Test if attribute byte is zero
45E2H JZ 487BH ; Generate "FF" error if file doesn't exist
45E5H JMP 45A1H ; Jump to open the file

; =========================================================================================
; RST 7,30h Sub command - CLOSE FILE
; =========================================================================================
45E8H POP PSW ; Retrieve A PUSHed by RST 7,32a entry
45E9H POP H ; Retrieve HL
45EAH POP D ; Retrieve DE
45EBH PUSH H ; Save FD control pointer to stack
45ECH MOV A,M ; Get FD control status byte
45EDH MVI M,00H ; Change FD control status to "closed"
45EFH CPI 02H ; Test if status
45F1H CZ 46DDH ; Call flush output buffer routine if opened for write mode
45F4H LXI H,0002H ; Load TPDD_CLOSE opcode into HL
45F7H CALL 409BH ; Send Request in HL and await response
45FAH CALL 4AC4H ; Restore original baud settings
45FDH POP H ; Restore FD control pointer
45FEH XTHL ; HL <--> (SP) so we can preserve HL through POP
45FFH POP H ; Pop return address (actually FD control address) from stack
4600H LXI H,4D59H ; Load new reuturn address - LCD, CRT, and LPT file close routine
4603H PUSH H ; Push new return address to stack - not returning to caller
4604H JMP 00A6H ; Return to Main ROM

; =========================================================================================
; RST 7,30h Sub command - EOF
; =========================================================================================
4607H CALL 465BH ; Calculate offset of BASIC instruction file # EOF marker
460AH MOV A,M ; Get the current EOF marker
460BH MVI M,00H ; Set the EOF marker to zero to reset it
460DH ANA A ; Test if at EOF for this file
460EH JNZ 4627H ; Jump if EOF marker for this file not zero
4611H LHLD FCCEH ; Get address of FD control
4614H LXI B,0007H ; Offset of write buffer length within FD control
4617H DAD B ; Point to write buffer length
4618H MOV A,M ; Get current write buffer length
4619H INX H ; Point to LSB of read/write buffer output pointer within FD control
461AH PUSH H ; Save address of read/write buffer output pointer to stack
461BH ANA A ; Test if data left in the buffer
461CH CZ 4663H ; Call to read more data from TPDD if buffer empty
461FH POP D ; Restore address of read/write output buffer within FD control
4620H LHLX ; Get current read/write pointer location from FD control
4621H MOV A,M ; Read the next byte from the buffer
4622H INX H ; Increment buffer pointer to the next byte
4623H SHLX ; Save read/write buffer pointer back to FD control
4624H DCX D ; Decrement back to read/write buffer length within FD control
4625H XCHG ; HL <--> DE Prepare to update buffer length
4626H DCR M ; Decrement length since we just read a byte

; =========================================================================================
; Test if EOF for BASIC file #
; =========================================================================================
4627H CPI 1AH ; Test if byte is EOF marker
4629H STC ; Ensure the Carry flag is set
462AH CMC ; And now clear it to indicate not EOF
462BH JNZ 4633H ; Jump if not at end of file
462EH CALL 465BH ; Calculate offset of BASIC instruction file # EOF marker
4631H MOV M,A ; Save EOF marker for this file #
4632H STC ; Set Carry to indicate EOF

; =========================================================================================
; Save EOF status
; =========================================================================================
4633H PUSH PSW ; Save EOF indication in Carry flag and marker value to stack
4634H LDES 10H ; Load offset to our return address (we PUSHed a bunch to the stack)
4636H LHLX ; Load HL with our return address from the stack
4637H LXI B,189AH ; Load address of return within EOF function
463AH DSUB ; Test if we were called from the EOF function
463BH JNZ 464FH ; Jump if not called from ROM EOF function - don't to EOF logical testing
463EH CALL 465BH ; Calculate offset of BASIC instruction file # EOF marker
4641H POP PSW ; Retreive EOF and marker value from stack
4642H MOV M,A ; Save the marker value to the file # marker storage location
4643H MOV C,A ; Save marker value in C
4644H SBB A ; Subtract with borrow (C was set if EOF)
4645H CALL 4BCBH ; Call into SGN function to set FAC1 with sign of A (EOF test)
4648H LDES 12H ; Prepare to "POP" 6 register pairs from the stack all at once
464AH XCHG ; HL <--> DE HL now has new stack value
464BH SPHL ; HL <--> SP "POP" 6 values from the stack
464CH JMP 00A6H ; Return to Main ROM

; =========================================================================================
; Non-EOF function call return
; =========================================================================================
464FH POP PSW ; Restore PSW with EOF indication (C flag)
4650H POP H ; Pop old PSW - we don't want it
4651H POP H ; Resore HL from stack
4652H POP D ; Restore DE from stack
4653H XTHL ; Push HL to stack to set new return address
4654H LXI H,4E8AH ; Load address of a "Stack frame retrun" routine
4657H XTHL ; Stack gets new return address, restore HL
4658H JMP 00A6H ; Return to the new address (not returning to parent)

; =========================================================================================
; Calculate offset of BASIC instruction file # EOF marker
; =========================================================================================
465BH LHLD FAA2H ; Get file # of active BASIC instruction (EOF, LINE INPUT, etc.)
465EH LXI D,FA91H ; Load base address of file status array
4661H DAD D ; Add offset to base of file status byte array
4662H RET

; =========================================================================================
; RST 7,30A Read data from server (TPDD) into FD file buffer
; =========================================================================================
4663H LXI H,0003H ; Load TPDD_READ opcode in HL
4666H CALL 4822H ; Send TPDD Command/Len in HL
4669H CALL 47CCH ; Receive a packet
466CH LDA FD02H ; Get response byte from storage for RX packet
466FH CPI 10H ; Test for valid read file response
4671H JNZ 469EH ; Branch if not valid read from file response
4674H LDA FD03H ; Get length of read from RX buffer
4677H LHLD FCCEH ; Get pointer to FD control
467AH LXI D,0008H ; Offset of address of read/write buffer relative to FD control
467DH DAD D ; Point to address of read/write buffer within FD control
467EH PUSH H ; Save address of read/write buffer to stack
467FH MOV D,H ; Move address of read/write buffer to DE for update
4680H MOV E,L ; Move LSB
4681H INX H ; Increment to MSB of read/write buffer address in FD control
4682H INX H ; Increment to read/write buffer
4683H SHLX ; Reset pointer to read/write buffer - we just read more data
4684H LXI D,FD04H ; DE points to the RX data in the buffer
4687H XCHG ; HL <--> DE Prepare to move data from RX buffer to FD buffer
4688H MOV C,A ; Move the RX data length to C
4689H MVI B,00H ; Clear MSB of BC count
468BH CALL 4A05H ; Move BC bytes from M to (DE) with increment - copy to FD buffer
468EH LDA FD03H ; Get length of RX read data again
4691H CPI 80H ; Test for maximum read length
4693H JZ 469AH ; If maximum read, skip writing EOF marker to read/write buffer
4696H XCHG ; HL = destination address in FD buffer
4697H MVI M,1AH ; Terminate .DO file in FD read/write buffer with EOF marker
4699H INR A ; Increment length to reflect EOF marker

; =========================================================================================
; RST 7,32A Read - not max read size
; =========================================================================================
469AH POP H ; Get address of read/write buffer in FD control from stack
469BH DCX H ; Decrement to FD control read/write buffer length location
469CH MOV M,A ; Save length of data in read/write buffer to FD control
469DH RET

; =========================================================================================
; RST 7,32A Read - unsuccessful TPDD read
; =========================================================================================
469EH LHLD FCCEH ; Get address of FD control
46A1H LXI D,0007H ; Load offset of output buffer count in FD control
46A4H DAD D ; Point to output buffer length in FD control
46A5H MVI M,01H ; Set read/write buffer length to 1 to indicate EOF marker
46A7H INX H ; Increment to LSB of read/write buffer output address in FD control
46A8H MOV D,H ; Save HL in DE for update of read/write buffer output in FD control
46A9H MOV E,L ; Save LSB of HL to DE
46AAH INX H ; Increment to MSB of read/write buffer in FD control
46ABH INX H ; Increment to the FD read/write buffer
46ACH SHLX ; Reset the FD control read/write buffer pointer to begining of buffer
46ADH MVI M,1AH ; Write an EOF marker to the buffer
46AFH RET

; =========================================================================================
; RST 7,32h PRINT # sub-operation
; =========================================================================================
46B0H LHLD FCCEH ; Pointer to FD control
46B3H LXI D,0007H ; ?Offset to output byte count
46B6H DAD D ; Get pointer to file's output byte count
46B7H MOV A,M ; Load byte count of pending bytes to write
46B8H CPI 80H ; Test if 128 bytes to write
46BAH CZ 46DDH ; Call routine to flush output buffer to file
46BDH POP PSW ; Restore A from stack (from RST 7,32h entry)
46BEH POP H ; Restore HL from stack
46BFH POP D ; Restore DE from stack
46C0H POP H ; Pop the return address - we will return via JMP
46C1H POP PSW ; Get the caller's A so we know what byte is being written
46C2H PUSH PSW ; Put it back on the stack...it isn't ours
46C3H CPI 1AH ; Test if writing an EOF marker to the file
46C5H JZ 46D6H ; Jump if writing EOF marder to the file - don't actually write it
46C8H LHLD FCCEH ; Get address of FD control
46CBH LXI D,0007H ; Get offset of output buffer length within FD control
46CEH DAD D ; Point to output buffer length address
46CFH INR M ; Increment the output buffer length - writing 1 byte
46D0H INX H ; Point to current file location pointer in FD control
46D1H XCHG ; HL <--> DE Move address of file location pointer to DE
46D2H LHLX ; Load current file location address to HL
46D3H MOV M,A ; Save the byte in the buffer (RX buffer for subsequent write)
46D4H INX H ; Increment the curent file location pointer (we will flush later)
46D5H SHLX ; Save the update current file location pointer to FD control
46D6H LXI H,14EAH ; Load address to update automatic timer and POP regs from the stack
46D9H PUSH H ; Push new return address. We will return to the parent's caller
46DAH JMP 00A6H ; Return to Main ROM
</pre>

Navigate to:
* [[Dissasembly of RAM and ROM versions of TS-DOS]]
* [[M100 TS-DOS ROM OptROM Support]]
* [[M100 TS-DOS ROM UI Code]]
* [[M100 TS-DOS ROM TPDD Protocol]]
* [[M100 TS-DOS ROM Compression]]
* [[M100 TS-DOS ROM Cold Boot Recovery]]

M100 TS-DOS ROM UI Code

2009-04-03T07:57:22Z

Kpettit:

M100 TS-DOS ROM OptROM Support

2009-04-03T07:55:16Z

Kpettit: /* TS-DOS Model 100/102 ROM OptROM Support */

== TS-DOS Model 100/102 ROM OptROM Support ==

This code defines the variables used throughout the TS-DOS application as well as the support routines needed to navigate between the Main ROM and the Option ROM (most of them). Also included is the TS-DOS startup code. The assembly labels defined are open for discussion and have not been applied to any of the disassembled code yet.

<pre>
=========================================================================================
; TS-DOS M100 ROM version Disassembly
;
; Initial Disassembly By Kenneth D. Pettit
; March, 2009
;
; =========================================================================================

; =========================================================================================
; Variables in ALTLCD buffer
; =========================================================================================
NB_CUR_DIR equ FCC0H ; NADSBox current directory ("MYFILE.<> ")
TPDD_BANK equ FCCAH ; TPDD2 Bank (side)
NB_TPDD_FLG equ FCCBH ; NADSBox/Desklink/TPDD2 flag (0=TPDD, 1=TPDD2, 2=NADSBox)
LAST_TAG equ FCCCH ; Tag/Untag last operation code
CUR_FILE equ FCCDH ; Currently selected file index on UI (1 based)
LJ_SP equ FCCEH ; Stack pointer upon entry for Long Jump
LJ_RET equ FCD0H ; Return vector for Long Jump "RETURN"
ERR_MODE equ FCD2H ; Print Error Messages flag, 1=Print, 0=Generate System Error
FDC_OPCODE equ FCD3H ; FDC Emulation mode opcode
CUR_PAGE equ FCD4H ; Current page of files being displayed (0 based)
TMP_FILE_IDX equ FCD5H ; Currently selected file index on UI - temp
FILE_COUNT equ FCD6H ; Count of files currently displayed on LCD
MAX_FILES equ FCD7H ; Maximum files that fit on the LCD
DISP_MODE equ FCD9H ; RAM / Disk Display mode (0=RAM, 1=DISK)
SKIP_PAGE equ FCDAH ; TPDD "skip page" count (number of pages to read and discard)
FILE_LEN equ FCDBH ; Pointer to "Current file" length bytes (in keyboard buffer)
PHYS_SCTR equ FCDDH ; FDC Emulation Physical Sector Number / Active File Length LSB
LOG_SCTR equ FCDEH ; FDC Emulation Logical Sector Number / Active File Length MSB
KEY_TYPE equ FCDFH ; Storage for FDC emulation / New file type code / Keypress storage
FILE_ADDR equ FCE0H ; Address of file being displayed/printed/loaded/saved
FILE_BUFF equ FCE2H ; Pointer for TPDD direct read data / address of file being read/written
TX_PKT_BUF equ FCE6H ; Storage for TX packets (28 bytes)
RX_PKT_BUF equ FD02H ; Storage for RX packets (130 bytes ??)

; =========================================================================================
; Main Entry point when called from "CALL 63013,1"
; =========================================================================================

.org 0000H

0000H JMP 00B2H ; Jump to entry point handler

; =========================================================================================
; Pop registers after we power back up from a powerdown (I think)
; =========================================================================================
0003H POP H
0004H POP D
0005H POP B
0006H POP PSW
0007H RET

; =========================================================================================
; RST 1 - Call Main ROM at location whose address follows RST 1 opcode
; =========================================================================================
0008H (C3H) JMP 0080H ; BASIC statement keyword table END to NEW

; =========================================================================================
; RST 2 - Call Main ROM's RST 2 routine
; =========================================================================================
0010H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
0011H DW 0010H ; Call the Main ROM's RST 2 function
0013H (C9H) RET

; =========================================================================================
; RST 3 routine - Compare HL and DE
; =========================================================================================
0018H JMP 006CH ; Jump to comparison routine

; =========================================================================================
; Return to Main ROM. After issuing the OUT E0H, we will be in Main ROM. The next opcode
; in Main ROM after this OUT statement occurs will be a RET (part of RST 1). We have
; PUSHed a return address to the stack, so the main ROM's RET instruction will get us
; where to intend to go.
; =========================================================================================
001BH OUT E0H ; Send A to the ROM bank port to switch to Main ROM
001DH RET ; Should never execute this instruction, but just in case

; =========================================================================================
; Send a space to the screen/printer - Not called from anywhere. Copy of Main ROM.
; =========================================================================================
001EH (3EH) MVI A,20H ; Prepare to print a SPACE

; =========================================================================================
; RST 3 routine - Send character in A to the screen / printer
; =========================================================================================
0020H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
0021H DW 0020H ; Main ROM's RST 3 routine
0023H (C9H) RET

; =========================================================================================
; Power down TRAP. Let Main ROM deal with it.
; =========================================================================================
0024H DI ; Disable interrupts while we jump
0025H CALL 0097H ; Jump to Main ROM's RST handler for this vector
0028H POP H
0029H JMP 0003H ; Pop regs after we power back up from a power-down?

; =========================================================================================
; Hardware Interrupt - Let Main ROM deal with it - Bar Code Reader
; =========================================================================================
002CH DI ; Disable interrupts while we jump
002DH CALL 0097H ; Jump to Main ROM's RST handler for this vector

; =========================================================================================
; Return from Main ROM hook in RAM returns here via RST 6
; =========================================================================================
0030H POP PSW ; Cleanup stack
0031H POP PSW ; Cleanup stack
0032H RET ; Return to OptROM execution point

0033H NOP ; Filler

; =========================================================================================
; Hardware Interrupt - Let Main ROM deal with it - RS232 character pending
; =========================================================================================
0034H DI ; Disable interrupts while we jump
0035H CALL 0097H ; Jump to Main ROM's RST handler for this vector
0038H JMP 00A6H ; Stack cleanup

003BH NOP ; UNUSED - filler

; =========================================================================================
; Hardware Interrupt - Let Main ROM deal with it - Timer background task
; =========================================================================================
003CH DI ; Disable interrupts
003DH CALL 0097H ; Jump to Main ROM's RST handler for this vector

; =========================================================================================
; This routine gets copied to RAM to be used for switching back to the TS-DOS ROM after
; calling a routine in the Main ROM.
; =========================================================================================
0040H PUSH PSW ; Preserve the PSW
0041H LDA FF45H ; Contents of port E8H
0044H INR A ; Prepare to switch to OptRom
0045H OUT E0H ; Switch to OptRom
0047H RST 6 ; Get sign of FAC1

; =========================================================================================
; This routine gets copied to RAM and appears to detect the presence of the TS-DOS ROM
; after power-up and copies the original "External ROM" detection routine to RAM
; if the TS-DOS ROM is no longer present. At least I think that's what it's doing.
; =========================================================================================
0048H LXI D,F605H ; Copy address for "Ext ROM detect" routine
004BH INR A ; Set bit to enable OptROM
004CH OUT E0H ; Switch to OptROM
004EH XRA A ; Prepare to switch back to Main ROM
004FH LHLD 0049H ; Load target address of the LXI D instruction above
0052H OUT E0H ; Switch back to Main ROM
0054H RST 3 ; Compare DE and HL - Test if OptROM is TS-DOS
0055H CPI 01H ; Test for TS-DOS ROM
0057H RC ; Return if TS-DOS ROM
0058H LXI H,111DH ; Load "Return" address to the CALL below
005BH SHLD FAE0H
005EH SHLD F5F2H ; Save a "Restart signature" ???
0061H CALL 2905H ; Copy the DB number of bytes from the DW address to (DE)
0064H DB 24H ; ....copy 24H bytes
0065H DW 036FH ; ....from ROM addres 036F (external ROM detect)
0067H RST 0 ; I'm not sure it it every actually returns here or not
0068H NOP
0069H CALL FAA4H ; Call our installed RAM hook to return to TS-DOS

; =========================================================================================
; Compare HL and DE - called by the RST 3 routine
; =========================================================================================
006CH MOV A,H ; Move H into A for comparison
006DH SUB D ; Compare MSB first
006EH RNZ ; Return if no match
006FH MOV A,L ; Now move L into A
0070H SUB E ; Compare LSB
0071H RET ; Return with flags set

; =========================================================================================
; Copy 8 bytes from DE to HL
; =========================================================================================
0072H LXI B,0008H ; Prepare to copy 8 bytes

; =========================================================================================
; Copy BC bytes from DE to HL
; =========================================================================================
0075H LDAX D ; Load value from (DE)
0076H MOV M,A ; Save value to (HL)
0077H INX D ; Increment DE
0078H INX H ; Increment HL
0079H DCX B ; Decrement counter
007AH MOV A,B ; Prepare to test counter for zero
007BH ORA C ; Test counter for zero
007CH JNZ 0075H ; Keep looping until 8 bytes copied
007FH RET

; =========================================================================================
; Handle the RST 1 routine. Read the Main ROM address from the 2 bytes after the RST 1
; =========================================================================================
0080H SHLD F9B2H ; Save HL off in "RickY" Cat entry so we don't clobber it
0083H POP H ; Get out return address (location of the ROM address to call
0084H PUSH D ; Push the return address back to the stack as storage
0085H MOV E,M ; Get LSB of the ROM address to call
0086H INX H ; Point to MSB of ROM address to call
0087H MOV D,M ; Get MSB of the ROM address to call
0088H INX H ; Point to return address after the RST 1 DB address
0089H XTHL ; Put the return address on the stack so we return after the RST 1
008AH XCHG ; Now get the address within ROM to call
008BH PUSH H ; Push the target ROM address to the stack so we "RETurn" there
008CH LXI H,FAA4H ; Load address of our RAM hook to switch back to our ROM bank and RET
008FH XTHL ; Push that address on the stack for after the ROM call is complete
0090H PUSH H ; Now put the ROM address back on the stack so we will RET there
0091H LHLD F9B2H ; Restore HL from temp storage in "RickY"
0094H JMP 00A6H ; Branch to switch to Main ROM and "RET" to the address we pushed

; =========================================================================================
; RST handler for calling the Main ROM's RST handlers. This routine restores the original
; RST vector address to the stack, and jumps to the Main ROM's RST routine while
; preserving all register values.
; =========================================================================================
0097H SHLD F9B4H ; Save HL temporarily (somewhere in RickY's name)
009AH LXI H,FAA4H ; Point to our RAM hook for returning to TS-DOS
009DH XTHL ; Put the hook address as the return address on the stack
009EH DCX H ; Decrement the return address by 4
009FH DCX H ; ...this will result in the starting address of the RST
00A0H DCX H ; ...that brought us here
00A1H DCX H
00A2H PUSH H ; Push the RST vector address to the stack
00A3H LHLD F9B4H ; Restore HL upon entry
00A6H PUSH PSW ; Save A to the stack
00A7H PUSH H ; Save the HL to the stack so we can preserve through XTHL
00A8H LXI H,1488H ; Load a RETurn address in the Main ROM (a POP PSW & RET)
00ABH XTHL ; Push the address and get HL back
00ACH LDA FF45H ; Contents of port E8H - prepare for jump to Main ROM
00AFH JMP 001BH ; Jump to Main ROM & our custom "RET" address in the ROM

; =========================================================================================
; Manual invocation entry point. This is where we jump when "CALL 63013,1" is invoked
; =========================================================================================
00B2H DI ; Disable interrupts so nobody bugs us yet
00B3H CPI 08H ; Check the invocation parameter to test for recovery request
00B5H JNC 0100H ; Jump to test for recovery mode
00B8H MOV B,A ; Save the calling paramter to B
00B9H PUSH B ; Save BC to the stack
00BAH PUSH D ; Save DE to the stack
00BBH PUSH H ; Save HL to the stack
00BCH LXI D,0040H ; Load address of our "Change to OptROM" routine
00BFH LXI H,FAA4H ; Load pointer to somewhere in RAM to hold our routine
00C2H CALL 0072H ; Copy 8 bytes from DE to HL
00C5H LXI B,0024H ; Now prepare to copy 36 bytes worth of "routine"
00C8H LXI H,F605H ; Point to another RAM location
00CBH CALL 0075H ; Copy the next "ROM Bank Switching" routine from our ROM
00CEH POP H ; Restore HL
00CFH POP D ; Restore DE
00D0H POP PSW ; Restore A
00D1H EI ; Allow interrupts again
00D2H JMP 0100H ; Go test if a "Cold Start" recovery is being requested

.org 100H

; =========================================================================================
; Test if cold-start recovery requested
; =========================================================================================
0100H MOV A,H ; Move H to A to test HL for zero
0101H ORA L ; Test for zero
0102H JZ 7000H ; Call recovery routine if requested
0105H POP H ; Pop the return address. We will exit manually
0106H CALL 0117H ; Ensure the TS-DOS progam is installed in the MENU
0109H JMP 3535H ; Jump to the TS-DOS UI

; =========================================================================================
; Move BC bytes from (HL) to (DE) with increment
; =========================================================================================
010CH MOV A,M ; Get next byte from (HL)
010DH STAX D ; Save byte in (DE)
010EH INX H ; Increment source pointer
010FH INX D ; Increment destination pointer
0110H DCX B ; Decrement loop control
0111H MOV A,B ; Move MSB to A to test for zero
0112H ORA C ; OR in LSB to test for zero
0113H JNZ 010CH ; Branch to copy next byte until done
0116H RET

; =========================================================================================
; Insert the "TS-DOS" invocation program (BASIC program) into the Catalog / MENU.
; we always insert ourselves at the lowest RAM address.
; =========================================================================================
0117H LXI H,01E1H ; Point to "TS-DOS" catalog entry in our ROM
011AH PUSH H ; Save the address on the stack for later
011BH INX H ; Point to the text portion of the catalog entry
011CH LXI B,0008H ; Prepare to copy 8 filename byte
011FH LXI D,FC93H ; Filename of current BASIC program
0122H CALL 010CH ; Copy BC bytes from HL to DE - put "TS-DOS " in cur. BASIC prog.
0125H XCHG ; HL <--> DE DE now has the address of the invocation program
0126H LHLX ; Get the length of the BASIC program into HL
0127H SHLD FCC4H ; Save the BASIC program length in the ALTLCD buffer for now
012AH INX D ; Point to MSB of the length
012BH INX D ; Point to LSB of the pointer to the "Next" BASIC instruction
012CH XCHG ; HL <--> DE HL has the pointer to the "Next" BASIC inst address
012DH SHLD FCC8H ; Save the "Next" BASIC inst pointer to ALTLCD (start of program)
0130H CALL 01D1H ; Update the System pointers
0133H CALL 01CDH ; Search Catalog for entry matching current BASIC program
0136H POP B ; Pop address in case we return
0137H RNZ ; Return if "TS-DOS" is already in the catalog
0138H LHLD F99AH ; Get the BASIC program not saved pointer - insert before that
013BH SHLD FCC2H ; Save storage location for the TS-DOS invocation progam
013EH LDAX B ; Load the file type byte from our ROM (B has the address from above)
013FH STA FCC6H ; Store the Type byte in the ALTLCD
0142H CALL 0185H ; Find empty entry in Catalog
0145H RC ; Return if catalog full
0146H PUSH H ; Save the address of the empty catalog entry to the stack
0147H LHLD FCC4H ; Restore the BASIC program length from ALTLCD
014AH MOV B,H ; Move BASIC program length to BC for copy
014BH MOV C,L ; Move LSB of length
014CH PUSH B ; Save Length to the stack
014DH LHLD FCC2H ; Get address of insertion for TS-DOS just before the unsaved BASIC prog.
0150H CALL 01DDH ; Call Main ROM's Insert BC spaces at M routine
0153H JC 0182H ; Abort if RAM full
0156H LHLD FCC2H ; Get address of insertion point again
0159H XCHG ; DE now has insertion point for BASIC program
015AH LHLD FCC8H ; Get the address of the BASIC program (in our ROM) from ALTLCD
015DH POP B ; Restore copy length of the BASIC program
015EH CALL 010CH ; Move BC bytes from (HL) to (DE) with increment
0161H POP D ; Get the address of the empty catalog entry we will use for TS-DOS
0162H PUSH D ; Save it back to the stack
0163H LHLD FBAEH ; Load the start of DO files pointer
0166H DCX H ; Derement the start of DO files pointer
0167H SHLD F99AH ; Save it as the new BASIC program not saved pointer
016AH INX H ; Point to start of DO files again
016BH XCHG ; Move it to DE
016CH LHLD FCC4H ; Load the TS-DOS BASIC progam length from ALTLCD
016FH DAD D ; Offset the start of DO files by the insertion amount
0170H SHLD FBAEH ; Save the new start of DO files pointer
0173H POP D ; Restore the address of the empty catalog entry
0174H LHLD FCC2H ; Get the starting address of the newly inserted TS-DOS program
0177H XCHG ; HL <--> DE Swap for the call to the catalog insertion routine
0178H LDA FCC6H ; Load A with the file type byte
017BH CALL 01D5H ; Save current BASIC program to the Catalog entry at HL
017EH CALL 01D1H ; Update system pointers
0181H RET

; =========================================================================================
; Insert "TS-DOS" RAM full abort routine ... stack cleanup.
; =========================================================================================
0182H POP H ; Pop the BASIC program length from the stack
0183H POP H ; Pop the catalog entry address from the stack
0184H RET

; =========================================================================================
; Find an empty entry in the Catalog. HL points to start of new entry
; This routine appears again at address 3E48H
; =========================================================================================
0185H LXI H,F9AFH ; Point to "RickY" to start search at beginning of catalog
0188H LXI B,000BH ; Get length of each entry in the Catalog
018BH DAD B ; Point to next entry in the catalog
018CH MOV A,M ; Get the File Attribute byte from the catalog for this file
018DH CPI FFH ; Test if at end of the catalog
018FH JZ 0197H ; Jump to set Carry flag and exit if at end
0192H ADD A ; Test if MSB set (test if entry available)
0193H JC 018BH ; Branch to get next entry if this one is used
0196H RET ; Return with Carry clear to indicate entry found

; =========================================================================================
; Empty catalog entry not found in Catalog, set Carry and return
; =========================================================================================
0197H STC ; Set the Carry flag - not found
0198H RET

; =========================================================================================
; Call Main ROM's Display function key line routine
; =========================================================================================
0199H RST 1 ; Call main ROM at address in following 2 bytes
019AH DW 42A8H
019CH RET

; =========================================================================================
; Call Main ROM's Erase function key display routine
; =========================================================================================
019DH RST 1 ; Call main ROM at address in following 2 bytes
019EH DW 428AH
01A0H RET

; =========================================================================================
; Call Main ROM's Set new function key table routine
; =========================================================================================
01A1H RST 1 ; Call main ROM at address in following 2 bytes
01A2H DW 5A7CH
01A4H RET

; =========================================================================================
; Call Main ROM's Wait for key from keyboard routine
; =========================================================================================
01A5H RST 1 ; Call main ROM at address in following 2 bytes
01A6H DW 12CBH
01A8H RET

; =========================================================================================
; Call Main ROM's Scan keyboard for character (CTRL-BREAK ==> CTRL-C) routine
; This appears later in the code also
; =========================================================================================
01A9H RST 1 ; Call main ROM at address in following 2 bytes
01AAH DW 7242H
01ACH RET

; =========================================================================================
; Call Main ROM's Power Down routine
; This appears later in the code also
; =========================================================================================
01ADH RST 1 ; Call main ROM at address in following 2 bytes
01AEH DW 13B5H
01B0H RET

; =========================================================================================
; Call Main ROM's Renew automatic power-off counter routine
; This apears later in the code also
; =========================================================================================
01B1H RST 1 ; Call main ROM at address in following 2 bytes
01B2H DW 1BB1H
01B4H RET

; =========================================================================================
; Call Main ROM's CLS statement routine
; This apears later in the code also
; =========================================================================================
01B5H RST 1 ; Call main ROM at address in following 2 bytes
01B6H DW 4231H
01B8H RET

; =========================================================================================
; Call Main ROM's Start inverse character mode routine
; This appears later in the code also
; =========================================================================================
01B9H RST 1 ; Call main ROM at address in following 2 bytes
01BAH DW 4269H
01BCH RET

; =========================================================================================
; Call Main ROM's Cancel inverse video routine
; This appears later in the code also
; =========================================================================================
01BDH RST 1 ; Call main ROM at address in following 2 bytes
01BEH DW 426EH
01C0H RET

; =========================================================================================
; Call Main ROM's Check keyboard queue for pending characters routine
; This appers later in the code also
; =========================================================================================
01C1H RST 1 ; Call main ROM at address in following 2 bytes
01C2H DW 13DBH
01C4H RET

; =========================================================================================
; Call Main ROM's Stop automatic scrolling routine
; This appers later in the code also
; =========================================================================================
01C5H RST 1 ; Call main ROM at address in following 2 bytes
01C6H DW 423FH
01C8H RET

; =========================================================================================
; Call Main ROM's Reset vector routine
; =========================================================================================
01C9H RST 1 ; Call main ROM at address in following 2 bytes
01CAH DW 0000H
01CCH RET

; =========================================================================================
; Search Catalog for entry matching current BASIC program
; =========================================================================================
01CDH RST 1 ; Call main ROM at address in following 2 bytes
01CEH DW 20AFH
01D0H RET

; =========================================================================================
; Call Main ROM's Update system pointers routine
; =========================================================================================
01D1H RST 1 ; Call main ROM at address in following 2 bytes
01D2H DW 2146H
01D4H RET

; =========================================================================================
; Call Main ROM's routine to save current BASIC program to the Catalog entry at HL
; =========================================================================================
01D5H RST 1 ; Call main ROM at address in following 2 bytes
01D6H DW 2239H
01D8H RET

; =========================================================================================
; Not a valid entry into ROM and not called anywhere
; =========================================================================================
01D9H RST 1 ; Call main ROM at address in following 2 bytes
01DAH DW 5825H
01DCH RET

; =========================================================================================
; Call Main ROM's Insert BC spaces at M routine
; =========================================================================================
01DDH RST 1 ; Call main ROM at address in following 2 bytes
01DEH DB 6B6DH
01E0H RET

; =========================================================================================
; TS-DOS entry that will be inserted into the catalog for invoking TS-DOS
; =========================================================================================
01E1H DB 80H ; TS-DOS file type for catalog entry
01E2H DB "TS-DOS " ; TS-DOS Catalog name entry

; =========================================================================================
; BASIC program that will be inserted into RAM to launch TS-DOS from the MENU/Catalog entry
; =========================================================================================
01EAH DB 0FH,00H,0EH,80H ; BASIC program length and pointer to "Next" BASIC instruction
01EDH DB 0AH,00H,B9H ; BASIC Line number "10" and BASIC token for CALL
01EFH DB "63013,1" ; CALL argument
01F5H DB 00H,00H ; BASIC terminating zeros

</pre>

End of disassembly for OptROM Support.

Navigate to:
* [[Dissasembly of RAM and ROM versions of TS-DOS]]
* [[M100 TS-DOS ROM UI Code]]
* [[M100 TS-DOS ROM RST 7 Handlers]]
* [[M100 TS-DOS ROM TPDD Protocol]]
* [[M100 TS-DOS ROM Compression]]
* [[M100 TS-DOS ROM Cold Boot Recovery]]

Disassembly of RAM and ROM versions of TS-DOS

2009-04-03T07:50:49Z

Kpettit: /* Model 100/102 ROM Version */

== TS-DOS Dissassembly ==

There are various version of TS-DOS for The Model 100/102, for T200 and for the PC-8201a. Additionally each of these versions has a ROM and a RAM. While the majority of the code is equivalent across the various incarnations of TS-DOS, there are some differences due to varying RS-232 hardware and to accomodate execution from OptROM vs. RAM.

The goal of the disassembly is to create a fully commented source file that can be assembled and subsequently modified / enhanced for new functionality. The disassembly is split into several sections to keep each page "relatively" short. The disassembly currently will not assemble as it contains absolute addresses that must be converted into assembly labels, or deleted where not needed.

== Model 100/102 ROM Version ==
* [[M100 TS-DOS ROM OptROM Support]]
* [[M100 TS-DOS ROM UI Code]]
* [[M100 TS-DOS ROM RST 7 Handlers]]
* [[M100 TS-DOS ROM TPDD Protocol]]

Not Completed Yet
* [[M100 TS-DOS ROM Compression]]
* [[M100 TS-DOS ROM Cold Boot Recovery]]

== Model 200 RAM Version ==
[[UI Code]] [[FKey Handlers]] [[RST 7 Handlers]] [[TPDD Protocol]]

Disassembly of RAM and ROM versions of TS-DOS

2009-04-03T07:49:59Z

Kpettit: /* Model 100/102 ROM Version */

== TS-DOS Dissassembly ==

There are various version of TS-DOS for The Model 100/102, for T200 and for the PC-8201a. Additionally each of these versions has a ROM and a RAM. While the majority of the code is equivalent across the various incarnations of TS-DOS, there are some differences due to varying RS-232 hardware and to accomodate execution from OptROM vs. RAM.

The goal of the disassembly is to create a fully commented source file that can be assembled and subsequently modified / enhanced for new functionality. The disassembly is split into several sections to keep each page "relatively" short. The disassembly currently will not assemble as it contains absolute addresses that must be converted into assembly labels, or deleted where not needed.

== Model 100/102 ROM Version ==
* [[M100 TS-DOS ROM OptROM Support]]
* [[M100 TS-DOS ROM UI Code]]
* [[M100 TS-DOS ROM FKey Handlers]]
* [[M100 TS-DOS ROM RST 7 Handlers]]
* [[M100 TS-DOS ROM TPDD Protocol]]

Not Completed Yet
* [[M100 TS-DOS ROM Compression]]
* [[M100 TS-DOS ROM Cold Boot Recovery]]

== Model 200 RAM Version ==
[[UI Code]] [[FKey Handlers]] [[RST 7 Handlers]] [[TPDD Protocol]]

M100 TS-DOS ROM UI Code

2009-04-03T07:43:49Z

Kpettit:

== TS-DOS Model 100/102 User Interface Code

<pre>
; =========================================================================================
; TS-DOS UI Entry location
; =========================================================================================

.org 3535H

3535H LXI H,FCC0H ; Start of Alt LCD character buffer
3538H MVI B,B4H ; Prepare to clear 180 bytes from the ALTLCD buffer
353AH XRA A ; Prepare to clear the ALTLCD buffer
353BH CALL 4A34H ; Fill (HL) with B bytes of A
353EH LXI H,0000H ; Prepare to get current stack pointer
3541H DAD SP ; Copy SP into HL
3542H SHLD FCCEH ; Stack pointer upon entry - pointer to arguments
3545H MVI A,01H ; Set flag to print error message to LCD - GUI mode
3547H CALL 4A85H ; Save the currently selected baud rate settings
354AH XRA A ; Zero A to clear our vars
354BH STA FCD4H ; Current Page of files being displayed
354EH STA FCDAH ; TPDD "skip page" count
3551H STA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3554H STA FCCAH ; TPDD2 Bank number
3557H INR A ; A = 1 to select 1st file on page
3558H STA FCCDH ; Currently selected file index
355BH LXI H,3564H ; Get pointer to main loop routine
355EH SHLD FCD0H ; Return vector after error
3561H CALL 4C27H ; CLS statement

; =========================================================================================
; UI Main loop
; =========================================================================================
3564H CALL 4C5AH ; Resume automatic scrolling
3567H CALL 3611H ; Print Copyright and files
356AH LDA FCD5H ; Load currently selected index from temp storage
356DH STA FCCDH ; Currently selected file index
3570H CALL 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Code will return here when a funtion key is pressed (except F4 & F6)
; =========================================================================================
3573H LXI H,48B5H ; Get address of "Long jump"
3576H PUSH H ; Push "Long jump" address to stack
3577H PUSH PSW ; Save function key press to stack
3578H CPI 02H ; Test if function key is F5-F8 (Non file operation F Keys)
357AH JNC 35B9H ; Jump to Function key handler if F5-F8 (No tagging to process)
357DH LDA FCCCH ; Last Tag/Untag operation code
3580H ANA A ; Test if a tag operation was performed
3581H JZ 35B9H ; Jump to Function key handler if no tag operation performed
3584H LDA FCD6H ; Count of files on screen
3587H MOV C,A ; Save count of files for loop decrementing
3588H INR C ; Increment by 1 for loop bounding
3589H MVI B,00H ; Start with index zero on the LCD
358BH PUSH B ; Save the current index on the stack

; =========================================================================================
; Display next file
; =========================================================================================
358CH LDA FCCDH ; Currently selected file index
358FH STA FCD5H ; Currently selected file index - temp
3592H CALL 3AC4H ; Print selected file using normal video
3595H POP B ; Restore index from stack
3596H INR B ; Increment to the next file index to display
3597H DCR C ; Decrement the loop control
3598H JZ 48B5H ; Branch to perform "Long Jump" if all files printed to LCD
359BH MOV A,B ; Get the index of the current file
359CH STA FCD5H ; Save in temporary "current file" area
359FH STA FCCDH ; Currently selected file index
35A2H PUSH B ; Push the value on the stack for the next iteration
35A3H CALL 3AB2H ; Print currently selected file using inverse video
35A6H LHLD FCE4H ; LCD Buffer address of current file selection
35A9H DCX H ; Decrement to the Tag area for the file
35AAH MOV A,M ; Get the file's Tag code
35ABH CPI 3EH ; Compare with '>'
35ADH JNZ 358CH ; Jump to process next file if not tagged
35B0H POP B ; Pop currently selected file value from stack
35B1H POP PSW
35B2H LXI H,358CH ; Return address to display the next file
35B5H PUSH PSW ; ? Stack trickery
35B6H PUSH B ; Save current file index to stack for use after a RET operation
35B7H PUSH H ; Setup "Display next file" as a return address for RET
35B8H PUSH PSW ; ? More stack trickery

; =========================================================================================
; Function key handler - Disk mode and dispatch to RAM mode
; =========================================================================================
35B9H CALL 4C56H ; Stop automatic scrolling
35BCH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
35BFH ORA A
35C0H JZ 35E2H ; Branch if in RAM mode
35C3H POP PSW
35C4H ANA A ; Test for F1
35C5H JZ 3B2EH ; Branch to F1 handler for disk
35C8H DCR A ; Test for F2
35C9H JZ 3D73H
35CCH DCR A ; Test for F3
35CDH JZ 3D9FH
35D0H DCR A ; Skip F4 - handled at lower level
35D1H DCR A ; Test for F5
35D2H JZ 3D53H
35D5H DCR A ; Skip F6 - handled at lower level
35D6H DCR A ; Test for F7
35D7H JZ 3D00H
35DAH DCR A ; Test for F8
35DBH POP H
35DCH JZ 35FEH ; Jump to exit if F8
35DFH JMP 3564H ; Jump to main loop

; =========================================================================================
; Function key handler - RAM mode
; =========================================================================================
35E2H POP PSW
35E3H ANA A ; Test for F1
35E4H JZ 3C4BH
35E7H DCR A ; Test for F2
35E8H JZ 3C2BH
35EBH DCR A ; Test for F3
35ECH JZ 3AF8H
35EFH DCR A ; Skip F4 - handled at lower level
35F0H DCR A ; Test for F5
35F1H JZ 3E5CH
35F4H DCR A ; Skip F6 - handled at lower level
35F5H DCR A ; Skip F7 - not defined for RAM
35F6H DCR A ; Test for F8
35F7H POP H
35F8H JZ 35FEH ; Jump to exit if F8
35FBH JMP 3564H ; Jump back to main loop

; =========================================================================================
; This is the UI exit routine
; =========================================================================================
35FEH CALL 4AC4H ; Restore original baud settings
3601H CALL 4BD7H ; Wait for TX empty and Reset UART to accept mode bits
3604H CALL 4C27H ; CLS statement
3607H CALL 4C5AH ; Resume automatic scrolling
360AH LXI H,0000H
360DH PUSH H
360EH JMP 00A6H ; Exit TS-DOS

; =========================================================================================
; Print Copyright string and files
; =========================================================================================
3611H LXI H,0101H ; Goto top left corner
3614H SHLD F639H ; Cursor row (1-8)
3617H LXI H,3E69H ; Point to "TS-DOS" copyright string
361AH CALL 4A2CH ; Send buffer at M to screen
361DH XRA A ; Indicate no previous Tag/Untag operation
361EH STA FCCCH ; Last Tag/Untag operation code
3621H MVI A,01H ; Start with 1st file in list
3623H STA FCD5H ; Currently selected file index - temp
3626H LXI H,0202H ; Goto first file entry location
3629H SHLD F639H ; Cursor row (1-8)
362CH JMP 383BH ; Draw the display

; =========================================================================================
; Print length of selected file using inverse video
; =========================================================================================
362FH LDA FCCDH ; Currently selected file index
3632H STA FCD5H ; Currently selected file index - temp
3635H CALL 3AB2H ; Print currently seleted file using inverse video
3638H LDA FCD5H ; Currently selected file index - temp
363BH DCR A ; Make index zero based for multiply x2
363CH STC ; Set Carry flag
363DH CMC ; Compliment (clear) carry flag
363EH RLC ; Rotate left circular
363FH MOV E,A ; E = File index * 2 to point to file length value
3640H MVI D,00H ; Clear MSB of file length offset
3642H LXI H,F685H ; Keyboard buffer - store file lengths
3645H DAD D ; Add file lenght offset from beginning of keyboard buffer
3646H XCHG ; HL <--> DE Save file length address pointer in DE
3647H LXI H,2307H ; Load position of File Size area on LCD
364AH SHLD F639H ; Cursor row (1-8)
364DH CALL 4C2BH ; Erase from cursor to end of line
3650H LHLX ; Load HL with file length
3651H CALL 4C2FH ; Start inverse character mode
3654H CALL 4C3EH ; Print binary number in HL at current position
3657H CALL 4C33H ; Cancel inverse character mode

; =========================================================================================
; Keyboard scan loop
; =========================================================================================
365AH CALL 3DFEH ; Process automatic power off logic
365DH CALL 4BEFH ; Scan keyboard for character (CTRL-BREAK ==> CTRL-C)
3660H JZ 365AH ; Jump to scan keyboard again if no key pressed
3663H JC 380CH ; Jump to Function Key Handler if FKey
3666H CPI 0DH ; Test for CR
3668H JZ 3722H
366BH CPI 17H ; Test for Ctrl-Up key
366DH JZ 37AAH
3670H CPI 14H ; Test for Shift-Up key
3672H JZ 3798H
3675H CPI 5DH ; Test for "]" key
3677H JZ 3798H
367AH CPI 3FH ; Test for "?" key
367CH JZ 3777H
367FH CPI 02H ; Test for Shift-Down arrow key
3681H JZ 3777H
3684H CPI 1EH ; Test for up key
3686H JZ 36EEH
3689H CPI 1FH ; Test for down key
368BH JZ 36FCH
368EH CPI 1DH ; Test for "left arrow" key
3690H JZ 36DDH
3693H CPI 1CH ; Test for "Right arrow" key
3695H JZ 36CAH
3698H CPI 20H ; Test for space key
369AH JZ 36CAH ; Treat space the same as right arrow
369DH ANI DFH ; Convert to Upper case
369FH CPI 52H ; Test for 'R' character
36A1H JZ 3759H
36A4H CPI 54H ; Test for 'T' character
36A6H JZ 37EEH
36A9H CPI 41H ; Test for "A" key
36ABH JZ 3715H
36AEH CPI 47H ; Test for "G" key
36B0H JZ 3715H
36B3H CPI 55H ; Test for "U" key
36B5H JZ 37AEH
36B8H CPI 44H ; Test for "D" key
36BAH JZ 39B9H
36BDH CPI 4CH ; Test for "L" key
36BFH JZ 39C2H
36C2H CPI 50H ; Test for "P" key
36C4H JZ 39C2H
36C7H JMP 365AH ; Go scan keyboard again

; =========================================================================================
; Handle Right Arrow key from TS-DOS key scan
; =========================================================================================
36CAH MVI A,01H ; Prepare to add 1 to selected file
36CCH LXI H,FCD5H ; Currently selected file index - temp storage
36CFH ADD M ; Add 1 to the selected file index
36D0H INX H ; Point to file count on screen
36D1H CMP M ; Compare new index with screen file count
36D2H JC 370AH ; Jump to process new file if we didn't wrap
36D5H JZ 370AH ; Jump to process new file if = file count
36D8H MVI A,01H ; Wrap to the first file
36DAH JMP 370AH ; Go process file 1 as the new selection

; =========================================================================================
; Handle Left Arrow key from TS-DOS key scan
; =========================================================================================
36DDH LDA FCD5H ; Currently selected file index - temp storage
36E0H DCR A ; Move to next lowest file index
36E1H JNZ 370AH ; If no wrap, jump to process new selection
36E4H LDA FCD6H ; Count of files on screen
36E7H ANA A ; Ensure there is at least 1 file on the screen
36E8H JZ 365AH ; Jump to keyboard scan loop if no files on LCD
36EBH JMP 370AH ; Go process new selection as the max (wrap-around)

; =========================================================================================
; Handle Up Arrow key from TS-DOS key scan
; =========================================================================================
36EEH LDA FCD5H ; Currently selected file index - temp storage
36F1H SUI 04H ; Subtract 4 from file count (4 files per line)
36F3H JC 365AH ; Jump to keysacn loop if negative
36F6H JZ 365AH ; Jump to keysacn loop if zero
36F9H JMP 370AH ; Go process the new file index setting

; =========================================================================================
; Handle Down Arrow key from TS-DOS key scan
; =========================================================================================
36FCH MVI A,04H ; There are 4 files per line
36FEH LXI H,FCD5H ; Currently selected file index - temp storage
3701H ADD M ; Add 4 to the index number
3702H MOV C,A ; Save new index for comparison and further processing
3703H INX H ; Maximum file index count
3704H MOV A,M ; Load maximum index for bounds
3705H CMP C ; Compare new index with maximum
3706H JC 365AH ; Jump to keyboard scan if moving past last file
3709H MOV A,C ; Restore new current file index
370AH PUSH PSW ; Save new file index for storage after the call
370BH CALL 3AC4H ; Print selected file using normal video
370EH POP PSW ; Restore new file index from stack
370FH STA FCCDH ; Save the new file index
3712H JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle "A" or "G" key from TS-DOS key scan
; =========================================================================================
3715H MVI A,3EH ; Load ">" for the tag symbol
3717H CALL 37CAH ; Go tag all files on the LCD
371AH MVI A,01H ; Indicate last operation as "Tag All"
371CH STA FCCCH ; Last Tag/Untag operation code
371FH JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle Enter key from TS-DOS key scan - Change Directory
; =========================================================================================
3722H LDA FCCBH ; Get NADSBox/Desklink/TPDD2 flag
3725H CPI 02H ; Test if NADSBox current directory valid
3727H JNZ 365AH ; Back to keyscan if no "current directory" - Enter is meaningless
372AH LHLD FCE4H ; LCD Buffer address of current file selection
372DH LXI B,0007H ; Load offset of file extension
3730H DAD B ; Point to file extension of selected file
3731H MOV A,M ; Load the 1st byte of the file extension
3732H CPI 3CH ; Test if 1st byte of extension is "<"
3734H JNZ 365AH ; Jump to keyscan if current selection not directory entry
3737H CALL 4A3BH ; Initialize blank filename and attribute byte
373AH LHLD FCE4H ; LCD Buffer address of current file selection
373DH CALL 3D95H ; Copy filename at (HL) to TX buffer
3740H CALL 408AH ; Open TPDD file for Read Mode
3743H LXI H,0002H ; Load opcode to close currently opened file
3746H CALL 409BH ; Send Request in HL and await response
3749H LHLD FCE4H ; LCD Buffer address of current file selection
374CH LXI D,FCC0H ; NADSBox current directory storage
374FH LXI B,0009H ; Copy 9 bytes of NADSBox directory to the LCD
3752H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3755H XRA A ; Clear A to show 1st page of files
3756H JMP 378AH ; Branch to show the page of files in A

; =========================================================================================
; Handle "R" key from TS-DOS key scan
; =========================================================================================
3759H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
375CH ANA A ; Test if in Disk mode
375DH JNZ 362FH ; Jump to keyscan if in Disk mode
3760H LHLD FCE4H ; LCD Buffer address of current file selection
3763H CALL 4902H ; Copy filename at (HL) to current BASIC program
3766H CALL 4A51H ; Get RAM directory address of current BASIC program
3769H CPI C0H ; Test if filetype is .DO
376BH CZ 5000H ; Call routine to Compress / Decompress .DO files
376EH CALL 4C0FH ; Update system pointers
3771H CALL 3611H ; Print Copyright and files
3774H JMP 362FH ; Jump to keyscan

; =========================================================================================
; Handle "?" and Shift-Down key from TS-DOS key scan
; =========================================================================================
3777H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
377AH ANA A ; Test if RAM mode
377BH JZ 365AH ; Branch to keyscan if in RAM mode
377EH LDA FCD6H ; Count of files on screen
3781H CPI 14H ; Maximum number of files that fit on the screen
3783H JC 365AH ; Branch to keyscan if on last page
3786H LDA FCD4H ; Current Page of files being displayed
3789H INR A ; Increment to next page of files

; =========================================================================================
; Show the page of files indicated by A
; =========================================================================================
378AH STA FCD4H ; Current Page of files being displayed
378DH MVI A,01H ; Go to 1st file on the new page
378FH STA FCCDH ; Currently selected file index
3792H CALL 3611H ; Print copyright and files
3795H JMP 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Handle "]" and Shift-Up key from TS-DOS key scan
; =========================================================================================
3798H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
379BH ANA A ; Test if RAM mode
379CH JZ 365AH ; Branch to keyscan if in RAM mode
379FH LDA FCD4H ; Current Page of files being displayed
37A2H ANA A ; Test if current page is zero
37A3H JZ 365AH ; Branch to keyscan if already on page 0
37A6H DCR A ; Decrement the page number
37A7H JMP 378AH ; Show the page of files indicated by A

; =========================================================================================
; Handle Ctrl-Up key from TS-DOS key scan
; =========================================================================================
37AAH XRA A ; Go to page zero
37ABH JMP 378AH ; Show the page of files indicated by A

; =========================================================================================
; Handle "U" key from TS-DOS key scan - Remove all tags
; =========================================================================================
37AEH MVI A,20H ; Display ' ' as the tag marker
37B0H CALL 37CAH ; Go process tag for all files
37B3H XRA A ; Indicate last tag operation was untag
37B4H STA FCCCH ; Store as "last tag" operation
37B7H JMP 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Swap TPDD2 Bank number
; =========================================================================================
37BAH LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
37BDH DCR A ; Test if the flag = 1 (TPDD2)
37BEH JNZ 365AH ; Jump to keyscan if not 1
37C1H LDA FCCAH ; Get TPDD Bank Number
37C4H XRI 01H ; Switch to the other bank
37C6H STA FCCAH ; Save TPDD bank number
37C9H RET

; =========================================================================================
; Process Tag or Untag for all files on screen
; =========================================================================================
37CAH STA FCCCH ; Store tag/untag code for later
37CDH LDA FCD6H ; Get Maximum file count on screen
37D0H ANA A ; Test for zero
37D1H RZ ; Return if no files on screen
37D2H XRA A ; Clear A
37D3H INR A ; A=1 to selet 1st file
37D4H STA FCD5H ; Currently selected file index
37D7H CALL 3ACDH ; Calculate Row and Column of soon-to-be (newly) selected file
37DAH LHLD FCE4H ; LCD Buffer address of current file selection
37DDH DCX H ; Point to Tag location for the file
37DEH LDA FCCCH ; Get the tag/untag code
37E1H RST 4 ; Display A to the LCD
37E2H LDA FCD5H ; Get currently selected file index
37E5H LXI H,FCD6H ; Point to count of files on screen
37E8H CMP M ; Compare current selection with count of files on LCD
37E9H JC 37D3H ; Jump to process next file if more files left
37ECH ANA A ; Set zero flag to indicate files were tagged/untagged
37EDH RET

; =========================================================================================
; Handle "T" key key from TS-DOS key scan - TAG
; =========================================================================================
37EEH CALL 3ACDH ; Calculate Row and Column of soon-to-be (newly) selected file
37F1H CALL 4C2FH ; Start inverse character mode
37F4H LHLD FCE4H ; LCD Buffer address of current file selection
37F7H DCX H ; Point to the "Tag" area for the file
37F8H MVI A,3EH ; Load the code for ">"
37FAH CMP M ; Compare if file is already tagged
37FBH JNZ 3800H ; Skip ahead if already tagged
37FEH MVI A,20H ; Need to untag - load the untag code
3800H RST 4 ; Display the tag code on the LCD
3801H CALL 4C33H ; Cancel inverse character mode
3804H LXI H,FCCCH ; Point to "last tag" operation code
3807H MVI M,01H ; Indicate last operation was "tag"
3809H JMP 36CAH ; Move to next file - jump to Right Arrow key handler

; =========================================================================================
; 1st level Function Key Handler (handles F4 and F6)
; =========================================================================================
380CH CPI 08H ; Test for valid function key code
380EH JNC 365AH ; Branch back to scan loop if invalid
3811H CPI 05H ; Test for F6
3813H JZ 3833H ; Jump if F6 pressed
3816H CPI 03H ; Test for F4
3818H RNZ ; Return to "Main Loop" if not F4 pressed
3819H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
381CH XRI 01H ; Swap RAM/DISK mode
381EH STA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3821H XRA A ; Clear A to go to 1st page of files
3822H STA FCD4H ; Current Page of files being displayed
3825H MVI A,01H ; Select the 1st file in the page
3827H STA FCCDH ; Currently selected file index
382AH CALL 4C27H ; CLS statement
382DH CALL 3611H ; Print the title bar and files
3830H JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; F6 Function Key Handler
; =========================================================================================
3833H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3836H ANA A ; Test if in RAM or DISK mode
3837H RZ ; Return if RAM mode
3838H JMP 37AAH ; Jump to Ctrl-Up key handler

; =========================================================================================
; Draw the display. This takes care of RAM and Disk mode displays, handles
; skipping page number to the proper "Disk" page, displaying the Bank# or
; current directory for NADSBox/Desklink, showing free space, filling in
; empty slots with "-.-", etc.
; =========================================================================================
383BH LXI H,F685H ; Keyboard buffer
383EH SHLD FCDBH ; Initialize pointer to file length table (in keyboard buffer)
3841H XRA A ; Prepare to set 1st file lenght to zero
3842H MOV M,A ; Set LSB of length of 1st file to zero
3843H INX H ; Increment to MSB of length
3844H MOV M,A ; Set MSB of length of file to zero
3845H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3848H ANA A ; Test if RAM or DISK
3849H JZ 395DH ; Jump to show RAM files if in RAM mode
384CH XRA A ; Prepare to initialize the "page being processed" variable
384DH STA FCDAH ; Clear the "page being processed" variable
3850H CALL 4735H ; Clear #files displayed, init TPDD and send 1st file dir referene opcode
3853H JNZ 390FH ; Process unformated disk (empty slots and error message)
3856H LDA FCD4H ; Current Page of files being displayed
3859H ANA A ; Test if displaying page 0
385AH JZ 3871H ; Jump if showing page 0 - don't need to skikp any pages
385DH STA FCDAH ; Initialize the number of pages left to skip count
3860H CALL 4742H ; Read next page of files from server
3863H LDA FCDAH ; Get the "Pages left to skip" count
3866H DCR A ; Decrement the remaining skip page count
3867H JNZ 385DH ; Keep reading pages until we have skipped enough pages
386AH XRA A ; Prepare to clear the remaining skip page count
386BH STA FCDAH ; Clear the remaining skip page count
386EH STA FCD6H ; Count of files on screen
3871H CALL 4742H ; Read next page of files from server
3874H LDA FCD6H ; Count of files on screen
3877H CPI 14H ; Test if all file slots are full
3879H CC 39AAH ; Print "-.-" for all empty file slots (if any)

; =========================================================================================
; Print NADSBox directory or TPDD Bank number to LCD
; =========================================================================================
387CH LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
387FH ANA A ; Test if server is TPDD
3880H JZ 389FH ; Skip processing Bank # or Current Dir if TPDD
3883H DCR A ; Test if server is TPDD2
3884H JZ 388DH ; Jump to print bank number if TPDD2
3887H LXI H,FCC0H ; Load pointer to NADSBox current directory storage
388AH JMP 38A5H ; Jump to print the NADSBox / Desklink directory

; =========================================================================================
; Print the TPDD Bank number to LCD
; =========================================================================================
388DH LXI H,2401H ; Go to Row 1, column 24
3890H SHLD F639H ; Cursor row (1-8)
3893H CALL 4C2FH ; Start inverse character mode
3896H MVI A,23H ; ASCII code for '#'
3898H RST 4 ; Send character in A to the LCD
3899H LDA FCCAH ; Load TPDD Bank number
389CH ADI 30H ; Convert to ASCII digit
389EH RST 4 ; Send it to the LCD
389FH CALL 4C33H ; Cancel inverse character mode
38A2H JMP 38B8H ; Branch to print the function menu, RAM/Disk free, etc.

; =========================================================================================
; Print the NADSBox / Desklink current directory in title bar
; =========================================================================================
38A5H PUSH H ; Save address of the directory string
38A6H LXI H,2101H ; Prepare to position the cursor in the title bar
38A9H SHLD F639H ; Cursor row (1-8)
38ACH CALL 4C2FH ; Start inverse character mode
38AFH POP H ; Retrieve the directory string from the stack
38B0H MVI C,06H ; Prepare to redraw 6 chars with inverse video
38B2H CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
38B5H CALL 4C33H ; Cancel inverse character mode

; =========================================================================================
; Print funtion menu, RAM/Disk free & selected file length
; =========================================================================================
38B8H LXI H,3E97H ; Point to Disk function menu
38BBH LXI B,3936H ; Routine to print free disk space
38BEH LDA FCD9H ; RAM/Disk mode
38C1H ANA A ; Test if in Disk mode and skip ahead to print Disk FKeys
38C2H JNZ 38CBH ; Skip ahead if in disk mode to keep vectors
38C5H LXI H,3ED9H ; Point to RAM function menu
38C8H LXI B,3922H ; Routine to print free RAM space
38CBH PUSH B ; Save routine address to stack
38CCH PUSH H ; Save pointer to function text to stack
38CDH LDA FCCDH ; Currently selected file index
38D0H LXI H,FCD6H ; Count of files on screen
38D3H CMP M ; Compare selected file with count of files on screen
38D4H JC 38DDH ; Branch if within bounds
38D7H MOV A,M ; Get the file count
38D8H ANA A ; Test if #files = 0
38D9H JNZ 38DDH ; Skip ahead if not zero
38DCH INR A ; Don't allow a count of zero - must be 1
38DDH STA FCD5H ; Currently selected file index - temp
38E0H LXI H,0B07H ; Row & column of start of text
38E3H SHLD F639H ; Cursor row (1-8)
38E6H POP H ; Get address of text from the stack and display it
38E7H CALL 4A2CH ; Send buffer at M to screen
38EAH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
38EDH ANA A ; Test if in RAM mode
38EEH JZ 3905H ; Jump if in RAM mode (0 = RAM)
38F1H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
38F4H ANA A ; Test if server is TPDD
38F5H JZ 3905H ; Skip printing of "Bank" or "Mkdr" if TPDD
38F8H LXI H,3FE9H ; Point to text for "Bank"
38FBH DCR A ; Test if server is TPDD2
38FCH JZ 3902H ; Jump to print "Bank" if TPDD2
38FFH LXI H,3FD8H ; Point to text for "Mkdr"
3902H CALL 4A2CH ; Send buffer at M to screen
3905H CALL 3940H ; Display DISK ON/OFF status on LCD
3908H LXI H,1507H ; Point to location for "Free" space (RAM or DISK)
390BH SHLD F639H ; Cursor row (1-8)
390EH RET

; =========================================================================================
; Handle unformatted disks. Print message and show empty slots.
; =========================================================================================
390FH XRA A ; Starting with slot zero...
3910H CALL 39AAH ; Print "-.-" for all empty file slots
3913H LXI H,3E97H ; Point to Disk Function menu string
3916H LXI B,391CH ; Print NOT FORMATTED to the display
3919H JMP 38CBH ; Go process the print and jump to error handler

; =========================================================================================
; Print "NOT FORMATTED" on the LCD and return
; =========================================================================================
391CH LXI H,`H ; Point to "NOT FORMATTED" string
391FH JMP 4A2CH ; Send buffer at M to screen

; =========================================================================================
; Print RAM free space at current posiiton
; =========================================================================================
3922H LHLD FBB2H ; Start of variable data pointer
3925H XCHG ; HL <--> DE
3926H LHLD F678H ; BASIC string buffer pointer
3929H MOV A,L ; Prepare for 16 bit subtract
392AH SUB E ; Subtract LSB
392BH MOV L,A ; Save LSB of difference for printing
392CH MOV A,H ; Prepare for subtrating MSB
392DH SBB D ; Subtract MSB
392EH MOV H,A ; Save in H for printing
392FH LXI B,FFF2H ; Load signed number -14
3932H DAD B ; Subtract 14 from free memory
3933H JMP 4C3EH ; Print binary number in HL at current position

; =========================================================================================
; Display free space on disk
; =========================================================================================
3936H CALL 4A10H ; Calculate free space on disk
3939H CALL 4C3EH ; Print binary number in HL at current position
393CH MVI A,30H ; Prepare to add an extra '0' since calc is /10
393EH RST 4 ; Send A to the LCD
393FH RET

; =========================================================================================
; Display DISK ON/OFF status on LCD
; =========================================================================================
3940H LDA FCD9H ; DISK/RAM mode (0=RAM, 1=DISK)
3943H ANA A ; Test if in RAM mode
3944H RNZ ; Return if not in RAM mode
3945H LDA FB2CH ; DISK-OFF/ON status
3948H LXI D,3FF2H ; Load pointer to "OFF" text
394BH CPI DBH ; Test if DISK mode (vector LSB) indicates ON or OFF
394DH JZ 3953H ; Branch if in DISK-OFF mode
3950H LXI D,3FF6H ; Load pointer to "ON" text
3953H LXI H,1908H ; Location of DISK-OFF/ON indication on LCD
3956H SHLD F639H ; Cursor row (1-8)
3959H XCHG ; HL = pointer to text in DE
395AH JMP 4A2CH ; Send buffer at M to screen

; =========================================================================================
; Display RAM files to LCD and calculate file lengths
; =========================================================================================
395DH LXI H,F9BAH ; Load pointer to 1st available file slot in catalog
3960H XRA A ; Set count of RAM files on screen to zero
3961H STA FCD6H ; Count of files on screen
3964H MVI A,14H ; Get max # files that will fit on LCD
3966H DCR A ; Decrement the max file count
3967H PUSH PSW ; Save count to the stack
3968H MOV A,M ; Get file type
3969H XRI 80H ; Compliment ?active bit
396BH ANI 9FH ; Test if file is active and should be displayed
396DH JNZ 3996H ; Branch to test next file if not displayed
3970H PUSH H ; Save address of current catalog file
3971H INX H ; Point to file address
3972H MOV E,M ; Get LSB of file address
3973H INX H ; Point to MSB of address
3974H MOV D,M ; Get MSB of file address
3975H XTHL ; HL <--> (SP) Get address of file within catalog
3976H PUSH H ; Push pointer to MSB of address on stack
3977H CALL 3CD3H ; Calculate length of RAM file
397AH XCHG ; HL <--> DE DE has the length
397BH CALL 4791H ; Store next file length to keyboard buffer
397EH POP H ; Get catalog address of current file from stack
397FH XTHL ; HL <--> (SP) swap catalog address with pointer to MSB of file address
3980H INX H ; Increment to filename
3981H MVI C,06H ; Prepare to print 6 characters of filename
3983H CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
3986H MVI A,2EH ; Load code for '.'
3988H RST 4 ; Send A to the LCD
3989H MVI C,02H ; Prepare to print 2 ext bytes to LCD
398BH CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
398EH MVI A,20H ; Load code for space
3990H RST 4 ; Send A to the LCD
3991H LXI H,FCD6H ; Count of files on screen
3994H INR M ; Increment number of files displayed on LCD
3995H POP H ; Get catalog address of file from stack
3996H LXI D,000BH ; Load offset to next file locaion in catalog
3999H DAD D ; Offset HL to next file
399AH POP PSW ; Restore the file count from the stack
399BH DCR A ; Decrement the max file count on the LCD
399CH JNZ 3967H ; Branch to test and display next file until zero
399FH LDA FCD6H ; Get the count of files actually displayed on screen
39A2H CPI 14H ; Test if max number of files displayed
39A4H CC 39AAH ; Branch to display "-.-" for remaining empty slots if not max
39A7H JMP 387CH ; Print NADSBox directory or TPDD Bank number to LCD

; =========================================================================================
; Print "-.-" for all empty file slots
; =========================================================================================
39AAH PUSH PSW ; Save current file index count on stack
39ABH LXI H,3FCDH ; Point to "-.-" text
39AEH CALL 4A2CH ; Send buffer at M to screen
39B1H POP PSW ; Restore current count
39B2H INR A ; Increment file index number
39B3H CPI 14H ; Compare A with max files that fit on LCD
39B5H JNZ 39AAH ; Jump to print next "-.-" if not done
39B8H RET

; =========================================================================================
; Handle "D" key from TS-DOS key scan
; =========================================================================================
39B9H CALL 3AA8H ; Test if printer busy. Return if not busy or error
39BCH CALL 4C52H ; LCOPY statement
39BFH JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle "L", "P" and "O" keys from TS-DOS key scan - list or print .DO file contents
; =========================================================================================
39C2H STA FCDFH ; Save key pressed
39C5H LXI D,0007H ; Load offset of Extension bytes
39C8H LHLD FCE4H ; LCD Buffer address of current file selection
39CBH DAD D ; Point to extension bytes in LCD buffer
39CCH MOV A,M ; Get 1st extension byte
39CDH CPI 44H ; Compare byte with "D"
39CFH JNZ 362FH ; Print length of selected file using inverse video if not "D"
39D2H INX H ; Point to 2nd extension byte
39D3H MOV A,M ; Load 2nd extension byte for comparison
39D4H CPI 4FH ; Compare with "0"
39D6H JNZ 3A06H ; Jump to print compressed file
39D9H CALL 3A49H ; Prepare file for reading (open disk file, address of RAM file)
39DCH LDA FCDFH ; Restore key pressed
39DFH CPI 4CH ; Test if key was "L" - List to LCD
39E1H CZ 4C27H ; CLS statement if LCD
39E4H CNZ 3AA8H ; Test if printer busy. Return if not busy or error
39E7H CALL 3A24H ; Get next block of data to display/print (HL=address)
39EAH PUSH PSW ; Push Z flag indicating if a full 128 bytes was read
39EBH CALL 3A6BH ; Display / print file data bytes at HL, A has length
39EEH POP PSW ; Get Z flag indicating if 128 bytes read
39EFH JZ 39E7H ; Jump to process more if 128 bytes were read last time
39F2H LDA FCDFH ; Restore key pressed
39F5H CPI 4CH ; Test if key was "L"
39F7H JNZ 3A00H ; Skip beep if printing
39FAH MVI A,07H ; Load code for BELL
39FCH RST 4 ; Go print a BELL (beep)
39FDH CALL 3DF8H ; Process power-off logic and wait for a key from keyboard

; =========================================================================================
; Clear screen and perform Long Jump
; =========================================================================================
3A00H CALL 4C27H ; CLS statement
3A03H JMP 48B5H ; Branch to "Long Jump" operation

; =========================================================================================
; Handler for the "O" key - print a compressed file??
; =========================================================================================
3A06H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A09H ANA A ; Test if in Disk mode
3A0AH JNZ 362FH ; Jump to keyscan if in Disk mode
3A0DH LHLD FCE4H ; LCD Buffer address of current file selection
3A10H CALL 4902H ; Copy filename at (HL) to current BASIC program
3A13H CALL 4A51H ; Get RAM directory address of current BASIC program
3A16H CPI C0H ; Test if filetype is .DO
3A18H CZ 5004H ; Call routine to Compress / Decompress .DO files
3A1BH CALL 4C0FH ; Update system pointers
3A1EH CALL 3611H ; Print Copyright and files
3A21H JMP 362FH ; Jump to keyscan

; =========================================================================================
; Get next 128 bytes (or less) of data from RAM or disk file for display
; =========================================================================================
3A24H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A27H ANA A ; Test if RAM mode
3A28H JNZ 40B6H ; If not RAM mode, go send TPDD_READ data opcode and recieve response
3A2BH LHLD FCDDH ; Get length of file to be displayed / printed
3A2EH LXI B,0080H ; Prepare to subtract 128 from length
3A31H MOV A,C ; Save 128 to A
3A32H DSUB ; Subtract 128 from file length
3A33H JNC 3A3AH ; Branch if length >= 128
3A36H DAD B ; Add 128 back to length to print "partial" buffer
3A37H MOV A,L ; Move remainder of bytes to display/print
3A38H MOV L,H ; Clear LSB of remainder
3A39H MOV C,A ; Move LSB of remainder to C
3A3AH SHLD FCDDH ; Save new remaining file length
3A3DH LHLD FCE0H ; Load the address to be printed / saved
3A40H PUSH H ; Save on stack
3A41H DAD B ; Update address to be used for display/printing next time
3A42H SHLD FCE0H ; Save address to be displayed / printed
3A45H POP H ; Retrieve address to be printed this loop from stack
3A46H CPI 80H ; Compare length with maximum
3A48H RET

; =========================================================================================
; Initialize Selected file for display (RAM or Disk)
; =========================================================================================
3A49H CALL 4A3BH ; Initialize blank filename and attribute byte
3A4CH LHLD FCE4H ; LCD Buffer address of current file selection
3A4FH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A52H ANA A ; Test if in RAM mode
3A53H JNZ 3A65H ; Branch to process Disk files if in Disk mode
3A56H CALL 4A4BH ; Get RAM directory address of selected file
3A59H PUSH D ; Push file address to stack
3A5AH CALL 3CD3H ; Calculate length of RAM file, HL=address of catalog entry, DE=file address
3A5DH SHLD FCDDH ; Save length to FDC emulation sector storage area
3A60H POP H ; Pop address of file into H
3A61H SHLD FCE0H ; Save file address
3A64H RET

; =====================================================================================
; Send TPDD Open command to open selected file
; =====================================================================================
3A65H CALL 3D95H ; Copy filename at (HL) to TX buffer
3A68H JMP 408AH ; Open TPDD file for Read Mode

; =====================================================================================
; Display / print file data bytes at HL, A has length
; =====================================================================================
3A6BH XCHG ; HL <--> DE
3A6CH ORA A ; Test if length = 0
3A6DH RZ ; Return if length = 0
3A6EH MOV C,A ; Save length count in C
3A6FH LDA FCDFH ; Load key press value
3A72H CPI 4CH ; Test if key was "L"
3A74H JNZ 3A82H ; Jump to print contents if not "L"
3A77H CALL 3A8FH ; Check for CTRL-C
3A7AH LDAX D ; Load next byte from src pointer
3A7BH RST 4 ; Send A to LCD
3A7CH INX D ; Increment the pointer
3A7DH DCR C ; Decrement the length count
3A7EH JNZ 3A77H ; Keep looping until all data displayed
3A81H RET

; =====================================================================================
; Print file data bytes at HL, A has length
; =====================================================================================
3A82H CALL 3A8FH ; Test for CTRL-C, etc.
3A85H LDAX D ; Load next file byte from source poiner
3A86H CALL 4C42H ; Print A to printer, expanding tabs if necessary
3A89H INX D ; Increment pointer
3A8AH DCR C ; Decrement length count
3A8BH JNZ 3A82H ; Keep looping until all data printed
3A8EH RET

; =========================================================================================
; Test for ESC, CTRL-C or Space
; =========================================================================================
3A8FH CALL 4C4AH ; Check keyboard queue for pending characters
3A92H RZ ; Return if no pending characters
3A93H CALL 4BEBH ; Wait for key from keyboard
3A96H CPI 03H ; Test for F4 maybe?
3A98H JZ 3A00H ; Clear screen and perform Long Jump if F4 maybe?
3A9BH CPI 1BH ; Test for ESC key
3A9DH JZ 3A00H ; Clear screen and perform Long Jump if ESC
3AA0H CPI 20H ; Test for space key
3AA2H JNZ 3A8FH ; Branch back to wait for ESC, CTRL-C or space if not space
3AA5H JMP 4BEBH ; Wait for key from keyboard

; =========================================================================================
; Test if printer busy. Return if not busy, print error if it is
; =========================================================================================
3AA8H IN BBH ; Get printer port input
3AAAH ANI 06H ; Mask all but BUSY and /BUSY
3AACH XRI 02H ; Compliment /BUSY
3AAEH JNZ 487BH ; Printer not ready / FF error
3AB1H RET

; =========================================================================================
; Print currently selected file using inverse video
; =========================================================================================
3AB2H CALL 3ACDH ; Calculate Row and Column of newly selected file
3AB5H SHLD FCE4H ; LCD Buffer address of current file selection
3AB8H CALL 4C2FH ; Start inverse character mode
3ABBH DCX H ; Start drawing from left edge of selection (include space)
3ABCH MVI C,0AH ; Draw 10 characters
3ABEH CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
3AC1H JMP 4C33H ; Cancel inverse character mode

; =========================================================================================
; Print selected file using normal video to "unselect" it
; =========================================================================================
3AC4H CALL 4C33H ; Cancel inverse character mode
3AC7H CALL 3ACDH ; Calculate row and column of newly selected file
3ACAH JMP 3ABBH ; Print the file to the LCD

; =========================================================================================
; Calculate Row and Column of soon-to-be (newly) selected file
; =========================================================================================
3ACDH LDA FCD5H ; Currently selected file index
3AD0H DCR A ; Make selected file zero based
3AD1H MOV L,A ; Save index to 16-bit HL
3AD2H MVI H,00H ; Make MSB zero
3AD4H LXI D,000AH ; Prepare to multiply index * 10 cols
3AD7H CALL 4C1FH ; Signed integer muliply (FAC1=HL*DE)
3ADAH LXI D,FE28H ; Load address of line 2 in the LCD buffer
3ADDH DAD D ; Calculate starting LCD buffer address for this file
3ADEH INX H ; Skip the "tag" space on the LCD
3ADFH PUSH H ; Save address on the stack
3AE0H LXI B,FE00H ; Load starting address of LCD character buffer
3AE3H DSUB ; Calculate file start offset from start of LCD buffer
3AE4H LXI D,0028H ; Load 1 LCD line width
3AE7H XCHG ; HL <--> DE Prepare for divide
3AE8H CALL 4C1BH ; Signed integer divide (FAC1=DE/HL)
3AEBH MOV A,L ; Save selected file's row number to A
3AECH INR A ; Make row 1-based
3AEDH STA F639H ; Cursor row (1-8)
3AF0H XCHG ; HL <--> DE DE had remainder*2 from divide
3AF1H ASHR ; Divide HL by 2
3AF2H MOV A,L ; Prepare to save remainder as the column
3AF3H STA F63AH ; Cursor column (1-40)
3AF6H POP H ; Restore address of LCD buffer location from stack
3AF7H RET

; =========================================================================================
; F3 Function key handler for RAM mode - Rename
; =========================================================================================
3AF8H CALL 4A4BH ; Get RAM directory address of selected file
3AFBH SHLD FCE0H ; Save address of file being processed
3AFEH LXI H,3F4AH ; Address of "New name" string
3B01H CALL 3E1AH ; Get 6-byte input filename from keyboard
3B04H RZ ; Return if no input provided
3B05H CALL 4902H ; Copy filename at (HL) to current BASIC program
3B08H LHLD FCE0H ; Load RAM directory address of file being renamed
3B0BH LXI B,0009H ; Load offset of extension within catalog entry
3B0EH DAD B ; Point to extension bytes
3B0FH LXI D,FC99H ; Load address of extension field of current BASIC program name
3B12H MOV A,M ; Get 1st byte of extension of catalog file being renamed
3B13H STAX D ; Save extension byte in current BASIC program filename - preserve EXT
3B14H INX D ; Point to 2nd ext byte of BASIC program name
3B15H INX H ; Point to 2nd ext byte of catalog filename
3B16H MOV A,M ; Get 2nd extension byte from catalog filename
3B17H STAX D ; Save byte in current BASIC program filename area
3B18H CALL 4A51H ; Get RAM directory address of current BASIC program
3B1BH JNZ 487EH ; If found, jump to File Exists Error
3B1EH LHLD FCE0H ; Load catalog address of file being renamed
3B21H INX H ; Point to LSB of file address
3B22H INX H ; Point to MSB of file address
3B23H INX H ; Point to name
3B24H LXI D,FC93H ; Load address of filename of current BASIC program
3B27H LXI B,0006H ; Prepare to copy 6 bytes of filename (ext doesn't change)
3B2AH XCHG ; HL <--> DE
3B2BH JMP 4A05H ; Move BC bytes from M to (DE) with increment

; =========================================================================================
; F1 Function key handler for DISK mode - Load
; =========================================================================================
3B2EH CALL 4A3BH ; Initialize blank filename and attribute byte
3B31H LHLD FCE4H ; LCD Buffer address of current file selection
3B34H CALL 3D95H ; Copy filename at (HL) to TX buffer
3B37H LDA FCCCH ; Last Tag/Untag operation code
3B3AH ANA A ; Test if a tag operation is pending
3B3BH JNZ 3B56H ; Branch if doing tag load operation
3B3EH LXI H,3F7AH ; Point to "Load as:" text
3B41H CALL 3E1AH ; Get 6-byte filename input from keyboard
3B44H JZ 3B56H ; Jump to use existing disk name as filename
3B47H CALL 4902H ; Copy filename at (HL) to current BASIC program
3B4AH LXI B,0002H ; Prepare to copy 2 extension bytes to current BASIC program space
3B4DH LXI H,FCEFH ; Point to disk file extension in TX buffer
3B50H LXI D,FC99H ; Point to current BASIC program extension address
3B53H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3B56H CALL 4A51H ; Get RAM directory address of current BASIC program
3B59H JZ 3B69H ; Branch to load if file doesn't already exist
3B5CH LXI H,3FB0H ; Point to "File Exists, Replace?" text
3B5FH CALL 48F4H ; Print string at HL to col 1 on the bottom line
3B62H CALL 3DEEH ; Get key from keyboard and test for 'Y' or 'y'
3B65H RNZ ; Return if isn't 'y' or 'Y'
3B66H CALL 3C38H ; Kill file in current BASIC program space
3B69H LHLD FD1DH ; Get file size from RX buffer
3B6CH MOV A,H ; Swap bytes (big endian in RX buffer)
3B6DH MOV H,L ; Move LSB to MSB
3B6EH MOV L,A ; Move MSB to LSB
3B6FH SHLD FD1DH ; Save with little endian to RX buffer
3B72H LDA FCEFH ; Get 1st byte of extension from TX buffer
3B75H CPI 44H ; Test if 1st extension byte is "D"
3B77H JNZ 3B82H ; Jump if not "D" to check for "C" or "B"
3B7AH LHLD FBAEH ; Get start of DO files pointer for location of new file
3B7DH MVI A,C0H ; Load file type code for .DO files
3B7FH JMP 3BA3H ; Process the file load

; =========================================================================================
; Test file exension type in A for .CO files
; =========================================================================================
3B82H CPI 43H ; Test if A contains "C"
3B84H JNZ 3B95H ; Branch if not .CO file
3B87H LHLD FBB0H ; Start of CO files pointer
3B8AH SHLD FCD5H ; Save in currently selected file index storage area
3B8DH LHLD FBB2H ; Get Start of variable data pointer as location for new file
3B90H MVI A,A0H ; Load file type code for .CO files
3B92H JMP 3BA3H ; Process the file load

; =========================================================================================
; Process load of .BA file
; =========================================================================================
3B95H LHLD FD1DH ; Get file size from RX buffer
3B98H SHLD FCD5H ; Save in Currently selected file index storage
3B9BH LHLD F99AH ; Get BASIC program not saved pointer
3B9EH SHLD FCE0H ; Save as address of file being processed
3BA1H MVI A,80H ; Load file type code for .BA files

; =========================================================================================
; Process file load operation
; =========================================================================================
3BA3H STA FCDFH ; Save file type code for later
3BA6H SHLD FCE2H ; Save address for new file
3BA9H LHLD FD1DH ; Get file size from RX buffer
3BACH SHLD FCDDH ; Save in FDC emulation physical/logical sector storage area
3BAFH PUSH H ; Save file size on stack
3BB0H POP B ; Copy file size to BC
3BB1H LDA FCDFH ; Get file type code
3BB4H CPI A0H ; Test for .CO file
3BB6H JZ 3BC0H ; Skip increment if .CO file (.BA has trailing 0x0000, .DO a 0x1A)
3BB9H INX B ; Increment file length for .BA and .DO files
3BBAH CPI 80H ; Test if file is .BA
3BBCH JNZ 3BC0H ; Skip additional increment if .BA
3BBFH INX B ; Add 1 more to length for .BA files to account for both trailing 0's
3BC0H PUSH B ; Save updated length on stack
3BC1H CALL 3E48H ; Find empty catalog entry
3BC4H JC 4887H ; Generate system error 0x0A ("DD") if full
3BC7H POP B ; Get length from stack
3BC8H PUSH H ; Save new file catalog address on stack
3BC9H PUSH B ; Save new file length on stack
3BCAH LHLD FCE2H ; Get address for new contents of new file
3BCDH CALL 4C0BH ; Insert BC spaces at M - make room
3BD0H JC 488AH ; Branch if error - RAM full error
3BD3H LHLD FCE2H ; Restore address of new file contents
3BD6H POP B ; Get file length from stack
3BD7H MVI M,00H ; Fill newly created file space with zero's
3BD9H INX H ; Increment pointer
3BDAH DCX B ; Decrement count
3BDBH MOV A,C ; Move LSB to A to check for zero - could use JNX here!
3BDCH ORA B ; Or in MSB to check for zero
3BDDH JNZ 3BD7H ; Keep looping until all are zero
3BE0H DCX H ; Decrement pointer to last byte in new file
3BE1H POP D ; Get File catalog address from stack
3BE2H LDA FCDFH ; Load file type code byte
3BE5H CPI C0H ; Test for .DO file
3BE7H JNZ 3BF3H ; Branch if not .DO file
3BEAH MVI M,1AH ; Terminate .DO file with EOF marker
3BECH LHLD FCE2H ; Reload address of new file contents
3BEFH DCX H ; Decrement pointer to jump into middle of loop
3BF0H JMP 3C1BH ; Write file entry to catalog

; =========================================================================================
; Process end-of-file / file length for .CO and .BA files
; =========================================================================================
3BF3H CPI A0H ; Test if new file is .CO
3BF5H JNZ 3C04H ; Branch if not .CO - must be .BA
3BF8H LHLD FCD5H ; Get old start of CO files pointer
3BFBH SHLD FBB0H ; Save as current start of CO files pointer
3BFEH LHLD FCE2H ; Reload address of new file contents
3C01H JMP 3C1BH ; Write file entry to catalog

; =========================================================================================
; Process end-of-file for .BA files
; =========================================================================================
3C04H PUSH D ; Push file catalog address to stack
3C05H LHLD FBAEH ; Get start of DO files pointer
3C08H DCX H ; Decrement address by 1
3C09H SHLD F99AH ; Save as new BASIC program not saved pointer
3C0CH INX H ; Increment back to start of .DO files
3C0DH XCHG ; HL <--> DE DE has start of DO files
3C0EH LHLD FCD5H ; Get BA file size
3C11H INX H ; Increment file size to account for trailing 0's
3C12H INX H ; Increment file size to account for trailing 0's
3C13H DAD D ; Add new length to start of DO files pointer
3C14H SHLD FBAEH ; Save new start of DO files pointer
3C17H POP D ; Retrieve file catalog address from stack
3C18H LHLD FCE0H ; Reload address of new file contents

; =========================================================================================
; Write file entry to catalog
; =========================================================================================
3C1BH XCHG ; HL <--> DE DE has file address, HL has catalog address
3C1CH CALL 4C17H ; Write new entry to catalog (A=type, DE=file address,HL=catalog address)
3C1FH CALL 4127H ; Open TPDD file and read data to file address being processed
3C22H CALL 4C0FH ; Update system pointers
3C25H LXI H,0002H ; Load TPDD_READ opcode in HL
3C28H JMP 409BH ; Send Request in HL and await response

; =========================================================================================
; F2 Function key handler for RAM mode - Kill
; =========================================================================================
3C2BH LDA FCCCH ; Get last Tag/Untag operation code
3C2EH ANA A ; Test if there is a pending tag operation
3C2FH CZ 3DE1H ; Display "Sure ?", validate and return if validated if no tag
3C32H LHLD FCE4H ; LCD Buffer address of current file selection
3C35H CALL 4902H ; Copy filename at (HL) to current BASIC program

; =========================================================================================
; Kill file in current BASIC program space
; =========================================================================================
3C38H CALL 4A51H ; Get RAM directory address of current BASIC program
3C3BH CPI C0H ; Test if file is .DO
3C3DH JZ 4BFFH ; Kill .DO file
3C40H CPI A0H ; Test if file is .CO
3C42H JZ 4C07H ; Kill .CO file
3C45H CPI 80H ; Test if file is .BA
3C47H JZ 4C03H ; Kill .BA file
3C4AH RET

; =========================================================================================
; F1 Function key handler for RAM mode - Save
; =========================================================================================
3C4BH CALL 4A3BH ; Initialize blank filename and attribute byte
3C4EH CALL 4A4BH ; Get RAM directory address of selected file
3C51H PUSH D ; Push file address to stack
3C52H PUSH H ; Push file catalog address to stack
3C53H INX H ; Point to LSB of file address
3C54H INX H ; Point to MSB of file address
3C55H INX H ; Point to filename in catalog
3C56H LXI D,FCE8H ; Point to TX buffer data area (payload)
3C59H LXI B,0006H ; Prepare to copy 6 filename bytes to TX packet data
3C5CH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C5FH MVI A,2EH ; Load code for '.'
3C61H STAX D ; Store '.' separator in TX packet data
3C62H INX D ; Increment TX packet data pointer
3C63H LXI B,0002H ; Prepare to copy 2 extention bytes from catalog
3C66H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C69H LDA FCCCH ; Last Tag/Untag operation code
3C6CH ANA A ; Test if a tag save operation is being performed
3C6DH JNZ 3C88H ; Jump ahead if doing a tag save - skip filename questioning
3C70H LXI H,3F71H ; Point to "Save as:" text
3C73H CALL 3E1AH ; Get 6-byte input filename from keyboard
3C76H JZ 3C88H ; Skip ahead to use catalog name if no input given
3C79H CALL 4902H ; Copy filename at (HL) to current BASIC program
3C7CH LXI B,0006H ; Prepare to copy 6 filename bytes from input string
3C7FH LXI D,FCE8H ; Point to filename area in TX buffer
3C82H LXI H,FC93H ; Filename of current BASIC program
3C85H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C88H POP H ; Restore file catalog address from stack
3C89H POP D ; Restore file address from stack
3C8AH PUSH D ; Save file address on stack
3C8BH CALL 3CD3H ; Calculate length of RAM file, HL=address of catalog entry, DE=file address
3C8EH MOV A,H ; Test for zero length file - move H to A
3C8FH ORA L ; OR LSB to test for zero
3C90H JZ 4884H ; Branch if empty - File Empty Error
3C93H PUSH H ; Save file address to stack
3C94H MVI A,01H ; Set file open mode to new file
3C96H STA FCD6H ; Save open mode to pass to open routine
3C99H CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3C9CH CALL 4A72H ; Send Dir Reference opcode
3C9FH JZ 3CCEH ; Jump to write data if file doesn't exist (size = 0)
3CA2H LXI H,3F8BH ; Point to "File Exists, A)ppend R)eplace Q)uit" text
3CA5H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3CA8H CALL 3DF8H ; Process power-off logic and wait for a key from keyboard
3CABH ANI DFH ; Make key uppercase
3CADH RST 4 ; Display key on LCD
3CAEH CPI 52H ; Test if key is 'R'
3CB0H JNZ 3CBCH ; Jump if not 'R'eplace
3CB3H CALL 431AH ; Issue TPDD Delete file Opcode
3CB6H CALL 4A72H ; Send Dir Reference opcode
3CB9H JMP 3CCEH ; Go write data to the file

; =========================================================================================
; F1-Save: Test for 'A'ppend
; =========================================================================================
3CBCH POP H ; Get file length from stack
3CBDH POP D ; Get file address from stack
3CBEH CPI 41H ; Test if response is 'A'ppend
3CC0H RNZ ; Return if not 'A'
3CC1H LDA FCEFH ; Load 1st byte of extension from TX buffer
3CC4H CPI 44H ; Test if file is "D"O file
3CC6H RNZ ; Don't allow appending non DO files
3CC7H MVI A,02H ; Set open mode to open existing (append)
3CC9H STA FCD6H ; Save mode to pass to open routine
3CCCH PUSH D ; Save file address on stack
3CCDH PUSH H ; Save file length on stack

; =========================================================================================
; Save function - Replace or new file, write data to file
; =========================================================================================
3CCEH POP H ; Retrieve file length from stack
3CCFH POP D ; Retrieve file address from stack
3CD0H JMP 40C8H ; Write HL bytes of data from (DE) to TPDD

; =========================================================================================
; Calculate length of RAM file, HL=address of catalog entry, DE=file address
; =========================================================================================
3CD3H MOV A,M ; Get RAM file type from catalog
3CD4H CPI C0H ; Test for .DO file
3CD6H JZ 3CE6H ; Jump to calculate length if .DO file
3CD9H CPI A0H ; Test for .CO file
3CDBH JZ 3CF5H ; Jump to calculate length if .CO file
3CDEH PUSH D ; Save address of start of BASIC program to stack
3CDFH CALL 4C13H ; Call ROM routine to find BASIC end of program
3CE2H POP B ; Get BASIC program start address from stack
3CE3H DSUB ; Subtract starting address from end address
3CE4H DCX H ; Don't count trailing 0x00 as part of BASIC program length
3CE5H RET

; =========================================================================================
; Calculate length of .DO file, HL=Catalog address, DE=file address
; =========================================================================================
3CE6H XCHG ; HL <--> DE Get file address in HL
3CE7H LXI D,0000H ; Clear file length
3CEAH MOV A,M ; Get next byte from .DO file
3CEBH INX H ; Increment pointer
3CECH INX D ; Increment length
3CEDH CPI 1AH ; Test for EOF marker
3CEFH JNZ 3CEAH ; Branch to next byte if not EOF
3CF2H DCX D ; Subtract EOF marker from file length
3CF3H XCHG ; HL <--> DE HL=length
3CF4H RET

; =========================================================================================
; Calculate length of .CO file, HL=Catalog address, DE=file address
; =========================================================================================
3CF5H XCHG ; HL <--> DE Get file address in HL
3CF6H INX H ; Increment past .CO load address
3CF7H INX H ; Increment past MSB of load address
3CF8H MOV C,M ; Get LSB of length
3CF9H INX H ; Increment to MSB of length
3CFAH MOV B,M ; Get MSB of length
3CFBH LXI H,0006H ; Prepare to add 6-byte header to length
3CFEH DAD B ; Add 6-byte header to length
3CFFH RET

; =========================================================================================
; F7 Function key handler for DISK mode - Mkdir
; =========================================================================================
3D00H LDA FCCBH ; NADSBox / TPDD2 / Desklink flag
3D03H ANA A ; Test if server is TPDD
3D04H RZ ; Return if not NADSBox or TPDD2
3D05H DCR A ; Test if TPDD2
3D06H JZ 37BAH ; Go Swap TPDD Bank Number if TPDD2
3D09H CALL 4A3BH ; Must be NADSBOx Initialize blank filename
3D0CH LXI H,3F61H ; Load pointer to "Directory name:" text
3D0FH CALL 3E1AH ; Get 6-byte input filename from keyboard
3D12H RZ ; Return if no input given
3D13H CALL 4902H ; Copy filename at (HL) to current BASIC program
3D16H LXI H,FC93H ; Filename of current BASIC program
3D19H LXI D,FCE8H ; Point to TX buffer data area (payload)
3D1CH LXI B,0006H ; Prepare to copy 6 filename bytes to TX buffer
3D1FH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3D22H LXI H,3E3CH ; Load code for "<>"
3D25H SHLD FCEFH ; Save "<>" extension bytes in TX buffer - NADSBox Mkdir
3D28H MVI A,2EH ; Load code for '.' extension separator
3D2AH STA FCEEH ; Save "." to TX buffer
3D2DH CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D30H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
3D33H CPI 02H ; Test if we have NADSBox current directory
3D35H RNZ ; Return if we don't have current directory
3D36H CALL 4A72H ; Send Directory Reference opcode
3D39H JNZ 3D4DH ; If the file exists, branch to open it for READ mode
3D3CH MVI A,01H ; Load OPEN_WRITE mode into A to create the directory
3D3EH STA FCE8H ; Save A in TX data storage mode field
3D41H LXI H,0101H ; Load opcode to open a file
3D44H CALL 409BH ; Send Request in HL and await response
3D47H LXI H,0002H ; Load opcode to close the file
3D4AH JMP 409BH ; Send Request in HL and await response

; =========================================================================================
; Open and close a directory file (from above)
; =========================================================================================
3D4DH CALL 408AH ; Open TPDD file for Read Mode
3D50H JMP 3D47H ; Branch to close the directory open request

; =========================================================================================
; F5 Function key handler for DISK mode - Format
; =========================================================================================
3D53H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
3D56H CPI 02H ; Test if we have "current directory" name
3D58H RZ ; Return if server is NADSBox / Desklink - No format supported
3D59H LXI H,3F1BH ; Load pointer to "Insert Disk" string
3D5CH CALL 48F4H ; Print string at HL to col 1 on the bottom line
3D5FH CALL 3DEEH ; Get key from keyboard and test for 'Y' or 'y'
3D62H RNZ ; Return if response not 'Y'
3D63H CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D66H CALL 49E3H ; Delay routine - about 3ms
3D69H LXI H,0006H ; Load TPDD_FORMAT opcode in HL
3D6CH CALL 409BH ; Send Request in HL and await response
3D6FH MVI A,07H ; Load code for BELL
3D72H RET ; Go beep to indicate format

; =========================================================================================
; F2 Function key handler for DISK mode - Kill
; =========================================================================================
3D73H LDA FCCCH ; Last Tag/Untag operation code
3D76H ANA A ; Test if there's an active tag group
3D77H CZ 3DE1H ; Display "Sure ?", validate and return if validated if no tag
3D7AH CALL 4A3BH ; Initialize blank filename and attribute byte
3D7DH CALL 3D83H ; Copy selected filename to TX buffer and init TPDD/NADSBox
3D80H JMP 431AH ; Issue TPDD Delete file Opcode

; =========================================================================================
; Copy selected filename to TX buffer and init TPDD/NADSBox
; =========================================================================================
3D83H LXI B,0009H ; Prepare to copy 9 filename bytes
3D86H LHLD FCE4H ; LCD Buffer address of current file selection
3D89H LXI D,FCE8H ; Address of TX packet data
3D8CH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3D8FH CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D92H JMP 4A72H ; Send Dir Reference opcode

; =========================================================================================
; Copy filename at (HL) to TX buffer
; =========================================================================================
3D95H CALL 4902H ; Copy filename at (HL) to current BASIC program
3D98H LXI H,FC93H ; Filename of current BASIC program
3D9BH CALL 4A57H ; Send Dir Reference for filename at (HL)
3D9EH RET

; =========================================================================================
; F3 Function key handler for DISK mode - Name
; =========================================================================================
3D9FH CALL 4A3BH ; Initialize blank filename and attribute byte
3DA2H CALL 3D83H ; Copy selected filename to TX buffer and init TPDD/NADSBox
3DA5H LXI H,FCE8H ; Point to TX buffer data area (payload)
3DA8H LXI D,FC9CH ; Filename of last program loaded from tape
3DABH LXI B,0009H ; Prepare to copy 9 bytes to "last program loaded" filename
3DAEH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3DB1H LHLD FD1DH ; Get file size from RX buffer
3DB4H MOV C,H ; Save file size MSB to C (swap endian)
3DB5H MOV B,L ; Save file size LSB to B (swap endian)
3DB6H LXI H,7CC0H ; ? Load HL with 31936
3DB9H DSUB ; ? Compare file length with 31936
3DBAH LXI H,3F4AH ; Address of "New name" string
3DBDH JNZ 3DD7H ; Branch to change filename if not 30656
3DC0H LXI B,0009H ; Allow a 9-byte filename input string
3DC3H CALL 3E1DH ; Get max BC length input for filename and convert to uppercase
3DC6H RZ ; Return if no input provided
3DC7H PUSH H ; Save pointer to input string to stack
3DC8H PUSH PSW ; Save string length to stack
3DC9H CALL 4A3BH ; Initialize blank filename and attribute byte
3DCCH POP PSW ; Get string length from stack
3DCDH POP H ; Get string address from stack
3DCEH LXI D,FCE8H ; Point to TX buffer data area (payload)
3DD1H MOV C,A ; Copy length to BC
3DD2H MVI B,00H ; Make MSB of length = 0
3DD4H JMP 41B0H ; Rename the TPDD file whose name is in (HL)

; =========================================================================================
; Get filename from keyboard and rename Disk file, filename in "current BASIC program"
; =========================================================================================
3DD7H CALL 3E1AH ; Get 6-byte input filename from keyboard
3DDAH RZ ; Return if no input provided
3DDBH CALL 4902H ; Copy filename at (HL) to current BASIC program
3DDEH JMP 41A7H ; Rename the TPDD file whose name is in "current BASIC program"

; =========================================================================================
; Display "Sure ?", validate and return if validated
; =========================================================================================
3DE1H LXI H,3F83H ; Load pointer to "Sure ?" string
3DE4H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3DE7H CALL 3DEEH ; Get key and test for 'Y' or 'y'
3DEAH JNZ 48B5H ; Branch to "Long jump" operation to abort if not 'y'
3DEDH RET

; =========================================================================================
; Get key from keyboard and test for 'Y' or 'y'
; =========================================================================================
3DEEH CALL 3DF8H ; Process power-off logic and wait for a key from keyboard
3DF1H RST 4 ; Display the key on the LCD
3DF2H CPI 59H ; Test if key pressed was 'Y'
3DF4H RZ ; Return if key pressed was 'Y'
3DF5H CPI 79H ; Test if key pressed was 'y'
3DF7H RET

; =========================================================================================
; Process power-off logic and wait for a key from keyboard
; =========================================================================================
3DF8H CALL 3DFEH ; Process automatic poweroff logic
3DFBH JMP 4BEBH ; Wait for key from keyboard

; =========================================================================================
; Process automatic power-off logic during key scan loop
; =========================================================================================
3DFEH XRA A ; Clear A
3DFFH DCR A ; Set A to 0xFF
3E00H STA F656H ; Power off exit condition switch
3E03H CALL 4C4AH ; Check keyboard queue for pending characters
3E06H JZ 3DFEH ; Branch back if no keyboard characters in queue - wait for key
3E09H XRA A ; Clear A
3E0AH STA F656H ; Power off exit condition switch
3E0DH LXI H,F932H ; Load address of "Renew Automatic Poweroff Counter Flag"
3E10H ORA M ; Test if auto poweroff counter should be renewed
3E11H JZ 4BF7H ; Renew automatic power-off counter if enabled
3E14H CALL 4BF3H ; Turn off the computer
3E17H JMP 3DFEH ; Branch back to continue processing power off logic

; =========================================================================================
; Get max 6-byte input for filename and convert to uppercase
; =========================================================================================
3E1AH LXI B,0006H ; Get maximum 6 characters of input

; =========================================================================================
; Get max BC length input for filename and convert to uppercase
; =========================================================================================
3E1DH CALL 3E2FH ; Get max BC length input string from keyboard
3E20H RZ ; Return if no input provided
3E21H PUSH H ; Preserve pointer to input string
3E22H PUSH PSW ; Preserve flags from input
3E23H CALL 4C5EH ; Get char at M and convert to uppercase
3E26H MOV M,A ; Save uppercase char back to string
3E27H INX H ; Point to next byte in input
3E28H ANA A ; Test for NULL - end of string
3E29H JNZ 3E23H ; Keep looping until end of string
3E2CH POP PSW ; Restore flags from input routine
3E2DH POP H ; Restore pointer to input string
3E2EH RET

; =========================================================================================
; Get maximum BC length input character string from keyboard
; =========================================================================================
3E2FH PUSH B ; Save maximum input length to stack
3E30H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3E33H CALL 4C46H ; Input and display (no "?") line and store
3E36H JC 48B5H ; Branch to "Long jump" if CTRL-C
3E39H INX H ; Point to start of input string
3E3AH MOV A,B ; Get string length (counting NULL)
3E3BH DCR A ; Remove NULL from count
3E3CH POP D ; Restore maximum input length
3E3DH RZ ; Return if string length is zero
3E3EH CMP E ; Compare expected length with actual length
3E3FH RC ; Return if string is shorter than expected
3E40H PUSH H ; Save pointer to start of string on stack
3E41H DAD D ; Add Expected length to pointer
3E42H MVI M,00H ; Truncate the string to the max length
3E44H POP H ; Restore pointer to input string
3E45H MOV A,E ; Update length to reflect maximum
3E46H ORA A ; Clear zero flag to indicate input provided
3E47H RET

; =========================================================================================
; Find Empty catalog entry (only 9 instructions...Don't bother with Main ROM)
; =========================================================================================
3E48H LXI H,F9AFH ; Point to the "RickY" catalog entry (start of valid entries)
3E4BH LXI B,000BH ; Load length of each catalog entry
3E4EH DAD B ; Point to next catalog entry to test if empty
3E4FH MOV A,M ; Get file attribute byte from catalog entry
3E50H CPI FFH ; Test if at end of catalog
3E52H JZ 3E5AH ; Jump to report directory full if at end
3E55H ADD A ; Test if MSB is set (entry being used)
3E56H JC 3E4EH ; Jump to test next enry if MSB set
3E59H RET ; Entry found...return with Carry clear

; =========================================================================================
; Empty catalog entry not found...set Carry and exit
; =========================================================================================
3E5AH STC ; Indicate empty entry not found
3E5BH RET

; =========================================================================================
; F5 Function key handler for RAM mode - DOS ON/OF
; =========================================================================================
3E5CH LHLD FB2CH ; Get LFILES statement hook address
3E5FH LXI B,08DBH ; Load address of default (DOS-OFF) hook for LFILES
3E62H DSUB ; Test if in DOS-OFF mode
3E63H JZ 401FH ; Jump to add our custom RST 7 hooks if in DOS-OFF mode
3E66H JMP 3FFAH ; Must be in DOS-ON mode, jump to turn it off

; =========================================================================================
; Strings
; =========================================================================================
3E69H DB 0x1B, "p TS-DOS (100 v4.00) (c)87,TSI. ",0x1B,'q',0x00
3E97H DB "DISK Free: File:",0DH,0AH,"Load Kill Name Ram Frmt Log Menu",00H
3ED9H DB " RAM Free: File:",0DH,0AH,"Save Kill Name Disk DOS- Menu",00H
3F1BH DB "Insert Disk, Press \"Y\" to begin ",00H
3F3CH DB "NOT FORMATTED",00H
3F4AH DB "New Name:",00H
3F54H DB "System name:",00H
3F61H DB "Directory name:",00H
3F71H DB "Save as:",00H
3F7AH DB "Load as:",00H
3F83H DB "Sure ? ",00H
3F8BH DB "File exists, A)ppend R)eplace Q)uit:",00H
3FB0H DB "File exists, Replace? (Y/N):",00H
3FCDH DB "-.- ",00H
3FD8H DB 0x1B,"Y74 ",1BH,"Y7>MkDr",00H ; TODO: Check this
3FE9H DB 0x1B,"Y7>Bank",00H ; TODO: Check this
3FF2H DB "OFF",00H
3FF6H DB "ON ",00H
</pre>

Navigate to:
- [[Dissasembly of RAM and ROM versions of TS-DOS]]
- [[M100 TS-DOS ROM OptROM Support]]
- [[M100 TS-DOS ROM RST 7 Handlers]]
- [[M100 TS-DOS ROM TPDD Protocol]]
- [[M100 TS-DOS ROM Compression]]
- [[M100 TS-DOS ROM Cold Boot Recovery]]

M100 TS-DOS ROM UI Code

2009-04-03T07:37:39Z

Kpettit: New page: == TS-DOS Model 100/102 User Interface Code <pre> ; ========================================================================================= ; TS-DOS UI Entry location ; ================...

== TS-DOS Model 100/102 User Interface Code

<pre>
; =========================================================================================
; TS-DOS UI Entry location
; =========================================================================================

.org 3535H

3535H LXI H,FCC0H ; Start of Alt LCD character buffer
3538H MVI B,B4H ; Prepare to clear 180 bytes from the ALTLCD buffer
353AH XRA A ; Prepare to clear the ALTLCD buffer
353BH CALL 4A34H ; Fill (HL) with B bytes of A
353EH LXI H,0000H ; Prepare to get current stack pointer
3541H DAD SP ; Copy SP into HL
3542H SHLD FCCEH ; Stack pointer upon entry - pointer to arguments
3545H MVI A,01H ; Set flag to print error message to LCD - GUI mode
3547H CALL 4A85H ; Save the currently selected baud rate settings
354AH XRA A ; Zero A to clear our vars
354BH STA FCD4H ; Current Page of files being displayed
354EH STA FCDAH ; TPDD "skip page" count
3551H STA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3554H STA FCCAH ; TPDD2 Bank number
3557H INR A ; A = 1 to select 1st file on page
3558H STA FCCDH ; Currently selected file index
355BH LXI H,3564H ; Get pointer to main loop routine
355EH SHLD FCD0H ; Return vector after error
3561H CALL 4C27H ; CLS statement

; =========================================================================================
; UI Main loop
; =========================================================================================
3564H CALL 4C5AH ; Resume automatic scrolling
3567H CALL 3611H ; Print Copyright and files
356AH LDA FCD5H ; Load currently selected index from temp storage
356DH STA FCCDH ; Currently selected file index
3570H CALL 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Code will return here when a funtion key is pressed (except F4 & F6)
; =========================================================================================
3573H LXI H,48B5H ; Get address of "Long jump"
3576H PUSH H ; Push "Long jump" address to stack
3577H PUSH PSW ; Save function key press to stack
3578H CPI 02H ; Test if function key is F5-F8 (Non file operation F Keys)
357AH JNC 35B9H ; Jump to Function key handler if F5-F8 (No tagging to process)
357DH LDA FCCCH ; Last Tag/Untag operation code
3580H ANA A ; Test if a tag operation was performed
3581H JZ 35B9H ; Jump to Function key handler if no tag operation performed
3584H LDA FCD6H ; Count of files on screen
3587H MOV C,A ; Save count of files for loop decrementing
3588H INR C ; Increment by 1 for loop bounding
3589H MVI B,00H ; Start with index zero on the LCD
358BH PUSH B ; Save the current index on the stack

; =========================================================================================
; Display next file
; =========================================================================================
358CH LDA FCCDH ; Currently selected file index
358FH STA FCD5H ; Currently selected file index - temp
3592H CALL 3AC4H ; Print selected file using normal video
3595H POP B ; Restore index from stack
3596H INR B ; Increment to the next file index to display
3597H DCR C ; Decrement the loop control
3598H JZ 48B5H ; Branch to perform "Long Jump" if all files printed to LCD
359BH MOV A,B ; Get the index of the current file
359CH STA FCD5H ; Save in temporary "current file" area
359FH STA FCCDH ; Currently selected file index
35A2H PUSH B ; Push the value on the stack for the next iteration
35A3H CALL 3AB2H ; Print currently selected file using inverse video
35A6H LHLD FCE4H ; LCD Buffer address of current file selection
35A9H DCX H ; Decrement to the Tag area for the file
35AAH MOV A,M ; Get the file's Tag code
35ABH CPI 3EH ; Compare with '>'
35ADH JNZ 358CH ; Jump to process next file if not tagged
35B0H POP B ; Pop currently selected file value from stack
35B1H POP PSW
35B2H LXI H,358CH ; Return address to display the next file
35B5H PUSH PSW ; ? Stack trickery
35B6H PUSH B ; Save current file index to stack for use after a RET operation
35B7H PUSH H ; Setup "Display next file" as a return address for RET
35B8H PUSH PSW ; ? More stack trickery

; =========================================================================================
; Function key handler - Disk mode and dispatch to RAM mode
; =========================================================================================
35B9H CALL 4C56H ; Stop automatic scrolling
35BCH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
35BFH ORA A
35C0H JZ 35E2H ; Branch if in RAM mode
35C3H POP PSW
35C4H ANA A ; Test for F1
35C5H JZ 3B2EH ; Branch to F1 handler for disk
35C8H DCR A ; Test for F2
35C9H JZ 3D73H
35CCH DCR A ; Test for F3
35CDH JZ 3D9FH
35D0H DCR A ; Skip F4 - handled at lower level
35D1H DCR A ; Test for F5
35D2H JZ 3D53H
35D5H DCR A ; Skip F6 - handled at lower level
35D6H DCR A ; Test for F7
35D7H JZ 3D00H
35DAH DCR A ; Test for F8
35DBH POP H
35DCH JZ 35FEH ; Jump to exit if F8
35DFH JMP 3564H ; Jump to main loop

; =========================================================================================
; Function key handler - RAM mode
; =========================================================================================
35E2H POP PSW
35E3H ANA A ; Test for F1
35E4H JZ 3C4BH
35E7H DCR A ; Test for F2
35E8H JZ 3C2BH
35EBH DCR A ; Test for F3
35ECH JZ 3AF8H
35EFH DCR A ; Skip F4 - handled at lower level
35F0H DCR A ; Test for F5
35F1H JZ 3E5CH
35F4H DCR A ; Skip F6 - handled at lower level
35F5H DCR A ; Skip F7 - not defined for RAM
35F6H DCR A ; Test for F8
35F7H POP H
35F8H JZ 35FEH ; Jump to exit if F8
35FBH JMP 3564H ; Jump back to main loop

; =========================================================================================
; This is the UI exit routine
; =========================================================================================
35FEH CALL 4AC4H ; Restore original baud settings
3601H CALL 4BD7H ; Wait for TX empty and Reset UART to accept mode bits
3604H CALL 4C27H ; CLS statement
3607H CALL 4C5AH ; Resume automatic scrolling
360AH LXI H,0000H
360DH PUSH H
360EH JMP 00A6H ; Exit TS-DOS

; =========================================================================================
; Print Copyright string and files
; =========================================================================================
3611H LXI H,0101H ; Goto top left corner
3614H SHLD F639H ; Cursor row (1-8)
3617H LXI H,3E69H ; Point to "TS-DOS" copyright string
361AH CALL 4A2CH ; Send buffer at M to screen
361DH XRA A ; Indicate no previous Tag/Untag operation
361EH STA FCCCH ; Last Tag/Untag operation code
3621H MVI A,01H ; Start with 1st file in list
3623H STA FCD5H ; Currently selected file index - temp
3626H LXI H,0202H ; Goto first file entry location
3629H SHLD F639H ; Cursor row (1-8)
362CH JMP 383BH ; Draw the display

; =========================================================================================
; Print length of selected file using inverse video
; =========================================================================================
362FH LDA FCCDH ; Currently selected file index
3632H STA FCD5H ; Currently selected file index - temp
3635H CALL 3AB2H ; Print currently seleted file using inverse video
3638H LDA FCD5H ; Currently selected file index - temp
363BH DCR A ; Make index zero based for multiply x2
363CH STC ; Set Carry flag
363DH CMC ; Compliment (clear) carry flag
363EH RLC ; Rotate left circular
363FH MOV E,A ; E = File index * 2 to point to file length value
3640H MVI D,00H ; Clear MSB of file length offset
3642H LXI H,F685H ; Keyboard buffer - store file lengths
3645H DAD D ; Add file lenght offset from beginning of keyboard buffer
3646H XCHG ; HL <--> DE Save file length address pointer in DE
3647H LXI H,2307H ; Load position of File Size area on LCD
364AH SHLD F639H ; Cursor row (1-8)
364DH CALL 4C2BH ; Erase from cursor to end of line
3650H LHLX ; Load HL with file length
3651H CALL 4C2FH ; Start inverse character mode
3654H CALL 4C3EH ; Print binary number in HL at current position
3657H CALL 4C33H ; Cancel inverse character mode

; =========================================================================================
; Keyboard scan loop
; =========================================================================================
365AH CALL 3DFEH ; Process automatic power off logic
365DH CALL 4BEFH ; Scan keyboard for character (CTRL-BREAK ==> CTRL-C)
3660H JZ 365AH ; Jump to scan keyboard again if no key pressed
3663H JC 380CH ; Jump to Function Key Handler if FKey
3666H CPI 0DH ; Test for CR
3668H JZ 3722H
366BH CPI 17H ; Test for Ctrl-Up key
366DH JZ 37AAH
3670H CPI 14H ; Test for Shift-Up key
3672H JZ 3798H
3675H CPI 5DH ; Test for "]" key
3677H JZ 3798H
367AH CPI 3FH ; Test for "?" key
367CH JZ 3777H
367FH CPI 02H ; Test for Shift-Down arrow key
3681H JZ 3777H
3684H CPI 1EH ; Test for up key
3686H JZ 36EEH
3689H CPI 1FH ; Test for down key
368BH JZ 36FCH
368EH CPI 1DH ; Test for "left arrow" key
3690H JZ 36DDH
3693H CPI 1CH ; Test for "Right arrow" key
3695H JZ 36CAH
3698H CPI 20H ; Test for space key
369AH JZ 36CAH ; Treat space the same as right arrow
369DH ANI DFH ; Convert to Upper case
369FH CPI 52H ; Test for 'R' character
36A1H JZ 3759H
36A4H CPI 54H ; Test for 'T' character
36A6H JZ 37EEH
36A9H CPI 41H ; Test for "A" key
36ABH JZ 3715H
36AEH CPI 47H ; Test for "G" key
36B0H JZ 3715H
36B3H CPI 55H ; Test for "U" key
36B5H JZ 37AEH
36B8H CPI 44H ; Test for "D" key
36BAH JZ 39B9H
36BDH CPI 4CH ; Test for "L" key
36BFH JZ 39C2H
36C2H CPI 50H ; Test for "P" key
36C4H JZ 39C2H
36C7H JMP 365AH ; Go scan keyboard again

; =========================================================================================
; Handle Right Arrow key from TS-DOS key scan
; =========================================================================================
36CAH MVI A,01H ; Prepare to add 1 to selected file
36CCH LXI H,FCD5H ; Currently selected file index - temp storage
36CFH ADD M ; Add 1 to the selected file index
36D0H INX H ; Point to file count on screen
36D1H CMP M ; Compare new index with screen file count
36D2H JC 370AH ; Jump to process new file if we didn't wrap
36D5H JZ 370AH ; Jump to process new file if = file count
36D8H MVI A,01H ; Wrap to the first file
36DAH JMP 370AH ; Go process file 1 as the new selection

; =========================================================================================
; Handle Left Arrow key from TS-DOS key scan
; =========================================================================================
36DDH LDA FCD5H ; Currently selected file index - temp storage
36E0H DCR A ; Move to next lowest file index
36E1H JNZ 370AH ; If no wrap, jump to process new selection
36E4H LDA FCD6H ; Count of files on screen
36E7H ANA A ; Ensure there is at least 1 file on the screen
36E8H JZ 365AH ; Jump to keyboard scan loop if no files on LCD
36EBH JMP 370AH ; Go process new selection as the max (wrap-around)

; =========================================================================================
; Handle Up Arrow key from TS-DOS key scan
; =========================================================================================
36EEH LDA FCD5H ; Currently selected file index - temp storage
36F1H SUI 04H ; Subtract 4 from file count (4 files per line)
36F3H JC 365AH ; Jump to keysacn loop if negative
36F6H JZ 365AH ; Jump to keysacn loop if zero
36F9H JMP 370AH ; Go process the new file index setting

; =========================================================================================
; Handle Down Arrow key from TS-DOS key scan
; =========================================================================================
36FCH MVI A,04H ; There are 4 files per line
36FEH LXI H,FCD5H ; Currently selected file index - temp storage
3701H ADD M ; Add 4 to the index number
3702H MOV C,A ; Save new index for comparison and further processing
3703H INX H ; Maximum file index count
3704H MOV A,M ; Load maximum index for bounds
3705H CMP C ; Compare new index with maximum
3706H JC 365AH ; Jump to keyboard scan if moving past last file
3709H MOV A,C ; Restore new current file index
370AH PUSH PSW ; Save new file index for storage after the call
370BH CALL 3AC4H ; Print selected file using normal video
370EH POP PSW ; Restore new file index from stack
370FH STA FCCDH ; Save the new file index
3712H JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle "A" or "G" key from TS-DOS key scan
; =========================================================================================
3715H MVI A,3EH ; Load ">" for the tag symbol
3717H CALL 37CAH ; Go tag all files on the LCD
371AH MVI A,01H ; Indicate last operation as "Tag All"
371CH STA FCCCH ; Last Tag/Untag operation code
371FH JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle Enter key from TS-DOS key scan - Change Directory
; =========================================================================================
3722H LDA FCCBH ; Get NADSBox/Desklink/TPDD2 flag
3725H CPI 02H ; Test if NADSBox current directory valid
3727H JNZ 365AH ; Back to keyscan if no "current directory" - Enter is meaningless
372AH LHLD FCE4H ; LCD Buffer address of current file selection
372DH LXI B,0007H ; Load offset of file extension
3730H DAD B ; Point to file extension of selected file
3731H MOV A,M ; Load the 1st byte of the file extension
3732H CPI 3CH ; Test if 1st byte of extension is "<"
3734H JNZ 365AH ; Jump to keyscan if current selection not directory entry
3737H CALL 4A3BH ; Initialize blank filename and attribute byte
373AH LHLD FCE4H ; LCD Buffer address of current file selection
373DH CALL 3D95H ; Copy filename at (HL) to TX buffer
3740H CALL 408AH ; Open TPDD file for Read Mode
3743H LXI H,0002H ; Load opcode to close currently opened file
3746H CALL 409BH ; Send Request in HL and await response
3749H LHLD FCE4H ; LCD Buffer address of current file selection
374CH LXI D,FCC0H ; NADSBox current directory storage
374FH LXI B,0009H ; Copy 9 bytes of NADSBox directory to the LCD
3752H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3755H XRA A ; Clear A to show 1st page of files
3756H JMP 378AH ; Branch to show the page of files in A

; =========================================================================================
; Handle "R" key from TS-DOS key scan
; =========================================================================================
3759H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
375CH ANA A ; Test if in Disk mode
375DH JNZ 362FH ; Jump to keyscan if in Disk mode
3760H LHLD FCE4H ; LCD Buffer address of current file selection
3763H CALL 4902H ; Copy filename at (HL) to current BASIC program
3766H CALL 4A51H ; Get RAM directory address of current BASIC program
3769H CPI C0H ; Test if filetype is .DO
376BH CZ 5000H ; Call routine to Compress / Decompress .DO files
376EH CALL 4C0FH ; Update system pointers
3771H CALL 3611H ; Print Copyright and files
3774H JMP 362FH ; Jump to keyscan

; =========================================================================================
; Handle "?" and Shift-Down key from TS-DOS key scan
; =========================================================================================
3777H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
377AH ANA A ; Test if RAM mode
377BH JZ 365AH ; Branch to keyscan if in RAM mode
377EH LDA FCD6H ; Count of files on screen
3781H CPI 14H ; Maximum number of files that fit on the screen
3783H JC 365AH ; Branch to keyscan if on last page
3786H LDA FCD4H ; Current Page of files being displayed
3789H INR A ; Increment to next page of files

; =========================================================================================
; Show the page of files indicated by A
; =========================================================================================
378AH STA FCD4H ; Current Page of files being displayed
378DH MVI A,01H ; Go to 1st file on the new page
378FH STA FCCDH ; Currently selected file index
3792H CALL 3611H ; Print copyright and files
3795H JMP 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Handle "]" and Shift-Up key from TS-DOS key scan
; =========================================================================================
3798H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
379BH ANA A ; Test if RAM mode
379CH JZ 365AH ; Branch to keyscan if in RAM mode
379FH LDA FCD4H ; Current Page of files being displayed
37A2H ANA A ; Test if current page is zero
37A3H JZ 365AH ; Branch to keyscan if already on page 0
37A6H DCR A ; Decrement the page number
37A7H JMP 378AH ; Show the page of files indicated by A

; =========================================================================================
; Handle Ctrl-Up key from TS-DOS key scan
; =========================================================================================
37AAH XRA A ; Go to page zero
37ABH JMP 378AH ; Show the page of files indicated by A

; =========================================================================================
; Handle "U" key from TS-DOS key scan - Remove all tags
; =========================================================================================
37AEH MVI A,20H ; Display ' ' as the tag marker
37B0H CALL 37CAH ; Go process tag for all files
37B3H XRA A ; Indicate last tag operation was untag
37B4H STA FCCCH ; Store as "last tag" operation
37B7H JMP 362FH ; Print length of selected file using inverse video

; =========================================================================================
; Swap TPDD2 Bank number
; =========================================================================================
37BAH LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
37BDH DCR A ; Test if the flag = 1 (TPDD2)
37BEH JNZ 365AH ; Jump to keyscan if not 1
37C1H LDA FCCAH ; Get TPDD Bank Number
37C4H XRI 01H ; Switch to the other bank
37C6H STA FCCAH ; Save TPDD bank number
37C9H RET

; =========================================================================================
; Process Tag or Untag for all files on screen
; =========================================================================================
37CAH STA FCCCH ; Store tag/untag code for later
37CDH LDA FCD6H ; Get Maximum file count on screen
37D0H ANA A ; Test for zero
37D1H RZ ; Return if no files on screen
37D2H XRA A ; Clear A
37D3H INR A ; A=1 to selet 1st file
37D4H STA FCD5H ; Currently selected file index
37D7H CALL 3ACDH ; Calculate Row and Column of soon-to-be (newly) selected file
37DAH LHLD FCE4H ; LCD Buffer address of current file selection
37DDH DCX H ; Point to Tag location for the file
37DEH LDA FCCCH ; Get the tag/untag code
37E1H RST 4 ; Display A to the LCD
37E2H LDA FCD5H ; Get currently selected file index
37E5H LXI H,FCD6H ; Point to count of files on screen
37E8H CMP M ; Compare current selection with count of files on LCD
37E9H JC 37D3H ; Jump to process next file if more files left
37ECH ANA A ; Set zero flag to indicate files were tagged/untagged
37EDH RET

; =========================================================================================
; Handle "T" key key from TS-DOS key scan - TAG
; =========================================================================================
37EEH CALL 3ACDH ; Calculate Row and Column of soon-to-be (newly) selected file
37F1H CALL 4C2FH ; Start inverse character mode
37F4H LHLD FCE4H ; LCD Buffer address of current file selection
37F7H DCX H ; Point to the "Tag" area for the file
37F8H MVI A,3EH ; Load the code for ">"
37FAH CMP M ; Compare if file is already tagged
37FBH JNZ 3800H ; Skip ahead if already tagged
37FEH MVI A,20H ; Need to untag - load the untag code
3800H RST 4 ; Display the tag code on the LCD
3801H CALL 4C33H ; Cancel inverse character mode
3804H LXI H,FCCCH ; Point to "last tag" operation code
3807H MVI M,01H ; Indicate last operation was "tag"
3809H JMP 36CAH ; Move to next file - jump to Right Arrow key handler

; =========================================================================================
; 1st level Function Key Handler (handles F4 and F6)
; =========================================================================================
380CH CPI 08H ; Test for valid function key code
380EH JNC 365AH ; Branch back to scan loop if invalid
3811H CPI 05H ; Test for F6
3813H JZ 3833H ; Jump if F6 pressed
3816H CPI 03H ; Test for F4
3818H RNZ ; Return to "Main Loop" if not F4 pressed
3819H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
381CH XRI 01H ; Swap RAM/DISK mode
381EH STA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3821H XRA A ; Clear A to go to 1st page of files
3822H STA FCD4H ; Current Page of files being displayed
3825H MVI A,01H ; Select the 1st file in the page
3827H STA FCCDH ; Currently selected file index
382AH CALL 4C27H ; CLS statement
382DH CALL 3611H ; Print the title bar and files
3830H JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; F6 Function Key Handler
; =========================================================================================
3833H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3836H ANA A ; Test if in RAM or DISK mode
3837H RZ ; Return if RAM mode
3838H JMP 37AAH ; Jump to Ctrl-Up key handler

; =========================================================================================
; Draw the display. This takes care of RAM and Disk mode displays, handles
; skipping page number to the proper "Disk" page, displaying the Bank# or
; current directory for NADSBox/Desklink, showing free space, filling in
; empty slots with "-.-", etc.
; =========================================================================================
383BH LXI H,F685H ; Keyboard buffer
383EH SHLD FCDBH ; Initialize pointer to file length table (in keyboard buffer)
3841H XRA A ; Prepare to set 1st file lenght to zero
3842H MOV M,A ; Set LSB of length of 1st file to zero
3843H INX H ; Increment to MSB of length
3844H MOV M,A ; Set MSB of length of file to zero
3845H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3848H ANA A ; Test if RAM or DISK
3849H JZ 395DH ; Jump to show RAM files if in RAM mode
384CH XRA A ; Prepare to initialize the "page being processed" variable
384DH STA FCDAH ; Clear the "page being processed" variable
3850H CALL 4735H ; Clear #files displayed, init TPDD and send 1st file dir referene opcode
3853H JNZ 390FH ; Process unformated disk (empty slots and error message)
3856H LDA FCD4H ; Current Page of files being displayed
3859H ANA A ; Test if displaying page 0
385AH JZ 3871H ; Jump if showing page 0 - don't need to skikp any pages
385DH STA FCDAH ; Initialize the number of pages left to skip count
3860H CALL 4742H ; Read next page of files from server
3863H LDA FCDAH ; Get the "Pages left to skip" count
3866H DCR A ; Decrement the remaining skip page count
3867H JNZ 385DH ; Keep reading pages until we have skipped enough pages
386AH XRA A ; Prepare to clear the remaining skip page count
386BH STA FCDAH ; Clear the remaining skip page count
386EH STA FCD6H ; Count of files on screen
3871H CALL 4742H ; Read next page of files from server
3874H LDA FCD6H ; Count of files on screen
3877H CPI 14H ; Test if all file slots are full
3879H CC 39AAH ; Print "-.-" for all empty file slots (if any)

; =========================================================================================
; Print NADSBox directory or TPDD Bank number to LCD
; =========================================================================================
387CH LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
387FH ANA A ; Test if server is TPDD
3880H JZ 389FH ; Skip processing Bank # or Current Dir if TPDD
3883H DCR A ; Test if server is TPDD2
3884H JZ 388DH ; Jump to print bank number if TPDD2
3887H LXI H,FCC0H ; Load pointer to NADSBox current directory storage
388AH JMP 38A5H ; Jump to print the NADSBox / Desklink directory

; =========================================================================================
; Print the TPDD Bank number to LCD
; =========================================================================================
388DH LXI H,2401H ; Go to Row 1, column 24
3890H SHLD F639H ; Cursor row (1-8)
3893H CALL 4C2FH ; Start inverse character mode
3896H MVI A,23H ; ASCII code for '#'
3898H RST 4 ; Send character in A to the LCD
3899H LDA FCCAH ; Load TPDD Bank number
389CH ADI 30H ; Convert to ASCII digit
389EH RST 4 ; Send it to the LCD
389FH CALL 4C33H ; Cancel inverse character mode
38A2H JMP 38B8H ; Branch to print the function menu, RAM/Disk free, etc.

; =========================================================================================
; Print the NADSBox / Desklink current directory in title bar
; =========================================================================================
38A5H PUSH H ; Save address of the directory string
38A6H LXI H,2101H ; Prepare to position the cursor in the title bar
38A9H SHLD F639H ; Cursor row (1-8)
38ACH CALL 4C2FH ; Start inverse character mode
38AFH POP H ; Retrieve the directory string from the stack
38B0H MVI C,06H ; Prepare to redraw 6 chars with inverse video
38B2H CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
38B5H CALL 4C33H ; Cancel inverse character mode

; =========================================================================================
; Print funtion menu, RAM/Disk free & selected file length
; =========================================================================================
38B8H LXI H,3E97H ; Point to Disk function menu
38BBH LXI B,3936H ; Routine to print free disk space
38BEH LDA FCD9H ; RAM/Disk mode
38C1H ANA A ; Test if in Disk mode and skip ahead to print Disk FKeys
38C2H JNZ 38CBH ; Skip ahead if in disk mode to keep vectors
38C5H LXI H,3ED9H ; Point to RAM function menu
38C8H LXI B,3922H ; Routine to print free RAM space
38CBH PUSH B ; Save routine address to stack
38CCH PUSH H ; Save pointer to function text to stack
38CDH LDA FCCDH ; Currently selected file index
38D0H LXI H,FCD6H ; Count of files on screen
38D3H CMP M ; Compare selected file with count of files on screen
38D4H JC 38DDH ; Branch if within bounds
38D7H MOV A,M ; Get the file count
38D8H ANA A ; Test if #files = 0
38D9H JNZ 38DDH ; Skip ahead if not zero
38DCH INR A ; Don't allow a count of zero - must be 1
38DDH STA FCD5H ; Currently selected file index - temp
38E0H LXI H,0B07H ; Row & column of start of text
38E3H SHLD F639H ; Cursor row (1-8)
38E6H POP H ; Get address of text from the stack and display it
38E7H CALL 4A2CH ; Send buffer at M to screen
38EAH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
38EDH ANA A ; Test if in RAM mode
38EEH JZ 3905H ; Jump if in RAM mode (0 = RAM)
38F1H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
38F4H ANA A ; Test if server is TPDD
38F5H JZ 3905H ; Skip printing of "Bank" or "Mkdr" if TPDD
38F8H LXI H,3FE9H ; Point to text for "Bank"
38FBH DCR A ; Test if server is TPDD2
38FCH JZ 3902H ; Jump to print "Bank" if TPDD2
38FFH LXI H,3FD8H ; Point to text for "Mkdr"
3902H CALL 4A2CH ; Send buffer at M to screen
3905H CALL 3940H ; Display DISK ON/OFF status on LCD
3908H LXI H,1507H ; Point to location for "Free" space (RAM or DISK)
390BH SHLD F639H ; Cursor row (1-8)
390EH RET

; =========================================================================================
; Handle unformatted disks. Print message and show empty slots.
; =========================================================================================
390FH XRA A ; Starting with slot zero...
3910H CALL 39AAH ; Print "-.-" for all empty file slots
3913H LXI H,3E97H ; Point to Disk Function menu string
3916H LXI B,391CH ; Print NOT FORMATTED to the display
3919H JMP 38CBH ; Go process the print and jump to error handler

; =========================================================================================
; Print "NOT FORMATTED" on the LCD and return
; =========================================================================================
391CH LXI H,`H ; Point to "NOT FORMATTED" string
391FH JMP 4A2CH ; Send buffer at M to screen

; =========================================================================================
; Print RAM free space at current posiiton
; =========================================================================================
3922H LHLD FBB2H ; Start of variable data pointer
3925H XCHG ; HL <--> DE
3926H LHLD F678H ; BASIC string buffer pointer
3929H MOV A,L ; Prepare for 16 bit subtract
392AH SUB E ; Subtract LSB
392BH MOV L,A ; Save LSB of difference for printing
392CH MOV A,H ; Prepare for subtrating MSB
392DH SBB D ; Subtract MSB
392EH MOV H,A ; Save in H for printing
392FH LXI B,FFF2H ; Load signed number -14
3932H DAD B ; Subtract 14 from free memory
3933H JMP 4C3EH ; Print binary number in HL at current position

; =========================================================================================
; Display free space on disk
; =========================================================================================
3936H CALL 4A10H ; Calculate free space on disk
3939H CALL 4C3EH ; Print binary number in HL at current position
393CH MVI A,30H ; Prepare to add an extra '0' since calc is /10
393EH RST 4 ; Send A to the LCD
393FH RET

; =========================================================================================
; Display DISK ON/OFF status on LCD
; =========================================================================================
3940H LDA FCD9H ; DISK/RAM mode (0=RAM, 1=DISK)
3943H ANA A ; Test if in RAM mode
3944H RNZ ; Return if not in RAM mode
3945H LDA FB2CH ; DISK-OFF/ON status
3948H LXI D,3FF2H ; Load pointer to "OFF" text
394BH CPI DBH ; Test if DISK mode (vector LSB) indicates ON or OFF
394DH JZ 3953H ; Branch if in DISK-OFF mode
3950H LXI D,3FF6H ; Load pointer to "ON" text
3953H LXI H,1908H ; Location of DISK-OFF/ON indication on LCD
3956H SHLD F639H ; Cursor row (1-8)
3959H XCHG ; HL = pointer to text in DE
395AH JMP 4A2CH ; Send buffer at M to screen

; =========================================================================================
; Display RAM files to LCD and calculate file lengths
; =========================================================================================
395DH LXI H,F9BAH ; Load pointer to 1st available file slot in catalog
3960H XRA A ; Set count of RAM files on screen to zero
3961H STA FCD6H ; Count of files on screen
3964H MVI A,14H ; Get max # files that will fit on LCD
3966H DCR A ; Decrement the max file count
3967H PUSH PSW ; Save count to the stack
3968H MOV A,M ; Get file type
3969H XRI 80H ; Compliment ?active bit
396BH ANI 9FH ; Test if file is active and should be displayed
396DH JNZ 3996H ; Branch to test next file if not displayed
3970H PUSH H ; Save address of current catalog file
3971H INX H ; Point to file address
3972H MOV E,M ; Get LSB of file address
3973H INX H ; Point to MSB of address
3974H MOV D,M ; Get MSB of file address
3975H XTHL ; HL <--> (SP) Get address of file within catalog
3976H PUSH H ; Push pointer to MSB of address on stack
3977H CALL 3CD3H ; Calculate length of RAM file
397AH XCHG ; HL <--> DE DE has the length
397BH CALL 4791H ; Store next file length to keyboard buffer
397EH POP H ; Get catalog address of current file from stack
397FH XTHL ; HL <--> (SP) swap catalog address with pointer to MSB of file address
3980H INX H ; Increment to filename
3981H MVI C,06H ; Prepare to print 6 characters of filename
3983H CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
3986H MVI A,2EH ; Load code for '.'
3988H RST 4 ; Send A to the LCD
3989H MVI C,02H ; Prepare to print 2 ext bytes to LCD
398BH CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
398EH MVI A,20H ; Load code for space
3990H RST 4 ; Send A to the LCD
3991H LXI H,FCD6H ; Count of files on screen
3994H INR M ; Increment number of files displayed on LCD
3995H POP H ; Get catalog address of file from stack
3996H LXI D,000BH ; Load offset to next file locaion in catalog
3999H DAD D ; Offset HL to next file
399AH POP PSW ; Restore the file count from the stack
399BH DCR A ; Decrement the max file count on the LCD
399CH JNZ 3967H ; Branch to test and display next file until zero
399FH LDA FCD6H ; Get the count of files actually displayed on screen
39A2H CPI 14H ; Test if max number of files displayed
39A4H CC 39AAH ; Branch to display "-.-" for remaining empty slots if not max
39A7H JMP 387CH ; Print NADSBox directory or TPDD Bank number to LCD

; =========================================================================================
; Print "-.-" for all empty file slots
; =========================================================================================
39AAH PUSH PSW ; Save current file index count on stack
39ABH LXI H,3FCDH ; Point to "-.-" text
39AEH CALL 4A2CH ; Send buffer at M to screen
39B1H POP PSW ; Restore current count
39B2H INR A ; Increment file index number
39B3H CPI 14H ; Compare A with max files that fit on LCD
39B5H JNZ 39AAH ; Jump to print next "-.-" if not done
39B8H RET

; =========================================================================================
; Handle "D" key from TS-DOS key scan
; =========================================================================================
39B9H CALL 3AA8H ; Test if printer busy. Return if not busy or error
39BCH CALL 4C52H ; LCOPY statement
39BFH JMP 362FH ; Print length of selected file using inverse video.

; =========================================================================================
; Handle "L", "P" and "O" keys from TS-DOS key scan - list or print .DO file contents
; =========================================================================================
39C2H STA FCDFH ; Save key pressed
39C5H LXI D,0007H ; Load offset of Extension bytes
39C8H LHLD FCE4H ; LCD Buffer address of current file selection
39CBH DAD D ; Point to extension bytes in LCD buffer
39CCH MOV A,M ; Get 1st extension byte
39CDH CPI 44H ; Compare byte with "D"
39CFH JNZ 362FH ; Print length of selected file using inverse video if not "D"
39D2H INX H ; Point to 2nd extension byte
39D3H MOV A,M ; Load 2nd extension byte for comparison
39D4H CPI 4FH ; Compare with "0"
39D6H JNZ 3A06H ; Jump to print compressed file
39D9H CALL 3A49H ; Prepare file for reading (open disk file, address of RAM file)
39DCH LDA FCDFH ; Restore key pressed
39DFH CPI 4CH ; Test if key was "L" - List to LCD
39E1H CZ 4C27H ; CLS statement if LCD
39E4H CNZ 3AA8H ; Test if printer busy. Return if not busy or error
39E7H CALL 3A24H ; Get next block of data to display/print (HL=address)
39EAH PUSH PSW ; Push Z flag indicating if a full 128 bytes was read
39EBH CALL 3A6BH ; Display / print file data bytes at HL, A has length
39EEH POP PSW ; Get Z flag indicating if 128 bytes read
39EFH JZ 39E7H ; Jump to process more if 128 bytes were read last time
39F2H LDA FCDFH ; Restore key pressed
39F5H CPI 4CH ; Test if key was "L"
39F7H JNZ 3A00H ; Skip beep if printing
39FAH MVI A,07H ; Load code for BELL
39FCH RST 4 ; Go print a BELL (beep)
39FDH CALL 3DF8H ; Process power-off logic and wait for a key from keyboard

; =========================================================================================
; Clear screen and perform Long Jump
; =========================================================================================
3A00H CALL 4C27H ; CLS statement
3A03H JMP 48B5H ; Branch to "Long Jump" operation

; =========================================================================================
; Handler for the "O" key - print a compressed file??
; =========================================================================================
3A06H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A09H ANA A ; Test if in Disk mode
3A0AH JNZ 362FH ; Jump to keyscan if in Disk mode
3A0DH LHLD FCE4H ; LCD Buffer address of current file selection
3A10H CALL 4902H ; Copy filename at (HL) to current BASIC program
3A13H CALL 4A51H ; Get RAM directory address of current BASIC program
3A16H CPI C0H ; Test if filetype is .DO
3A18H CZ 5004H ; Call routine to Compress / Decompress .DO files
3A1BH CALL 4C0FH ; Update system pointers
3A1EH CALL 3611H ; Print Copyright and files
3A21H JMP 362FH ; Jump to keyscan

; =========================================================================================
; Get next 128 bytes (or less) of data from RAM or disk file for display
; =========================================================================================
3A24H LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A27H ANA A ; Test if RAM mode
3A28H JNZ 40B6H ; If not RAM mode, go send TPDD_READ data opcode and recieve response
3A2BH LHLD FCDDH ; Get length of file to be displayed / printed
3A2EH LXI B,0080H ; Prepare to subtract 128 from length
3A31H MOV A,C ; Save 128 to A
3A32H DSUB ; Subtract 128 from file length
3A33H JNC 3A3AH ; Branch if length >= 128
3A36H DAD B ; Add 128 back to length to print "partial" buffer
3A37H MOV A,L ; Move remainder of bytes to display/print
3A38H MOV L,H ; Clear LSB of remainder
3A39H MOV C,A ; Move LSB of remainder to C
3A3AH SHLD FCDDH ; Save new remaining file length
3A3DH LHLD FCE0H ; Load the address to be printed / saved
3A40H PUSH H ; Save on stack
3A41H DAD B ; Update address to be used for display/printing next time
3A42H SHLD FCE0H ; Save address to be displayed / printed
3A45H POP H ; Retrieve address to be printed this loop from stack
3A46H CPI 80H ; Compare length with maximum
3A48H RET

; =========================================================================================
; Initialize Selected file for display (RAM or Disk)
; =========================================================================================
3A49H CALL 4A3BH ; Initialize blank filename and attribute byte
3A4CH LHLD FCE4H ; LCD Buffer address of current file selection
3A4FH LDA FCD9H ; RAM / Disk mode (0=RAM, 1=DISK)
3A52H ANA A ; Test if in RAM mode
3A53H JNZ 3A65H ; Branch to process Disk files if in Disk mode
3A56H CALL 4A4BH ; Get RAM directory address of selected file
3A59H PUSH D ; Push file address to stack
3A5AH CALL 3CD3H ; Calculate length of RAM file, HL=address of catalog entry, DE=file address
3A5DH SHLD FCDDH ; Save length to FDC emulation sector storage area
3A60H POP H ; Pop address of file into H
3A61H SHLD FCE0H ; Save file address
3A64H RET

; =====================================================================================
; Send TPDD Open command to open selected file
; =====================================================================================
3A65H CALL 3D95H ; Copy filename at (HL) to TX buffer
3A68H JMP 408AH ; Open TPDD file for Read Mode

; =====================================================================================
; Display / print file data bytes at HL, A has length
; =====================================================================================
3A6BH XCHG ; HL <--> DE
3A6CH ORA A ; Test if length = 0
3A6DH RZ ; Return if length = 0
3A6EH MOV C,A ; Save length count in C
3A6FH LDA FCDFH ; Load key press value
3A72H CPI 4CH ; Test if key was "L"
3A74H JNZ 3A82H ; Jump to print contents if not "L"
3A77H CALL 3A8FH ; Check for CTRL-C
3A7AH LDAX D ; Load next byte from src pointer
3A7BH RST 4 ; Send A to LCD
3A7CH INX D ; Increment the pointer
3A7DH DCR C ; Decrement the length count
3A7EH JNZ 3A77H ; Keep looping until all data displayed
3A81H RET

; =====================================================================================
; Print file data bytes at HL, A has length
; =====================================================================================
3A82H CALL 3A8FH ; Test for CTRL-C, etc.
3A85H LDAX D ; Load next file byte from source poiner
3A86H CALL 4C42H ; Print A to printer, expanding tabs if necessary
3A89H INX D ; Increment pointer
3A8AH DCR C ; Decrement length count
3A8BH JNZ 3A82H ; Keep looping until all data printed
3A8EH RET

; =========================================================================================
; Test for ESC, CTRL-C or Space
; =========================================================================================
3A8FH CALL 4C4AH ; Check keyboard queue for pending characters
3A92H RZ ; Return if no pending characters
3A93H CALL 4BEBH ; Wait for key from keyboard
3A96H CPI 03H ; Test for F4 maybe?
3A98H JZ 3A00H ; Clear screen and perform Long Jump if F4 maybe?
3A9BH CPI 1BH ; Test for ESC key
3A9DH JZ 3A00H ; Clear screen and perform Long Jump if ESC
3AA0H CPI 20H ; Test for space key
3AA2H JNZ 3A8FH ; Branch back to wait for ESC, CTRL-C or space if not space
3AA5H JMP 4BEBH ; Wait for key from keyboard

; =========================================================================================
; Test if printer busy. Return if not busy, print error if it is
; =========================================================================================
3AA8H IN BBH ; Get printer port input
3AAAH ANI 06H ; Mask all but BUSY and /BUSY
3AACH XRI 02H ; Compliment /BUSY
3AAEH JNZ 487BH ; Printer not ready / FF error
3AB1H RET

; =========================================================================================
; Print currently selected file using inverse video
; =========================================================================================
3AB2H CALL 3ACDH ; Calculate Row and Column of newly selected file
3AB5H SHLD FCE4H ; LCD Buffer address of current file selection
3AB8H CALL 4C2FH ; Start inverse character mode
3ABBH DCX H ; Start drawing from left edge of selection (include space)
3ABCH MVI C,0AH ; Draw 10 characters
3ABEH CALL 48E5H ; Redraw C characters from buffer at HL using current video mode
3AC1H JMP 4C33H ; Cancel inverse character mode

; =========================================================================================
; Print selected file using normal video to "unselect" it
; =========================================================================================
3AC4H CALL 4C33H ; Cancel inverse character mode
3AC7H CALL 3ACDH ; Calculate row and column of newly selected file
3ACAH JMP 3ABBH ; Print the file to the LCD

; =========================================================================================
; Calculate Row and Column of soon-to-be (newly) selected file
; =========================================================================================
3ACDH LDA FCD5H ; Currently selected file index
3AD0H DCR A ; Make selected file zero based
3AD1H MOV L,A ; Save index to 16-bit HL
3AD2H MVI H,00H ; Make MSB zero
3AD4H LXI D,000AH ; Prepare to multiply index * 10 cols
3AD7H CALL 4C1FH ; Signed integer muliply (FAC1=HL*DE)
3ADAH LXI D,FE28H ; Load address of line 2 in the LCD buffer
3ADDH DAD D ; Calculate starting LCD buffer address for this file
3ADEH INX H ; Skip the "tag" space on the LCD
3ADFH PUSH H ; Save address on the stack
3AE0H LXI B,FE00H ; Load starting address of LCD character buffer
3AE3H DSUB ; Calculate file start offset from start of LCD buffer
3AE4H LXI D,0028H ; Load 1 LCD line width
3AE7H XCHG ; HL <--> DE Prepare for divide
3AE8H CALL 4C1BH ; Signed integer divide (FAC1=DE/HL)
3AEBH MOV A,L ; Save selected file's row number to A
3AECH INR A ; Make row 1-based
3AEDH STA F639H ; Cursor row (1-8)
3AF0H XCHG ; HL <--> DE DE had remainder*2 from divide
3AF1H ASHR ; Divide HL by 2
3AF2H MOV A,L ; Prepare to save remainder as the column
3AF3H STA F63AH ; Cursor column (1-40)
3AF6H POP H ; Restore address of LCD buffer location from stack
3AF7H RET

; =========================================================================================
; F3 Function key handler for RAM mode - Rename
; =========================================================================================
3AF8H CALL 4A4BH ; Get RAM directory address of selected file
3AFBH SHLD FCE0H ; Save address of file being processed
3AFEH LXI H,3F4AH ; Address of "New name" string
3B01H CALL 3E1AH ; Get 6-byte input filename from keyboard
3B04H RZ ; Return if no input provided
3B05H CALL 4902H ; Copy filename at (HL) to current BASIC program
3B08H LHLD FCE0H ; Load RAM directory address of file being renamed
3B0BH LXI B,0009H ; Load offset of extension within catalog entry
3B0EH DAD B ; Point to extension bytes
3B0FH LXI D,FC99H ; Load address of extension field of current BASIC program name
3B12H MOV A,M ; Get 1st byte of extension of catalog file being renamed
3B13H STAX D ; Save extension byte in current BASIC program filename - preserve EXT
3B14H INX D ; Point to 2nd ext byte of BASIC program name
3B15H INX H ; Point to 2nd ext byte of catalog filename
3B16H MOV A,M ; Get 2nd extension byte from catalog filename
3B17H STAX D ; Save byte in current BASIC program filename area
3B18H CALL 4A51H ; Get RAM directory address of current BASIC program
3B1BH JNZ 487EH ; If found, jump to File Exists Error
3B1EH LHLD FCE0H ; Load catalog address of file being renamed
3B21H INX H ; Point to LSB of file address
3B22H INX H ; Point to MSB of file address
3B23H INX H ; Point to name
3B24H LXI D,FC93H ; Load address of filename of current BASIC program
3B27H LXI B,0006H ; Prepare to copy 6 bytes of filename (ext doesn't change)
3B2AH XCHG ; HL <--> DE
3B2BH JMP 4A05H ; Move BC bytes from M to (DE) with increment

; =========================================================================================
; F1 Function key handler for DISK mode - Load
; =========================================================================================
3B2EH CALL 4A3BH ; Initialize blank filename and attribute byte
3B31H LHLD FCE4H ; LCD Buffer address of current file selection
3B34H CALL 3D95H ; Copy filename at (HL) to TX buffer
3B37H LDA FCCCH ; Last Tag/Untag operation code
3B3AH ANA A ; Test if a tag operation is pending
3B3BH JNZ 3B56H ; Branch if doing tag load operation
3B3EH LXI H,3F7AH ; Point to "Load as:" text
3B41H CALL 3E1AH ; Get 6-byte filename input from keyboard
3B44H JZ 3B56H ; Jump to use existing disk name as filename
3B47H CALL 4902H ; Copy filename at (HL) to current BASIC program
3B4AH LXI B,0002H ; Prepare to copy 2 extension bytes to current BASIC program space
3B4DH LXI H,FCEFH ; Point to disk file extension in TX buffer
3B50H LXI D,FC99H ; Point to current BASIC program extension address
3B53H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3B56H CALL 4A51H ; Get RAM directory address of current BASIC program
3B59H JZ 3B69H ; Branch to load if file doesn't already exist
3B5CH LXI H,3FB0H ; Point to "File Exists, Replace?" text
3B5FH CALL 48F4H ; Print string at HL to col 1 on the bottom line
3B62H CALL 3DEEH ; Get key from keyboard and test for 'Y' or 'y'
3B65H RNZ ; Return if isn't 'y' or 'Y'
3B66H CALL 3C38H ; Kill file in current BASIC program space
3B69H LHLD FD1DH ; Get file size from RX buffer
3B6CH MOV A,H ; Swap bytes (big endian in RX buffer)
3B6DH MOV H,L ; Move LSB to MSB
3B6EH MOV L,A ; Move MSB to LSB
3B6FH SHLD FD1DH ; Save with little endian to RX buffer
3B72H LDA FCEFH ; Get 1st byte of extension from TX buffer
3B75H CPI 44H ; Test if 1st extension byte is "D"
3B77H JNZ 3B82H ; Jump if not "D" to check for "C" or "B"
3B7AH LHLD FBAEH ; Get start of DO files pointer for location of new file
3B7DH MVI A,C0H ; Load file type code for .DO files
3B7FH JMP 3BA3H ; Process the file load

; =========================================================================================
; Test file exension type in A for .CO files
; =========================================================================================
3B82H CPI 43H ; Test if A contains "C"
3B84H JNZ 3B95H ; Branch if not .CO file
3B87H LHLD FBB0H ; Start of CO files pointer
3B8AH SHLD FCD5H ; Save in currently selected file index storage area
3B8DH LHLD FBB2H ; Get Start of variable data pointer as location for new file
3B90H MVI A,A0H ; Load file type code for .CO files
3B92H JMP 3BA3H ; Process the file load

; =========================================================================================
; Process load of .BA file
; =========================================================================================
3B95H LHLD FD1DH ; Get file size from RX buffer
3B98H SHLD FCD5H ; Save in Currently selected file index storage
3B9BH LHLD F99AH ; Get BASIC program not saved pointer
3B9EH SHLD FCE0H ; Save as address of file being processed
3BA1H MVI A,80H ; Load file type code for .BA files

; =========================================================================================
; Process file load operation
; =========================================================================================
3BA3H STA FCDFH ; Save file type code for later
3BA6H SHLD FCE2H ; Save address for new file
3BA9H LHLD FD1DH ; Get file size from RX buffer
3BACH SHLD FCDDH ; Save in FDC emulation physical/logical sector storage area
3BAFH PUSH H ; Save file size on stack
3BB0H POP B ; Copy file size to BC
3BB1H LDA FCDFH ; Get file type code
3BB4H CPI A0H ; Test for .CO file
3BB6H JZ 3BC0H ; Skip increment if .CO file (.BA has trailing 0x0000, .DO a 0x1A)
3BB9H INX B ; Increment file length for .BA and .DO files
3BBAH CPI 80H ; Test if file is .BA
3BBCH JNZ 3BC0H ; Skip additional increment if .BA
3BBFH INX B ; Add 1 more to length for .BA files to account for both trailing 0's
3BC0H PUSH B ; Save updated length on stack
3BC1H CALL 3E48H ; Find empty catalog entry
3BC4H JC 4887H ; Generate system error 0x0A ("DD") if full
3BC7H POP B ; Get length from stack
3BC8H PUSH H ; Save new file catalog address on stack
3BC9H PUSH B ; Save new file length on stack
3BCAH LHLD FCE2H ; Get address for new contents of new file
3BCDH CALL 4C0BH ; Insert BC spaces at M - make room
3BD0H JC 488AH ; Branch if error - RAM full error
3BD3H LHLD FCE2H ; Restore address of new file contents
3BD6H POP B ; Get file length from stack
3BD7H MVI M,00H ; Fill newly created file space with zero's
3BD9H INX H ; Increment pointer
3BDAH DCX B ; Decrement count
3BDBH MOV A,C ; Move LSB to A to check for zero - could use JNX here!
3BDCH ORA B ; Or in MSB to check for zero
3BDDH JNZ 3BD7H ; Keep looping until all are zero
3BE0H DCX H ; Decrement pointer to last byte in new file
3BE1H POP D ; Get File catalog address from stack
3BE2H LDA FCDFH ; Load file type code byte
3BE5H CPI C0H ; Test for .DO file
3BE7H JNZ 3BF3H ; Branch if not .DO file
3BEAH MVI M,1AH ; Terminate .DO file with EOF marker
3BECH LHLD FCE2H ; Reload address of new file contents
3BEFH DCX H ; Decrement pointer to jump into middle of loop
3BF0H JMP 3C1BH ; Write file entry to catalog

; =========================================================================================
; Process end-of-file / file length for .CO and .BA files
; =========================================================================================
3BF3H CPI A0H ; Test if new file is .CO
3BF5H JNZ 3C04H ; Branch if not .CO - must be .BA
3BF8H LHLD FCD5H ; Get old start of CO files pointer
3BFBH SHLD FBB0H ; Save as current start of CO files pointer
3BFEH LHLD FCE2H ; Reload address of new file contents
3C01H JMP 3C1BH ; Write file entry to catalog

; =========================================================================================
; Process end-of-file for .BA files
; =========================================================================================
3C04H PUSH D ; Push file catalog address to stack
3C05H LHLD FBAEH ; Get start of DO files pointer
3C08H DCX H ; Decrement address by 1
3C09H SHLD F99AH ; Save as new BASIC program not saved pointer
3C0CH INX H ; Increment back to start of .DO files
3C0DH XCHG ; HL <--> DE DE has start of DO files
3C0EH LHLD FCD5H ; Get BA file size
3C11H INX H ; Increment file size to account for trailing 0's
3C12H INX H ; Increment file size to account for trailing 0's
3C13H DAD D ; Add new length to start of DO files pointer
3C14H SHLD FBAEH ; Save new start of DO files pointer
3C17H POP D ; Retrieve file catalog address from stack
3C18H LHLD FCE0H ; Reload address of new file contents

; =========================================================================================
; Write file entry to catalog
; =========================================================================================
3C1BH XCHG ; HL <--> DE DE has file address, HL has catalog address
3C1CH CALL 4C17H ; Write new entry to catalog (A=type, DE=file address,HL=catalog address)
3C1FH CALL 4127H ; Open TPDD file and read data to file address being processed
3C22H CALL 4C0FH ; Update system pointers
3C25H LXI H,0002H ; Load TPDD_READ opcode in HL
3C28H JMP 409BH ; Send Request in HL and await response

; =========================================================================================
; F2 Function key handler for RAM mode - Kill
; =========================================================================================
3C2BH LDA FCCCH ; Get last Tag/Untag operation code
3C2EH ANA A ; Test if there is a pending tag operation
3C2FH CZ 3DE1H ; Display "Sure ?", validate and return if validated if no tag
3C32H LHLD FCE4H ; LCD Buffer address of current file selection
3C35H CALL 4902H ; Copy filename at (HL) to current BASIC program

; =========================================================================================
; Kill file in current BASIC program space
; =========================================================================================
3C38H CALL 4A51H ; Get RAM directory address of current BASIC program
3C3BH CPI C0H ; Test if file is .DO
3C3DH JZ 4BFFH ; Kill .DO file
3C40H CPI A0H ; Test if file is .CO
3C42H JZ 4C07H ; Kill .CO file
3C45H CPI 80H ; Test if file is .BA
3C47H JZ 4C03H ; Kill .BA file
3C4AH RET

; =========================================================================================
; F1 Function key handler for RAM mode - Save
; =========================================================================================
3C4BH CALL 4A3BH ; Initialize blank filename and attribute byte
3C4EH CALL 4A4BH ; Get RAM directory address of selected file
3C51H PUSH D ; Push file address to stack
3C52H PUSH H ; Push file catalog address to stack
3C53H INX H ; Point to LSB of file address
3C54H INX H ; Point to MSB of file address
3C55H INX H ; Point to filename in catalog
3C56H LXI D,FCE8H ; Point to TX buffer data area (payload)
3C59H LXI B,0006H ; Prepare to copy 6 filename bytes to TX packet data
3C5CH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C5FH MVI A,2EH ; Load code for '.'
3C61H STAX D ; Store '.' separator in TX packet data
3C62H INX D ; Increment TX packet data pointer
3C63H LXI B,0002H ; Prepare to copy 2 extention bytes from catalog
3C66H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C69H LDA FCCCH ; Last Tag/Untag operation code
3C6CH ANA A ; Test if a tag save operation is being performed
3C6DH JNZ 3C88H ; Jump ahead if doing a tag save - skip filename questioning
3C70H LXI H,3F71H ; Point to "Save as:" text
3C73H CALL 3E1AH ; Get 6-byte input filename from keyboard
3C76H JZ 3C88H ; Skip ahead to use catalog name if no input given
3C79H CALL 4902H ; Copy filename at (HL) to current BASIC program
3C7CH LXI B,0006H ; Prepare to copy 6 filename bytes from input string
3C7FH LXI D,FCE8H ; Point to filename area in TX buffer
3C82H LXI H,FC93H ; Filename of current BASIC program
3C85H CALL 4A05H ; Move BC bytes from M to (DE) with increment
3C88H POP H ; Restore file catalog address from stack
3C89H POP D ; Restore file address from stack
3C8AH PUSH D ; Save file address on stack
3C8BH CALL 3CD3H ; Calculate length of RAM file, HL=address of catalog entry, DE=file address
3C8EH MOV A,H ; Test for zero length file - move H to A
3C8FH ORA L ; OR LSB to test for zero
3C90H JZ 4884H ; Branch if empty - File Empty Error
3C93H PUSH H ; Save file address to stack
3C94H MVI A,01H ; Set file open mode to new file
3C96H STA FCD6H ; Save open mode to pass to open routine
3C99H CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3C9CH CALL 4A72H ; Send Dir Reference opcode
3C9FH JZ 3CCEH ; Jump to write data if file doesn't exist (size = 0)
3CA2H LXI H,3F8BH ; Point to "File Exists, A)ppend R)eplace Q)uit" text
3CA5H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3CA8H CALL 3DF8H ; Process power-off logic and wait for a key from keyboard
3CABH ANI DFH ; Make key uppercase
3CADH RST 4 ; Display key on LCD
3CAEH CPI 52H ; Test if key is 'R'
3CB0H JNZ 3CBCH ; Jump if not 'R'eplace
3CB3H CALL 431AH ; Issue TPDD Delete file Opcode
3CB6H CALL 4A72H ; Send Dir Reference opcode
3CB9H JMP 3CCEH ; Go write data to the file

; =========================================================================================
; F1-Save: Test for 'A'ppend
; =========================================================================================
3CBCH POP H ; Get file length from stack
3CBDH POP D ; Get file address from stack
3CBEH CPI 41H ; Test if response is 'A'ppend
3CC0H RNZ ; Return if not 'A'
3CC1H LDA FCEFH ; Load 1st byte of extension from TX buffer
3CC4H CPI 44H ; Test if file is "D"O file
3CC6H RNZ ; Don't allow appending non DO files
3CC7H MVI A,02H ; Set open mode to open existing (append)
3CC9H STA FCD6H ; Save mode to pass to open routine
3CCCH PUSH D ; Save file address on stack
3CCDH PUSH H ; Save file length on stack

; =========================================================================================
; Save function - Replace or new file, write data to file
; =========================================================================================
3CCEH POP H ; Retrieve file length from stack
3CCFH POP D ; Retrieve file address from stack
3CD0H JMP 40C8H ; Write HL bytes of data from (DE) to TPDD

; =========================================================================================
; Calculate length of RAM file, HL=address of catalog entry, DE=file address
; =========================================================================================
3CD3H MOV A,M ; Get RAM file type from catalog
3CD4H CPI C0H ; Test for .DO file
3CD6H JZ 3CE6H ; Jump to calculate length if .DO file
3CD9H CPI A0H ; Test for .CO file
3CDBH JZ 3CF5H ; Jump to calculate length if .CO file
3CDEH PUSH D ; Save address of start of BASIC program to stack
3CDFH CALL 4C13H ; Call ROM routine to find BASIC end of program
3CE2H POP B ; Get BASIC program start address from stack
3CE3H DSUB ; Subtract starting address from end address
3CE4H DCX H ; Don't count trailing 0x00 as part of BASIC program length
3CE5H RET

; =========================================================================================
; Calculate length of .DO file, HL=Catalog address, DE=file address
; =========================================================================================
3CE6H XCHG ; HL <--> DE Get file address in HL
3CE7H LXI D,0000H ; Clear file length
3CEAH MOV A,M ; Get next byte from .DO file
3CEBH INX H ; Increment pointer
3CECH INX D ; Increment length
3CEDH CPI 1AH ; Test for EOF marker
3CEFH JNZ 3CEAH ; Branch to next byte if not EOF
3CF2H DCX D ; Subtract EOF marker from file length
3CF3H XCHG ; HL <--> DE HL=length
3CF4H RET

; =========================================================================================
; Calculate length of .CO file, HL=Catalog address, DE=file address
; =========================================================================================
3CF5H XCHG ; HL <--> DE Get file address in HL
3CF6H INX H ; Increment past .CO load address
3CF7H INX H ; Increment past MSB of load address
3CF8H MOV C,M ; Get LSB of length
3CF9H INX H ; Increment to MSB of length
3CFAH MOV B,M ; Get MSB of length
3CFBH LXI H,0006H ; Prepare to add 6-byte header to length
3CFEH DAD B ; Add 6-byte header to length
3CFFH RET

; =========================================================================================
; F7 Function key handler for DISK mode - Mkdir
; =========================================================================================
3D00H LDA FCCBH ; NADSBox / TPDD2 / Desklink flag
3D03H ANA A ; Test if server is TPDD
3D04H RZ ; Return if not NADSBox or TPDD2
3D05H DCR A ; Test if TPDD2
3D06H JZ 37BAH ; Go Swap TPDD Bank Number if TPDD2
3D09H CALL 4A3BH ; Must be NADSBOx Initialize blank filename
3D0CH LXI H,3F61H ; Load pointer to "Directory name:" text
3D0FH CALL 3E1AH ; Get 6-byte input filename from keyboard
3D12H RZ ; Return if no input given
3D13H CALL 4902H ; Copy filename at (HL) to current BASIC program
3D16H LXI H,FC93H ; Filename of current BASIC program
3D19H LXI D,FCE8H ; Point to TX buffer data area (payload)
3D1CH LXI B,0006H ; Prepare to copy 6 filename bytes to TX buffer
3D1FH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3D22H LXI H,3E3CH ; Load code for "<>"
3D25H SHLD FCEFH ; Save "<>" extension bytes in TX buffer - NADSBox Mkdir
3D28H MVI A,2EH ; Load code for '.' extension separator
3D2AH STA FCEEH ; Save "." to TX buffer
3D2DH CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D30H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
3D33H CPI 02H ; Test if we have NADSBox current directory
3D35H RNZ ; Return if we don't have current directory
3D36H CALL 4A72H ; Send Directory Reference opcode
3D39H JNZ 3D4DH ; If the file exists, branch to open it for READ mode
3D3CH MVI A,01H ; Load OPEN_WRITE mode into A to create the directory
3D3EH STA FCE8H ; Save A in TX data storage mode field
3D41H LXI H,0101H ; Load opcode to open a file
3D44H CALL 409BH ; Send Request in HL and await response
3D47H LXI H,0002H ; Load opcode to close the file
3D4AH JMP 409BH ; Send Request in HL and await response

; =========================================================================================
; Open and close a directory file (from above)
; =========================================================================================
3D4DH CALL 408AH ; Open TPDD file for Read Mode
3D50H JMP 3D47H ; Branch to close the directory open request

; =========================================================================================
; F5 Function key handler for DISK mode - Format
; =========================================================================================
3D53H LDA FCCBH ; NADSBox / Desklink / TPDD2 flag
3D56H CPI 02H ; Test if we have "current directory" name
3D58H RZ ; Return if server is NADSBox / Desklink - No format supported
3D59H LXI H,3F1BH ; Load pointer to "Insert Disk" string
3D5CH CALL 48F4H ; Print string at HL to col 1 on the bottom line
3D5FH CALL 3DEEH ; Get key from keyboard and test for 'Y' or 'y'
3D62H RNZ ; Return if response not 'Y'
3D63H CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D66H CALL 49E3H ; Delay routine - about 3ms
3D69H LXI H,0006H ; Load TPDD_FORMAT opcode in HL
3D6CH CALL 409BH ; Send Request in HL and await response
3D6FH MVI A,07H ; Load code for BELL
3D72H RET ; Go beep to indicate format

; =========================================================================================
; F2 Function key handler for DISK mode - Kill
; =========================================================================================
3D73H LDA FCCCH ; Last Tag/Untag operation code
3D76H ANA A ; Test if there's an active tag group
3D77H CZ 3DE1H ; Display "Sure ?", validate and return if validated if no tag
3D7AH CALL 4A3BH ; Initialize blank filename and attribute byte
3D7DH CALL 3D83H ; Copy selected filename to TX buffer and init TPDD/NADSBox
3D80H JMP 431AH ; Issue TPDD Delete file Opcode

; =========================================================================================
; Copy selected filename to TX buffer and init TPDD/NADSBox
; =========================================================================================
3D83H LXI B,0009H ; Prepare to copy 9 filename bytes
3D86H LHLD FCE4H ; LCD Buffer address of current file selection
3D89H LXI D,FCE8H ; Address of TX packet data
3D8CH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3D8FH CALL 4943H ; Configure baud, test for NADSBox, get NADSBox dir
3D92H JMP 4A72H ; Send Dir Reference opcode

; =========================================================================================
; Copy filename at (HL) to TX buffer
; =========================================================================================
3D95H CALL 4902H ; Copy filename at (HL) to current BASIC program
3D98H LXI H,FC93H ; Filename of current BASIC program
3D9BH CALL 4A57H ; Send Dir Reference for filename at (HL)
3D9EH RET

; =========================================================================================
; F3 Function key handler for DISK mode - Name
; =========================================================================================
3D9FH CALL 4A3BH ; Initialize blank filename and attribute byte
3DA2H CALL 3D83H ; Copy selected filename to TX buffer and init TPDD/NADSBox
3DA5H LXI H,FCE8H ; Point to TX buffer data area (payload)
3DA8H LXI D,FC9CH ; Filename of last program loaded from tape
3DABH LXI B,0009H ; Prepare to copy 9 bytes to "last program loaded" filename
3DAEH CALL 4A05H ; Move BC bytes from M to (DE) with increment
3DB1H LHLD FD1DH ; Get file size from RX buffer
3DB4H MOV C,H ; Save file size MSB to C (swap endian)
3DB5H MOV B,L ; Save file size LSB to B (swap endian)
3DB6H LXI H,7CC0H ; ? Load HL with 31936
3DB9H DSUB ; ? Compare file length with 31936
3DBAH LXI H,3F4AH ; Address of "New name" string
3DBDH JNZ 3DD7H ; Branch to change filename if not 30656
3DC0H LXI B,0009H ; Allow a 9-byte filename input string
3DC3H CALL 3E1DH ; Get max BC length input for filename and convert to uppercase
3DC6H RZ ; Return if no input provided
3DC7H PUSH H ; Save pointer to input string to stack
3DC8H PUSH PSW ; Save string length to stack
3DC9H CALL 4A3BH ; Initialize blank filename and attribute byte
3DCCH POP PSW ; Get string length from stack
3DCDH POP H ; Get string address from stack
3DCEH LXI D,FCE8H ; Point to TX buffer data area (payload)
3DD1H MOV C,A ; Copy length to BC
3DD2H MVI B,00H ; Make MSB of length = 0
3DD4H JMP 41B0H ; Rename the TPDD file whose name is in (HL)

; =========================================================================================
; Get filename from keyboard and rename Disk file, filename in "current BASIC program"
; =========================================================================================
3DD7H CALL 3E1AH ; Get 6-byte input filename from keyboard
3DDAH RZ ; Return if no input provided
3DDBH CALL 4902H ; Copy filename at (HL) to current BASIC program
3DDEH JMP 41A7H ; Rename the TPDD file whose name is in "current BASIC program"

; =========================================================================================
; Display "Sure ?", validate and return if validated
; =========================================================================================
3DE1H LXI H,3F83H ; Load pointer to "Sure ?" string
3DE4H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3DE7H CALL 3DEEH ; Get key and test for 'Y' or 'y'
3DEAH JNZ 48B5H ; Branch to "Long jump" operation to abort if not 'y'
3DEDH RET

; =========================================================================================
; Get key from keyboard and test for 'Y' or 'y'
; =========================================================================================
3DEEH CALL 3DF8H ; Process power-off logic and wait for a key from keyboard
3DF1H RST 4 ; Display the key on the LCD
3DF2H CPI 59H ; Test if key pressed was 'Y'
3DF4H RZ ; Return if key pressed was 'Y'
3DF5H CPI 79H ; Test if key pressed was 'y'
3DF7H RET

; =========================================================================================
; Process power-off logic and wait for a key from keyboard
; =========================================================================================
3DF8H CALL 3DFEH ; Process automatic poweroff logic
3DFBH JMP 4BEBH ; Wait for key from keyboard

; =========================================================================================
; Process automatic power-off logic during key scan loop
; =========================================================================================
3DFEH XRA A ; Clear A
3DFFH DCR A ; Set A to 0xFF
3E00H STA F656H ; Power off exit condition switch
3E03H CALL 4C4AH ; Check keyboard queue for pending characters
3E06H JZ 3DFEH ; Branch back if no keyboard characters in queue - wait for key
3E09H XRA A ; Clear A
3E0AH STA F656H ; Power off exit condition switch
3E0DH LXI H,F932H ; Load address of "Renew Automatic Poweroff Counter Flag"
3E10H ORA M ; Test if auto poweroff counter should be renewed
3E11H JZ 4BF7H ; Renew automatic power-off counter if enabled
3E14H CALL 4BF3H ; Turn off the computer
3E17H JMP 3DFEH ; Branch back to continue processing power off logic

; =========================================================================================
; Get max 6-byte input for filename and convert to uppercase
; =========================================================================================
3E1AH LXI B,0006H ; Get maximum 6 characters of input

; =========================================================================================
; Get max BC length input for filename and convert to uppercase
; =========================================================================================
3E1DH CALL 3E2FH ; Get max BC length input string from keyboard
3E20H RZ ; Return if no input provided
3E21H PUSH H ; Preserve pointer to input string
3E22H PUSH PSW ; Preserve flags from input
3E23H CALL 4C5EH ; Get char at M and convert to uppercase
3E26H MOV M,A ; Save uppercase char back to string
3E27H INX H ; Point to next byte in input
3E28H ANA A ; Test for NULL - end of string
3E29H JNZ 3E23H ; Keep looping until end of string
3E2CH POP PSW ; Restore flags from input routine
3E2DH POP H ; Restore pointer to input string
3E2EH RET

; =========================================================================================
; Get maximum BC length input character string from keyboard
; =========================================================================================
3E2FH PUSH B ; Save maximum input length to stack
3E30H CALL 48F4H ; Print string at HL to col 1 on the bottom line
3E33H CALL 4C46H ; Input and display (no "?") line and store
3E36H JC 48B5H ; Branch to "Long jump" if CTRL-C
3E39H INX H ; Point to start of input string
3E3AH MOV A,B ; Get string length (counting NULL)
3E3BH DCR A ; Remove NULL from count
3E3CH POP D ; Restore maximum input length
3E3DH RZ ; Return if string length is zero
3E3EH CMP E ; Compare expected length with actual length
3E3FH RC ; Return if string is shorter than expected
3E40H PUSH H ; Save pointer to start of string on stack
3E41H DAD D ; Add Expected length to pointer
3E42H MVI M,00H ; Truncate the string to the max length
3E44H POP H ; Restore pointer to input string
3E45H MOV A,E ; Update length to reflect maximum
3E46H ORA A ; Clear zero flag to indicate input provided
3E47H RET

; =========================================================================================
; Find Empty catalog entry (only 9 instructions...Don't bother with Main ROM)
; =========================================================================================
3E48H LXI H,F9AFH ; Point to the "RickY" catalog entry (start of valid entries)
3E4BH LXI B,000BH ; Load length of each catalog entry
3E4EH DAD B ; Point to next catalog entry to test if empty
3E4FH MOV A,M ; Get file attribute byte from catalog entry
3E50H CPI FFH ; Test if at end of catalog
3E52H JZ 3E5AH ; Jump to report directory full if at end
3E55H ADD A ; Test if MSB is set (entry being used)
3E56H JC 3E4EH ; Jump to test next enry if MSB set
3E59H RET ; Entry found...return with Carry clear

; =========================================================================================
; Empty catalog entry not found...set Carry and exit
; =========================================================================================
3E5AH STC ; Indicate empty entry not found
3E5BH RET

; =========================================================================================
; F5 Function key handler for RAM mode - DOS ON/OF
; =========================================================================================
3E5CH LHLD FB2CH ; Get LFILES statement hook address
3E5FH LXI B,08DBH ; Load address of default (DOS-OFF) hook for LFILES
3E62H DSUB ; Test if in DOS-OFF mode
3E63H JZ 401FH ; Jump to add our custom RST 7 hooks if in DOS-OFF mode
3E66H JMP 3FFAH ; Must be in DOS-ON mode, jump to turn it off

; =========================================================================================
; Strings
; =========================================================================================
3E69H DB 0x1B, "p TS-DOS (100 v4.00) (c)87,TSI. ",0x1B,'q',0x00
3E97H DB "DISK Free: File:",0DH,0AH,"Load Kill Name Ram Frmt Log Menu",00H
3ED9H DB " RAM Free: File:",0DH,0AH,"Save Kill Name Disk DOS- Menu",00H
3F1BH DB "Insert Disk, Press \"Y\" to begin ",00H
3F3CH DB "NOT FORMATTED",00H
3F4AH DB "New Name:",00H
3F54H DB "System name:",00H
3F61H DB "Directory name:",00H
3F71H DB "Save as:",00H
3F7AH DB "Load as:",00H
3F83H DB "Sure ? ",00H
3F8BH DB "File exists, A)ppend R)eplace Q)uit:",00H
3FB0H DB "File exists, Replace? (Y/N):",00H
3FCDH DB "-.- ",00H
3FD8H DB 0x1B,"Y74 ",1BH,"Y7>MkDr",00H ; TODO: Check this
3FE9H DB 0x1B,"Y7>Bank",00H ; TODO: Check this
3FF2H DB "OFF",00H
3FF6H DB "ON ",00H
</pre>

Navigate to:
- [[Dissasembly of RAM and ROM versions of TS-DOS]]
- [[M100 TS-DOS ROM OptROM Support]]
- [[M100 TS-DOS ROM RST 7 Handlers]]
- [[M100 TS-DOS ROM TPDD Protocol]]
- [[M100 TS-DOS ROM Compression]]
- [[M100 TS-DOS ROM Cold Boot Recovery]]

M100 TS-DOS ROM OptROM Support

2009-04-03T07:30:10Z

Kpettit:

== TS-DOS Model 100/102 ROM OptROM Support ==

This code defines the variables used throughout the TS-DOS application as well as the support routines needed to navigate between the Main ROM and the Option ROM (most of them). Also included is the TS-DOS startup code. The assembly labels defined are open for discussion and have not been applied to any of the disassembled code yet.

<pre>
=========================================================================================
; TS-DOS M100 ROM version Disassembly
;
; Initial Disassembly By Kenneth D. Pettit
; March, 2009
;
; =========================================================================================

; =========================================================================================
; Variables in ALTLCD buffer
; =========================================================================================
NB_CUR_DIR equ FCC0H ; NADSBox current directory ("MYFILE.<> ")
TPDD_BANK equ FCCAH ; TPDD2 Bank (side)
NB_TPDD_FLG equ FCCBH ; NADSBox/Desklink/TPDD2 flag (0=TPDD, 1=TPDD2, 2=NADSBox)
LAST_TAG equ FCCCH ; Tag/Untag last operation code
CUR_FILE equ FCCDH ; Currently selected file index on UI (1 based)
LJ_SP equ FCCEH ; Stack pointer upon entry for Long Jump
LJ_RET equ FCD0H ; Return vector for Long Jump "RETURN"
ERR_MODE equ FCD2H ; Print Error Messages flag, 1=Print, 0=Generate System Error
FDC_OPCODE equ FCD3H ; FDC Emulation mode opcode
CUR_PAGE equ FCD4H ; Current page of files being displayed (0 based)
TMP_FILE_IDX equ FCD5H ; Currently selected file index on UI - temp
FILE_COUNT equ FCD6H ; Count of files currently displayed on LCD
MAX_FILES equ FCD7H ; Maximum files that fit on the LCD
DISP_MODE equ FCD9H ; RAM / Disk Display mode (0=RAM, 1=DISK)
SKIP_PAGE equ FCDAH ; TPDD "skip page" count (number of pages to read and discard)
FILE_LEN equ FCDBH ; Pointer to "Current file" length bytes (in keyboard buffer)
PHYS_SCTR equ FCDDH ; FDC Emulation Physical Sector Number / Active File Length LSB
LOG_SCTR equ FCDEH ; FDC Emulation Logical Sector Number / Active File Length MSB
KEY_TYPE equ FCDFH ; Storage for FDC emulation / New file type code / Keypress storage
FILE_ADDR equ FCE0H ; Address of file being displayed/printed/loaded/saved
FILE_BUFF equ FCE2H ; Pointer for TPDD direct read data / address of file being read/written
TX_PKT_BUF equ FCE6H ; Storage for TX packets (28 bytes)
RX_PKT_BUF equ FD02H ; Storage for RX packets (130 bytes ??)

; =========================================================================================
; Main Entry point when called from "CALL 63013,1"
; =========================================================================================

.org 0000H

0000H JMP 00B2H ; Jump to entry point handler

; =========================================================================================
; Pop registers after we power back up from a powerdown (I think)
; =========================================================================================
0003H POP H
0004H POP D
0005H POP B
0006H POP PSW
0007H RET

; =========================================================================================
; RST 1 - Call Main ROM at location whose address follows RST 1 opcode
; =========================================================================================
0008H (C3H) JMP 0080H ; BASIC statement keyword table END to NEW

; =========================================================================================
; RST 2 - Call Main ROM's RST 2 routine
; =========================================================================================
0010H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
0011H DW 0010H ; Call the Main ROM's RST 2 function
0013H (C9H) RET

; =========================================================================================
; RST 3 routine - Compare HL and DE
; =========================================================================================
0018H JMP 006CH ; Jump to comparison routine

; =========================================================================================
; Return to Main ROM. After issuing the OUT E0H, we will be in Main ROM. The next opcode
; in Main ROM after this OUT statement occurs will be a RET (part of RST 1). We have
; PUSHed a return address to the stack, so the main ROM's RET instruction will get us
; where to intend to go.
; =========================================================================================
001BH OUT E0H ; Send A to the ROM bank port to switch to Main ROM
001DH RET ; Should never execute this instruction, but just in case

; =========================================================================================
; Send a space to the screen/printer - Not called from anywhere. Copy of Main ROM.
; =========================================================================================
001EH (3EH) MVI A,20H ; Prepare to print a SPACE

; =========================================================================================
; RST 3 routine - Send character in A to the screen / printer
; =========================================================================================
0020H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
0021H DW 0020H ; Main ROM's RST 3 routine
0023H (C9H) RET

; =========================================================================================
; Power down TRAP. Let Main ROM deal with it.
; =========================================================================================
0024H DI ; Disable interrupts while we jump
0025H CALL 0097H ; Jump to Main ROM's RST handler for this vector
0028H POP H
0029H JMP 0003H ; Pop regs after we power back up from a power-down?

; =========================================================================================
; Hardware Interrupt - Let Main ROM deal with it - Bar Code Reader
; =========================================================================================
002CH DI ; Disable interrupts while we jump
002DH CALL 0097H ; Jump to Main ROM's RST handler for this vector

; =========================================================================================
; Return from Main ROM hook in RAM returns here via RST 6
; =========================================================================================
0030H POP PSW ; Cleanup stack
0031H POP PSW ; Cleanup stack
0032H RET ; Return to OptROM execution point

0033H NOP ; Filler

; =========================================================================================
; Hardware Interrupt - Let Main ROM deal with it - RS232 character pending
; =========================================================================================
0034H DI ; Disable interrupts while we jump
0035H CALL 0097H ; Jump to Main ROM's RST handler for this vector
0038H JMP 00A6H ; Stack cleanup

003BH NOP ; UNUSED - filler

; =========================================================================================
; Hardware Interrupt - Let Main ROM deal with it - Timer background task
; =========================================================================================
003CH DI ; Disable interrupts
003DH CALL 0097H ; Jump to Main ROM's RST handler for this vector

; =========================================================================================
; This routine gets copied to RAM to be used for switching back to the TS-DOS ROM after
; calling a routine in the Main ROM.
; =========================================================================================
0040H PUSH PSW ; Preserve the PSW
0041H LDA FF45H ; Contents of port E8H
0044H INR A ; Prepare to switch to OptRom
0045H OUT E0H ; Switch to OptRom
0047H RST 6 ; Get sign of FAC1

; =========================================================================================
; This routine gets copied to RAM and appears to detect the presence of the TS-DOS ROM
; after power-up and copies the original "External ROM" detection routine to RAM
; if the TS-DOS ROM is no longer present. At least I think that's what it's doing.
; =========================================================================================
0048H LXI D,F605H ; Copy address for "Ext ROM detect" routine
004BH INR A ; Set bit to enable OptROM
004CH OUT E0H ; Switch to OptROM
004EH XRA A ; Prepare to switch back to Main ROM
004FH LHLD 0049H ; Load target address of the LXI D instruction above
0052H OUT E0H ; Switch back to Main ROM
0054H RST 3 ; Compare DE and HL - Test if OptROM is TS-DOS
0055H CPI 01H ; Test for TS-DOS ROM
0057H RC ; Return if TS-DOS ROM
0058H LXI H,111DH ; Load "Return" address to the CALL below
005BH SHLD FAE0H
005EH SHLD F5F2H ; Save a "Restart signature" ???
0061H CALL 2905H ; Copy the DB number of bytes from the DW address to (DE)
0064H DB 24H ; ....copy 24H bytes
0065H DW 036FH ; ....from ROM addres 036F (external ROM detect)
0067H RST 0 ; I'm not sure it it every actually returns here or not
0068H NOP
0069H CALL FAA4H ; Call our installed RAM hook to return to TS-DOS

; =========================================================================================
; Compare HL and DE - called by the RST 3 routine
; =========================================================================================
006CH MOV A,H ; Move H into A for comparison
006DH SUB D ; Compare MSB first
006EH RNZ ; Return if no match
006FH MOV A,L ; Now move L into A
0070H SUB E ; Compare LSB
0071H RET ; Return with flags set

; =========================================================================================
; Copy 8 bytes from DE to HL
; =========================================================================================
0072H LXI B,0008H ; Prepare to copy 8 bytes

; =========================================================================================
; Copy BC bytes from DE to HL
; =========================================================================================
0075H LDAX D ; Load value from (DE)
0076H MOV M,A ; Save value to (HL)
0077H INX D ; Increment DE
0078H INX H ; Increment HL
0079H DCX B ; Decrement counter
007AH MOV A,B ; Prepare to test counter for zero
007BH ORA C ; Test counter for zero
007CH JNZ 0075H ; Keep looping until 8 bytes copied
007FH RET

; =========================================================================================
; Handle the RST 1 routine. Read the Main ROM address from the 2 bytes after the RST 1
; =========================================================================================
0080H SHLD F9B2H ; Save HL off in "RickY" Cat entry so we don't clobber it
0083H POP H ; Get out return address (location of the ROM address to call
0084H PUSH D ; Push the return address back to the stack as storage
0085H MOV E,M ; Get LSB of the ROM address to call
0086H INX H ; Point to MSB of ROM address to call
0087H MOV D,M ; Get MSB of the ROM address to call
0088H INX H ; Point to return address after the RST 1 DB address
0089H XTHL ; Put the return address on the stack so we return after the RST 1
008AH XCHG ; Now get the address within ROM to call
008BH PUSH H ; Push the target ROM address to the stack so we "RETurn" there
008CH LXI H,FAA4H ; Load address of our RAM hook to switch back to our ROM bank and RET
008FH XTHL ; Push that address on the stack for after the ROM call is complete
0090H PUSH H ; Now put the ROM address back on the stack so we will RET there
0091H LHLD F9B2H ; Restore HL from temp storage in "RickY"
0094H JMP 00A6H ; Branch to switch to Main ROM and "RET" to the address we pushed

; =========================================================================================
; RST handler for calling the Main ROM's RST handlers. This routine restores the original
; RST vector address to the stack, and jumps to the Main ROM's RST routine while
; preserving all register values.
; =========================================================================================
0097H SHLD F9B4H ; Save HL temporarily (somewhere in RickY's name)
009AH LXI H,FAA4H ; Point to our RAM hook for returning to TS-DOS
009DH XTHL ; Put the hook address as the return address on the stack
009EH DCX H ; Decrement the return address by 4
009FH DCX H ; ...this will result in the starting address of the RST
00A0H DCX H ; ...that brought us here
00A1H DCX H
00A2H PUSH H ; Push the RST vector address to the stack
00A3H LHLD F9B4H ; Restore HL upon entry
00A6H PUSH PSW ; Save A to the stack
00A7H PUSH H ; Save the HL to the stack so we can preserve through XTHL
00A8H LXI H,1488H ; Load a RETurn address in the Main ROM (a POP PSW & RET)
00ABH XTHL ; Push the address and get HL back
00ACH LDA FF45H ; Contents of port E8H - prepare for jump to Main ROM
00AFH JMP 001BH ; Jump to Main ROM & our custom "RET" address in the ROM

; =========================================================================================
; Manual invocation entry point. This is where we jump when "CALL 63013,1" is invoked
; =========================================================================================
00B2H DI ; Disable interrupts so nobody bugs us yet
00B3H CPI 08H ; Check the invocation parameter to test for recovery request
00B5H JNC 0100H ; Jump to test for recovery mode
00B8H MOV B,A ; Save the calling paramter to B
00B9H PUSH B ; Save BC to the stack
00BAH PUSH D ; Save DE to the stack
00BBH PUSH H ; Save HL to the stack
00BCH LXI D,0040H ; Load address of our "Change to OptROM" routine
00BFH LXI H,FAA4H ; Load pointer to somewhere in RAM to hold our routine
00C2H CALL 0072H ; Copy 8 bytes from DE to HL
00C5H LXI B,0024H ; Now prepare to copy 36 bytes worth of "routine"
00C8H LXI H,F605H ; Point to another RAM location
00CBH CALL 0075H ; Copy the next "ROM Bank Switching" routine from our ROM
00CEH POP H ; Restore HL
00CFH POP D ; Restore DE
00D0H POP PSW ; Restore A
00D1H EI ; Allow interrupts again
00D2H JMP 0100H ; Go test if a "Cold Start" recovery is being requested

.org 100H

; =========================================================================================
; Test if cold-start recovery requested
; =========================================================================================
0100H MOV A,H ; Move H to A to test HL for zero
0101H ORA L ; Test for zero
0102H JZ 7000H ; Call recovery routine if requested
0105H POP H ; Pop the return address. We will exit manually
0106H CALL 0117H ; Ensure the TS-DOS progam is installed in the MENU
0109H JMP 3535H ; Jump to the TS-DOS UI

; =========================================================================================
; Move BC bytes from (HL) to (DE) with increment
; =========================================================================================
010CH MOV A,M ; Get next byte from (HL)
010DH STAX D ; Save byte in (DE)
010EH INX H ; Increment source pointer
010FH INX D ; Increment destination pointer
0110H DCX B ; Decrement loop control
0111H MOV A,B ; Move MSB to A to test for zero
0112H ORA C ; OR in LSB to test for zero
0113H JNZ 010CH ; Branch to copy next byte until done
0116H RET

; =========================================================================================
; Insert the "TS-DOS" invocation program (BASIC program) into the Catalog / MENU.
; we always insert ourselves at the lowest RAM address.
; =========================================================================================
0117H LXI H,01E1H ; Point to "TS-DOS" catalog entry in our ROM
011AH PUSH H ; Save the address on the stack for later
011BH INX H ; Point to the text portion of the catalog entry
011CH LXI B,0008H ; Prepare to copy 8 filename byte
011FH LXI D,FC93H ; Filename of current BASIC program
0122H CALL 010CH ; Copy BC bytes from HL to DE - put "TS-DOS " in cur. BASIC prog.
0125H XCHG ; HL <--> DE DE now has the address of the invocation program
0126H LHLX ; Get the length of the BASIC program into HL
0127H SHLD FCC4H ; Save the BASIC program length in the ALTLCD buffer for now
012AH INX D ; Point to MSB of the length
012BH INX D ; Point to LSB of the pointer to the "Next" BASIC instruction
012CH XCHG ; HL <--> DE HL has the pointer to the "Next" BASIC inst address
012DH SHLD FCC8H ; Save the "Next" BASIC inst pointer to ALTLCD (start of program)
0130H CALL 01D1H ; Update the System pointers
0133H CALL 01CDH ; Search Catalog for entry matching current BASIC program
0136H POP B ; Pop address in case we return
0137H RNZ ; Return if "TS-DOS" is already in the catalog
0138H LHLD F99AH ; Get the BASIC program not saved pointer - insert before that
013BH SHLD FCC2H ; Save storage location for the TS-DOS invocation progam
013EH LDAX B ; Load the file type byte from our ROM (B has the address from above)
013FH STA FCC6H ; Store the Type byte in the ALTLCD
0142H CALL 0185H ; Find empty entry in Catalog
0145H RC ; Return if catalog full
0146H PUSH H ; Save the address of the empty catalog entry to the stack
0147H LHLD FCC4H ; Restore the BASIC program length from ALTLCD
014AH MOV B,H ; Move BASIC program length to BC for copy
014BH MOV C,L ; Move LSB of length
014CH PUSH B ; Save Length to the stack
014DH LHLD FCC2H ; Get address of insertion for TS-DOS just before the unsaved BASIC prog.
0150H CALL 01DDH ; Call Main ROM's Insert BC spaces at M routine
0153H JC 0182H ; Abort if RAM full
0156H LHLD FCC2H ; Get address of insertion point again
0159H XCHG ; DE now has insertion point for BASIC program
015AH LHLD FCC8H ; Get the address of the BASIC program (in our ROM) from ALTLCD
015DH POP B ; Restore copy length of the BASIC program
015EH CALL 010CH ; Move BC bytes from (HL) to (DE) with increment
0161H POP D ; Get the address of the empty catalog entry we will use for TS-DOS
0162H PUSH D ; Save it back to the stack
0163H LHLD FBAEH ; Load the start of DO files pointer
0166H DCX H ; Derement the start of DO files pointer
0167H SHLD F99AH ; Save it as the new BASIC program not saved pointer
016AH INX H ; Point to start of DO files again
016BH XCHG ; Move it to DE
016CH LHLD FCC4H ; Load the TS-DOS BASIC progam length from ALTLCD
016FH DAD D ; Offset the start of DO files by the insertion amount
0170H SHLD FBAEH ; Save the new start of DO files pointer
0173H POP D ; Restore the address of the empty catalog entry
0174H LHLD FCC2H ; Get the starting address of the newly inserted TS-DOS program
0177H XCHG ; HL <--> DE Swap for the call to the catalog insertion routine
0178H LDA FCC6H ; Load A with the file type byte
017BH CALL 01D5H ; Save current BASIC program to the Catalog entry at HL
017EH CALL 01D1H ; Update system pointers
0181H RET

; =========================================================================================
; Insert "TS-DOS" RAM full abort routine ... stack cleanup.
; =========================================================================================
0182H POP H ; Pop the BASIC program length from the stack
0183H POP H ; Pop the catalog entry address from the stack
0184H RET

; =========================================================================================
; Find an empty entry in the Catalog. HL points to start of new entry
; This routine appears again at address 3E48H
; =========================================================================================
0185H LXI H,F9AFH ; Point to "RickY" to start search at beginning of catalog
0188H LXI B,000BH ; Get length of each entry in the Catalog
018BH DAD B ; Point to next entry in the catalog
018CH MOV A,M ; Get the File Attribute byte from the catalog for this file
018DH CPI FFH ; Test if at end of the catalog
018FH JZ 0197H ; Jump to set Carry flag and exit if at end
0192H ADD A ; Test if MSB set (test if entry available)
0193H JC 018BH ; Branch to get next entry if this one is used
0196H RET ; Return with Carry clear to indicate entry found

; =========================================================================================
; Empty catalog entry not found in Catalog, set Carry and return
; =========================================================================================
0197H STC ; Set the Carry flag - not found
0198H RET

; =========================================================================================
; Call Main ROM's Display function key line routine
; =========================================================================================
0199H RST 1 ; Call main ROM at address in following 2 bytes
019AH DW 42A8H
019CH RET

; =========================================================================================
; Call Main ROM's Erase function key display routine
; =========================================================================================
019DH RST 1 ; Call main ROM at address in following 2 bytes
019EH DW 428AH
01A0H RET

; =========================================================================================
; Call Main ROM's Set new function key table routine
; =========================================================================================
01A1H RST 1 ; Call main ROM at address in following 2 bytes
01A2H DW 5A7CH
01A4H RET

; =========================================================================================
; Call Main ROM's Wait for key from keyboard routine
; =========================================================================================
01A5H RST 1 ; Call main ROM at address in following 2 bytes
01A6H DW 12CBH
01A8H RET

; =========================================================================================
; Call Main ROM's Scan keyboard for character (CTRL-BREAK ==> CTRL-C) routine
; This appears later in the code also
; =========================================================================================
01A9H RST 1 ; Call main ROM at address in following 2 bytes
01AAH DW 7242H
01ACH RET

; =========================================================================================
; Call Main ROM's Power Down routine
; This appears later in the code also
; =========================================================================================
01ADH RST 1 ; Call main ROM at address in following 2 bytes
01AEH DW 13B5H
01B0H RET

; =========================================================================================
; Call Main ROM's Renew automatic power-off counter routine
; This apears later in the code also
; =========================================================================================
01B1H RST 1 ; Call main ROM at address in following 2 bytes
01B2H DW 1BB1H
01B4H RET

; =========================================================================================
; Call Main ROM's CLS statement routine
; This apears later in the code also
; =========================================================================================
01B5H RST 1 ; Call main ROM at address in following 2 bytes
01B6H DW 4231H
01B8H RET

; =========================================================================================
; Call Main ROM's Start inverse character mode routine
; This appears later in the code also
; =========================================================================================
01B9H RST 1 ; Call main ROM at address in following 2 bytes
01BAH DW 4269H
01BCH RET

; =========================================================================================
; Call Main ROM's Cancel inverse video routine
; This appears later in the code also
; =========================================================================================
01BDH RST 1 ; Call main ROM at address in following 2 bytes
01BEH DW 426EH
01C0H RET

; =========================================================================================
; Call Main ROM's Check keyboard queue for pending characters routine
; This appers later in the code also
; =========================================================================================
01C1H RST 1 ; Call main ROM at address in following 2 bytes
01C2H DW 13DBH
01C4H RET

; =========================================================================================
; Call Main ROM's Stop automatic scrolling routine
; This appers later in the code also
; =========================================================================================
01C5H RST 1 ; Call main ROM at address in following 2 bytes
01C6H DW 423FH
01C8H RET

; =========================================================================================
; Call Main ROM's Reset vector routine
; =========================================================================================
01C9H RST 1 ; Call main ROM at address in following 2 bytes
01CAH DW 0000H
01CCH RET

; =========================================================================================
; Search Catalog for entry matching current BASIC program
; =========================================================================================
01CDH RST 1 ; Call main ROM at address in following 2 bytes
01CEH DW 20AFH
01D0H RET

; =========================================================================================
; Call Main ROM's Update system pointers routine
; =========================================================================================
01D1H RST 1 ; Call main ROM at address in following 2 bytes
01D2H DW 2146H
01D4H RET

; =========================================================================================
; Call Main ROM's routine to save current BASIC program to the Catalog entry at HL
; =========================================================================================
01D5H RST 1 ; Call main ROM at address in following 2 bytes
01D6H DW 2239H
01D8H RET

; =========================================================================================
; Not a valid entry into ROM and not called anywhere
; =========================================================================================
01D9H RST 1 ; Call main ROM at address in following 2 bytes
01DAH DW 5825H
01DCH RET

; =========================================================================================
; Call Main ROM's Insert BC spaces at M routine
; =========================================================================================
01DDH RST 1 ; Call main ROM at address in following 2 bytes
01DEH DB 6B6DH
01E0H RET

; =========================================================================================
; TS-DOS entry that will be inserted into the catalog for invoking TS-DOS
; =========================================================================================
01E1H DB 80H ; TS-DOS file type for catalog entry
01E2H DB "TS-DOS " ; TS-DOS Catalog name entry

; =========================================================================================
; BASIC program that will be inserted into RAM to launch TS-DOS from the MENU/Catalog entry
; =========================================================================================
01EAH DB 0FH,00H,0EH,80H ; BASIC program length and pointer to "Next" BASIC instruction
01EDH DB 0AH,00H,B9H ; BASIC Line number "10" and BASIC token for CALL
01EFH DB "63013,1" ; CALL argument
01F5H DB 00H,00H ; BASIC terminating zeros

</pre>

End of disassembly for OptROM Support.

Navigate to:
- [[Dissasembly of RAM and ROM versions of TS-DOS]]
- [[M100 TS-DOS ROM UI Code]]
- [[M100 TS-DOS ROM FKey Handlers]]
- [[M100 TS-DOS ROM RST 7 Handlers]]
- [[M100 TS-DOS ROM TPDD Protocol]]
- [[M100 TS-DOS ROM Compression]]
- [[M100 TS-DOS ROM Cold Boot Recovery]]

Disassembly of RAM and ROM versions of TS-DOS

2009-04-03T07:26:36Z

Kpettit: /* Model 100/102 ROM Version */

== TS-DOS Dissassembly ==

There are various version of TS-DOS for The Model 100/102, for T200 and for the PC-8201a. Additionally each of these versions has a ROM and a RAM. While the majority of the code is equivalent across the various incarnations of TS-DOS, there are some differences due to varying RS-232 hardware and to accomodate execution from OptROM vs. RAM.

The goal of the disassembly is to create a fully commented source file that can be assembled and subsequently modified / enhanced for new functionality. The disassembly is split into several sections to keep each page "relatively" short. The disassembly currently will not assemble as it contains absolute addresses that must be converted into assembly labels, or deleted where not needed.

== Model 100/102 ROM Version ==
- [[M100 TS-DOS ROM OptROM Support]]
- [[M100 TS-DOS ROM UI Code]]
- [[M100 TS-DOS ROM FKey Handlers]]
- [[M100 TS-DOS ROM RST 7 Handlers]]
- [[M100 TS-DOS ROM TPDD Protocol]]

Not Completed Yet
- [[M100 TS-DOS ROM Compression]]
- [[M100 TS-DOS ROM Cold Boot Recovery]]

== Model 200 RAM Version ==
[[UI Code]] [[FKey Handlers]] [[RST 7 Handlers]] [[TPDD Protocol]]

Disassembly of RAM and ROM versions of TS-DOS

2009-04-03T07:21:47Z

Kpettit: /* Model 100/102 ROM Version */

== TS-DOS Dissassembly ==

There are various version of TS-DOS for The Model 100/102, for T200 and for the PC-8201a. Additionally each of these versions has a ROM and a RAM. While the majority of the code is equivalent across the various incarnations of TS-DOS, there are some differences due to varying RS-232 hardware and to accomodate execution from OptROM vs. RAM.

The goal of the disassembly is to create a fully commented source file that can be assembled and subsequently modified / enhanced for new functionality. The disassembly is split into several sections to keep each page "relatively" short. The disassembly currently will not assemble as it contains absolute addresses that must be converted into assembly labels, or deleted where not needed.

== Model 100/102 ROM Version ==
[[M100 TS-DOS ROM OptROM Support]] [[M100 TS-DOS ROM UI Code]]
[[M100 TS-DOS ROM FKey Handlers]] [[M100 TS-DOS ROM RST 7 Handlers]]
[[M100 TS-DOS ROM TPDD Protocol]]

Not Completed Yet
[[M100 TS-DOS ROM Compression]] [[M100 TS-DOS ROM Cold Boot Recovery]]

== Model 200 RAM Version ==
[[UI Code]] [[FKey Handlers]] [[RST 7 Handlers]] [[TPDD Protocol]]

M100 ROM OptROM Support

2009-04-03T07:12:02Z

Kpettit: M100 ROM OptROM Support moved to M100 TS-DOS ROM OptROM Support: Adding TS-DOS to the page title in case there are other ROMS disassembled in the future.

#REDIRECT [[M100 TS-DOS ROM OptROM Support]]

M100 TS-DOS ROM OptROM Support

2009-04-03T07:12:02Z

Kpettit: M100 ROM OptROM Support moved to M100 TS-DOS ROM OptROM Support: Adding TS-DOS to the page title in case there are other ROMS disassembled in the future.

M100 TS-DOS ROM OptROM Support

2009-04-03T07:11:03Z

Kpettit:

Disassembly of RAM and ROM versions of TS-DOS

2009-04-03T07:05:21Z

Kpettit: /* Model 100/102 ROM Version */

== TS-DOS Dissassembly ==

There are various version of TS-DOS for The Model 100/102, for T200 and for the PC-8201a. Additionally each of these versions has a ROM and a RAM. While the majority of the code is equivalent across the various incarnations of TS-DOS, there are some differences due to varying RS-232 hardware and to accomodate execution from OptROM vs. RAM.

The goal of the disassembly is to create a fully commented source file that can be assembled and subsequently modified / enhanced for new functionality. The disassembly is split into several sections to keep each page "relatively" short. The disassembly currently will not assemble as it contains absolute addresses that must be converted into assembly labels, or deleted where not needed.

== Model 100/102 ROM Version ==
[[M100 ROM OptROM Support]] [[M100 ROM UI Code]]
[[M100 ROM FKey Handlers]] [[M100 ROM RST 7 Handlers]]
[[M100 ROM TPDD Protocol]]

Not Completed Yet
[[M100 ROM Compression]] [[M100 ROM Cold Boot Recovery]]

== Model 200 RAM Version ==
[[UI Code]] [[FKey Handlers]] [[RST 7 Handlers]] [[TPDD Protocol]]

OptROM Support

2009-04-03T07:01:16Z

Kpettit: OptROM Support moved to M100 ROM OptROM Support: To allow OptROM Support pages per Model

#REDIRECT [[M100 ROM OptROM Support]]

M100 TS-DOS ROM OptROM Support

2009-04-03T07:01:16Z

Kpettit: OptROM Support moved to M100 ROM OptROM Support: To allow OptROM Support pages per Model

= TS-DOS Model 100/102 =

== OptROM Support ==

This code defines the variables used throughout the TS-DOS application as well as the support routines needed to navigate between the Main ROM and the Option ROM (most of them). Also included is the TS-DOS startup code. The assembly labels defined are open for discussion and have not been applied to any of the disassembled code yet.

<pre>
=========================================================================================
; TS-DOS M100 ROM version Disassembly
;
; By Kenneth D. Pettit
; March, 2009
;
; =========================================================================================

; =========================================================================================
; Variables in ALTLCD buffer
; =========================================================================================
NB_CUR_DIR equ FCC0H ; NADSBox current directory ("MYFILE.<> ")
TPDD_BANK equ FCCAH ; TPDD2 Bank (side)
NB_TPDD_FLG equ FCCBH ; NADSBox/Desklink/TPDD2 flag (0=TPDD, 1=TPDD2, 2=NADSBox)
LAST_TAG equ FCCCH ; Tag/Untag last operation code
CUR_FILE equ FCCDH ; Currently selected file index on UI (1 based)
LJ_SP equ FCCEH ; Stack pointer upon entry for Long Jump
LJ_RET equ FCD0H ; Return vector for Long Jump "RETURN"
ERR_MODE equ FCD2H ; Print Error Messages flag, 1=Print, 0=Generate System Error
FDC_OPCODE equ FCD3H ; FDC Emulation mode opcode
CUR_PAGE equ FCD4H ; Current page of files being displayed (0 based)
TMP_FILE_IDX equ FCD5H ; Currently selected file index on UI - temp
FILE_COUNT equ FCD6H ; Count of files currently displayed on LCD
MAX_FILES equ FCD7H ; Maximum files that fit on the LCD
DISP_MODE equ FCD9H ; RAM / Disk Display mode (0=RAM, 1=DISK)
SKIP_PAGE equ FCDAH ; TPDD "skip page" count (number of pages to read and discard)
FILE_LEN equ FCDBH ; Pointer to "Current file" length bytes (in keyboard buffer)
PHYS_SCTR equ FCDDH ; FDC Emulation Physical Sector Number / Active File Length LSB
LOG_SCTR equ FCDEH ; FDC Emulation Logical Sector Number / Active File Length MSB
KEY_TYPE equ FCDFH ; Storage for FDC emulation / New file type code / Keypress storage
FILE_ADDR equ FCE0H ; Address of file being displayed/printed/loaded/saved
FILE_BUFF equ FCE2H ; Pointer for TPDD direct read data / address of file being read/written
TX_PKT_BUF equ FCE6H ; Storage for TX packets (28 bytes)
RX_PKT_BUF equ FD02H ; Storage for RX packets (130 bytes ??)

; =========================================================================================
; Main Entry point when called from "CALL 63013,1"
; =========================================================================================

.org 0000H

0000H JMP 00B2H ; Jump to entry point handler

; =========================================================================================
; Pop registers after we power back up from a powerdown (I think)
; =========================================================================================
0003H POP H
0004H POP D
0005H POP B
0006H POP PSW
0007H RET

; =========================================================================================
; RST 1 - Call Main ROM at location whose address follows RST 1 opcode
; =========================================================================================
0008H (C3H) JMP 0080H ; BASIC statement keyword table END to NEW

; =========================================================================================
; RST 2 - Call Main ROM's RST 2 routine
; =========================================================================================
0010H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
0011H DW 0010H ; Call the Main ROM's RST 2 function
0013H (C9H) RET

; =========================================================================================
; RST 3 routine - Compare HL and DE
; =========================================================================================
0018H JMP 006CH ; Jump to comparison routine

; =========================================================================================
; Return to Main ROM. After issuing the OUT E0H, we will be in Main ROM. The next opcode
; in Main ROM after this OUT statement occurs will be a RET (part of RST 1). We have
; PUSHed a return address to the stack, so the main ROM's RET instruction will get us
; where to intend to go.
; =========================================================================================
001BH OUT E0H ; Send A to the ROM bank port to switch to Main ROM
001DH RET ; Should never execute this instruction, but just in case

; =========================================================================================
; Send a space to the screen/printer - Not called from anywhere. Copy of Main ROM.
; =========================================================================================
001EH (3EH) MVI A,20H ; Prepare to print a SPACE

; =========================================================================================
; RST 3 routine - Send character in A to the screen / printer
; =========================================================================================
0020H (CFH) RST 1 ; Call main ROM at address in following 2 bytes
0021H DW 0020H ; Main ROM's RST 3 routine
0023H (C9H) RET

; =========================================================================================
; Power down TRAP. Let Main ROM deal with it.
; =========================================================================================
0024H DI ; Disable interrupts while we jump
0025H CALL 0097H ; Jump to Main ROM's RST handler for this vector
0028H POP H
0029H JMP 0003H ; Pop regs after we power back up from a power-down?

; =========================================================================================
; Hardware Interrupt - Let Main ROM deal with it - Bar Code Reader
; =========================================================================================
002CH DI ; Disable interrupts while we jump
002DH CALL 0097H ; Jump to Main ROM's RST handler for this vector

; =========================================================================================
; Return from Main ROM hook in RAM returns here via RST 6
; =========================================================================================
0030H POP PSW ; Cleanup stack
0031H POP PSW ; Cleanup stack
0032H RET ; Return to OptROM execution point

0033H NOP ; Filler

; =========================================================================================
; Hardware Interrupt - Let Main ROM deal with it - RS232 character pending
; =========================================================================================
0034H DI ; Disable interrupts while we jump
0035H CALL 0097H ; Jump to Main ROM's RST handler for this vector
0038H JMP 00A6H ; Stack cleanup

003BH NOP ; UNUSED - filler

; =========================================================================================
; Hardware Interrupt - Let Main ROM deal with it - Timer background task
; =========================================================================================
003CH DI ; Disable interrupts
003DH CALL 0097H ; Jump to Main ROM's RST handler for this vector

; =========================================================================================
; This routine gets copied to RAM to be used for switching back to the TS-DOS ROM after
; calling a routine in the Main ROM.
; =========================================================================================
0040H PUSH PSW ; Preserve the PSW
0041H LDA FF45H ; Contents of port E8H
0044H INR A ; Prepare to switch to OptRom
0045H OUT E0H ; Switch to OptRom
0047H RST 6 ; Get sign of FAC1

; =========================================================================================
; This routine gets copied to RAM and appears to detect the presence of the TS-DOS ROM
; after power-up and copies the original "External ROM" detection routine to RAM
; if the TS-DOS ROM is no longer present. At least I think that's what it's doing.
; =========================================================================================
0048H LXI D,F605H ; Copy address for "Ext ROM detect" routine
004BH INR A ; Set bit to enable OptROM
004CH OUT E0H ; Switch to OptROM
004EH XRA A ; Prepare to switch back to Main ROM
004FH LHLD 0049H ; Load target address of the LXI D instruction above
0052H OUT E0H ; Switch back to Main ROM
0054H RST 3 ; Compare DE and HL - Test if OptROM is TS-DOS
0055H CPI 01H ; Test for TS-DOS ROM
0057H RC ; Return if TS-DOS ROM
0058H LXI H,111DH ; Load "Return" address to the CALL below
005BH SHLD FAE0H
005EH SHLD F5F2H ; Save a "Restart signature" ???
0061H CALL 2905H ; Copy the DB number of bytes from the DW address to (DE)
0064H DB 24H ; ....copy 24H bytes
0065H DW 036FH ; ....from ROM addres 036F (external ROM detect)
0067H RST 0 ; I'm not sure it it every actually returns here or not
0068H NOP
0069H CALL FAA4H ; Call our installed RAM hook to return to TS-DOS

; =========================================================================================
; Compare HL and DE - called by the RST 3 routine
; =========================================================================================
006CH MOV A,H ; Move H into A for comparison
006DH SUB D ; Compare MSB first
006EH RNZ ; Return if no match
006FH MOV A,L ; Now move L into A
0070H SUB E ; Compare LSB
0071H RET ; Return with flags set

; =========================================================================================
; Copy 8 bytes from DE to HL
; =========================================================================================
0072H LXI B,0008H ; Prepare to copy 8 bytes

; =========================================================================================
; Copy BC bytes from DE to HL
; =========================================================================================
0075H LDAX D ; Load value from (DE)
0076H MOV M,A ; Save value to (HL)
0077H INX D ; Increment DE
0078H INX H ; Increment HL
0079H DCX B ; Decrement counter
007AH MOV A,B ; Prepare to test counter for zero
007BH ORA C ; Test counter for zero
007CH JNZ 0075H ; Keep looping until 8 bytes copied
007FH RET

; =========================================================================================
; Handle the RST 1 routine. Read the Main ROM address from the 2 bytes after the RST 1
; =========================================================================================
0080H SHLD F9B2H ; Save HL off in "RickY" Cat entry so we don't clobber it
0083H POP H ; Get out return address (location of the ROM address to call
0084H PUSH D ; Push the return address back to the stack as storage
0085H MOV E,M ; Get LSB of the ROM address to call
0086H INX H ; Point to MSB of ROM address to call
0087H MOV D,M ; Get MSB of the ROM address to call
0088H INX H ; Point to return address after the RST 1 DB address
0089H XTHL ; Put the return address on the stack so we return after the RST 1
008AH XCHG ; Now get the address within ROM to call
008BH PUSH H ; Push the target ROM address to the stack so we "RETurn" there
008CH LXI H,FAA4H ; Load address of our RAM hook to switch back to our ROM bank and RET
008FH XTHL ; Push that address on the stack for after the ROM call is complete
0090H PUSH H ; Now put the ROM address back on the stack so we will RET there
0091H LHLD F9B2H ; Restore HL from temp storage in "RickY"
0094H JMP 00A6H ; Branch to switch to Main ROM and "RET" to the address we pushed

; =========================================================================================
; RST handler for calling the Main ROM's RST handlers. This routine restores the original
; RST vector address to the stack, and jumps to the Main ROM's RST routine while
; preserving all register values.
; =========================================================================================
0097H SHLD F9B4H ; Save HL temporarily (somewhere in RickY's name)
009AH LXI H,FAA4H ; Point to our RAM hook for returning to TS-DOS
009DH XTHL ; Put the hook address as the return address on the stack
009EH DCX H ; Decrement the return address by 4
009FH DCX H ; ...this will result in the starting address of the RST
00A0H DCX H ; ...that brought us here
00A1H DCX H
00A2H PUSH H ; Push the RST vector address to the stack
00A3H LHLD F9B4H ; Restore HL upon entry
00A6H PUSH PSW ; Save A to the stack
00A7H PUSH H ; Save the HL to the stack so we can preserve through XTHL
00A8H LXI H,1488H ; Load a RETurn address in the Main ROM (a POP PSW & RET)
00ABH XTHL ; Push the address and get HL back
00ACH LDA FF45H ; Contents of port E8H - prepare for jump to Main ROM
00AFH JMP 001BH ; Jump to Main ROM & our custom "RET" address in the ROM

; =========================================================================================
; Manual invocation entry point. This is where we jump when "CALL 63013,1" is invoked
; =========================================================================================
00B2H DI ; Disable interrupts so nobody bugs us yet
00B3H CPI 08H ; Check the invocation parameter to test for recovery request
00B5H JNC 0100H ; Jump to test for recovery mode
00B8H MOV B,A ; Save the calling paramter to B
00B9H PUSH B ; Save BC to the stack
00BAH PUSH D ; Save DE to the stack
00BBH PUSH H ; Save HL to the stack
00BCH LXI D,0040H ; Load address of our "Change to OptROM" routine
00BFH LXI H,FAA4H ; Load pointer to somewhere in RAM to hold our routine
00C2H CALL 0072H ; Copy 8 bytes from DE to HL
00C5H LXI B,0024H ; Now prepare to copy 36 bytes worth of "routine"
00C8H LXI H,F605H ; Point to another RAM location
00CBH CALL 0075H ; Copy the next "ROM Bank Switching" routine from our ROM
00CEH POP H ; Restore HL
00CFH POP D ; Restore DE
00D0H POP PSW ; Restore A
00D1H EI ; Allow interrupts again
00D2H JMP 0100H ; Go test if a "Cold Start" recovery is being requested

.org 100H

; =========================================================================================
; Test if cold-start recovery requested
; =========================================================================================
0100H MOV A,H ; Move H to A to test HL for zero
0101H ORA L ; Test for zero
0102H JZ 7000H ; Call recovery routine if requested
0105H POP H ; Pop the return address. We will exit manually
0106H CALL 0117H ; Ensure the TS-DOS progam is installed in the MENU
0109H JMP 3535H ; Jump to the TS-DOS UI

; =========================================================================================
; Move BC bytes from (HL) to (DE) with increment
; =========================================================================================
010CH MOV A,M ; Get next byte from (HL)
010DH STAX D ; Save byte in (DE)
010EH INX H ; Increment source pointer
010FH INX D ; Increment destination pointer
0110H DCX B ; Decrement loop control
0111H MOV A,B ; Move MSB to A to test for zero
0112H ORA C ; OR in LSB to test for zero
0113H JNZ 010CH ; Branch to copy next byte until done
0116H RET

; =========================================================================================
; Insert the "TS-DOS" invocation program (BASIC program) into the Catalog / MENU.
; we always insert ourselves at the lowest RAM address.
; =========================================================================================
0117H LXI H,01E1H ; Point to "TS-DOS" catalog entry in our ROM
011AH PUSH H ; Save the address on the stack for later
011BH INX H ; Point to the text portion of the catalog entry
011CH LXI B,0008H ; Prepare to copy 8 filename byte
011FH LXI D,FC93H ; Filename of current BASIC program
0122H CALL 010CH ; Copy BC bytes from HL to DE - put "TS-DOS " in cur. BASIC prog.
0125H XCHG ; HL <--> DE DE now has the address of the invocation program
0126H LHLX ; Get the length of the BASIC program into HL
0127H SHLD FCC4H ; Save the BASIC program length in the ALTLCD buffer for now
012AH INX D ; Point to MSB of the length
012BH INX D ; Point to LSB of the pointer to the "Next" BASIC instruction
012CH XCHG ; HL <--> DE HL has the pointer to the "Next" BASIC inst address
012DH SHLD FCC8H ; Save the "Next" BASIC inst pointer to ALTLCD (start of program)
0130H CALL 01D1H ; Update the System pointers
0133H CALL 01CDH ; Search Catalog for entry matching current BASIC program
0136H POP B ; Pop address in case we return
0137H RNZ ; Return if "TS-DOS" is already in the catalog
0138H LHLD F99AH ; Get the BASIC program not saved pointer - insert before that
013BH SHLD FCC2H ; Save storage location for the TS-DOS invocation progam
013EH LDAX B ; Load the file type byte from our ROM (B has the address from above)
013FH STA FCC6H ; Store the Type byte in the ALTLCD
0142H CALL 0185H ; Find empty entry in Catalog
0145H RC ; Return if catalog full
0146H PUSH H ; Save the address of the empty catalog entry to the stack
0147H LHLD FCC4H ; Restore the BASIC program length from ALTLCD
014AH MOV B,H ; Move BASIC program length to BC for copy
014BH MOV C,L ; Move LSB of length
014CH PUSH B ; Save Length to the stack
014DH LHLD FCC2H ; Get address of insertion for TS-DOS just before the unsaved BASIC prog.
0150H CALL 01DDH ; Call Main ROM's Insert BC spaces at M routine
0153H JC 0182H ; Abort if RAM full
0156H LHLD FCC2H ; Get address of insertion point again
0159H XCHG ; DE now has insertion point for BASIC program
015AH LHLD FCC8H ; Get the address of the BASIC program (in our ROM) from ALTLCD
015DH POP B ; Restore copy length of the BASIC program
015EH CALL 010CH ; Move BC bytes from (HL) to (DE) with increment
0161H POP D ; Get the address of the empty catalog entry we will use for TS-DOS
0162H PUSH D ; Save it back to the stack
0163H LHLD FBAEH ; Load the start of DO files pointer
0166H DCX H ; Derement the start of DO files pointer
0167H SHLD F99AH ; Save it as the new BASIC program not saved pointer
016AH INX H ; Point to start of DO files again
016BH XCHG ; Move it to DE
016CH LHLD FCC4H ; Load the TS-DOS BASIC progam length from ALTLCD
016FH DAD D ; Offset the start of DO files by the insertion amount
0170H SHLD FBAEH ; Save the new start of DO files pointer
0173H POP D ; Restore the address of the empty catalog entry
0174H LHLD FCC2H ; Get the starting address of the newly inserted TS-DOS program
0177H XCHG ; HL <--> DE Swap for the call to the catalog insertion routine
0178H LDA FCC6H ; Load A with the file type byte
017BH CALL 01D5H ; Save current BASIC program to the Catalog entry at HL
017EH CALL 01D1H ; Update system pointers
0181H RET

; =========================================================================================
; Insert "TS-DOS" RAM full abort routine ... stack cleanup.
; =========================================================================================
0182H POP H ; Pop the BASIC program length from the stack
0183H POP H ; Pop the catalog entry address from the stack
0184H RET

; =========================================================================================
; Find an empty entry in the Catalog. HL points to start of new entry
; This routine appears again at address 3E48H
; =========================================================================================
0185H LXI H,F9AFH ; Point to "RickY" to start search at beginning of catalog
0188H LXI B,000BH ; Get length of each entry in the Catalog
018BH DAD B ; Point to next entry in the catalog
018CH MOV A,M ; Get the File Attribute byte from the catalog for this file
018DH CPI FFH ; Test if at end of the catalog
018FH JZ 0197H ; Jump to set Carry flag and exit if at end
0192H ADD A ; Test if MSB set (test if entry available)
0193H JC 018BH ; Branch to get next entry if this one is used
0196H RET ; Return with Carry clear to indicate entry found

; =========================================================================================
; Empty catalog entry not found in Catalog, set Carry and return
; =========================================================================================
0197H STC ; Set the Carry flag - not found
0198H RET

; =========================================================================================
; Call Main ROM's Display function key line routine
; =========================================================================================
0199H RST 1 ; Call main ROM at address in following 2 bytes
019AH DW 42A8H
019CH RET

; =========================================================================================
; Call Main ROM's Erase function key display routine
; =========================================================================================
019DH RST 1 ; Call main ROM at address in following 2 bytes
019EH DW 428AH
01A0H RET

; =========================================================================================
; Call Main ROM's Set new function key table routine
; =========================================================================================
01A1H RST 1 ; Call main ROM at address in following 2 bytes
01A2H DW 5A7CH
01A4H RET

; =========================================================================================
; Call Main ROM's Wait for key from keyboard routine
; =========================================================================================
01A5H RST 1 ; Call main ROM at address in following 2 bytes
01A6H DW 12CBH
01A8H RET

; =========================================================================================
; Call Main ROM's Scan keyboard for character (CTRL-BREAK ==> CTRL-C) routine
; This appears later in the code also
; =========================================================================================
01A9H RST 1 ; Call main ROM at address in following 2 bytes
01AAH DW 7242H
01ACH RET

; =========================================================================================
; Call Main ROM's Power Down routine
; This appears later in the code also
; =========================================================================================
01ADH RST 1 ; Call main ROM at address in following 2 bytes
01AEH DW 13B5H
01B0H RET

; =========================================================================================
; Call Main ROM's Renew automatic power-off counter routine
; This apears later in the code also
; =========================================================================================
01B1H RST 1 ; Call main ROM at address in following 2 bytes
01B2H DW 1BB1H
01B4H RET

; =========================================================================================
; Call Main ROM's CLS statement routine
; This apears later in the code also
; =========================================================================================
01B5H RST 1 ; Call main ROM at address in following 2 bytes
01B6H DW 4231H
01B8H RET

; =========================================================================================
; Call Main ROM's Start inverse character mode routine
; This appears later in the code also
; =========================================================================================
01B9H RST 1 ; Call main ROM at address in following 2 bytes
01BAH DW 4269H
01BCH RET

; =========================================================================================
; Call Main ROM's Cancel inverse video routine
; This appears later in the code also
; =========================================================================================
01BDH RST 1 ; Call main ROM at address in following 2 bytes
01BEH DW 426EH
01C0H RET

; =========================================================================================
; Call Main ROM's Check keyboard queue for pending characters routine
; This appers later in the code also
; =========================================================================================
01C1H RST 1 ; Call main ROM at address in following 2 bytes
01C2H DW 13DBH
01C4H RET

; =========================================================================================
; Call Main ROM's Stop automatic scrolling routine
; This appers later in the code also
; =========================================================================================
01C5H RST 1 ; Call main ROM at address in following 2 bytes
01C6H DW 423FH
01C8H RET

; =========================================================================================
; Call Main ROM's Reset vector routine
; =========================================================================================
01C9H RST 1 ; Call main ROM at address in following 2 bytes
01CAH DW 0000H
01CCH RET

; =========================================================================================
; Search Catalog for entry matching current BASIC program
; =========================================================================================
01CDH RST 1 ; Call main ROM at address in following 2 bytes
01CEH DW 20AFH
01D0H RET

; =========================================================================================
; Call Main ROM's Update system pointers routine
; =========================================================================================
01D1H RST 1 ; Call main ROM at address in following 2 bytes
01D2H DW 2146H
01D4H RET

; =========================================================================================
; Call Main ROM's routine to save current BASIC program to the Catalog entry at HL
; =========================================================================================
01D5H RST 1 ; Call main ROM at address in following 2 bytes
01D6H DW 2239H
01D8H RET

; =========================================================================================
; Not a valid entry into ROM and not called anywhere
; =========================================================================================
01D9H RST 1 ; Call main ROM at address in following 2 bytes
01DAH DW 5825H
01DCH RET

; =========================================================================================
; Call Main ROM's Insert BC spaces at M routine
; =========================================================================================
01DDH RST 1 ; Call main ROM at address in following 2 bytes
01DEH DB 6B6DH
01E0H RET

; =========================================================================================
; TS-DOS entry that will be inserted into the catalog for invoking TS-DOS
; =========================================================================================
01E1H DB 80H ; TS-DOS file type for catalog entry
01E2H DB "TS-DOS " ; TS-DOS Catalog name entry

; =========================================================================================
; BASIC program that will be inserted into RAM to launch TS-DOS from the MENU/Catalog entry
; =========================================================================================
01EAH DB 0FH,00H,0EH,80H ; BASIC program length and pointer to "Next" BASIC instruction
01EDH DB 0AH,00H,B9H ; BASIC Line number "10" and BASIC token for CALL
01EFH DB "63013,1" ; CALL argument
01F5H DB 00H,00H ; BASIC terminating zeros

</pre>

End of disassembly for OptROM Support.

M100 TS-DOS ROM OptROM Support

2009-04-03T06:58:31Z

Kpettit: New page: = TS-DOS Model 100/102 = == OptROM Support == This code defines the variables used throughout the TS-DOS application as well as the support routines needed to navigate between the Main R...

Disassembly of RAM and ROM versions of TS-DOS

2009-04-03T06:52:54Z

Kpettit:

== TS-DOS Dissassembly ==

There are various version of TS-DOS for The Model 100/102, for T200 and for the PC-8201a. Additionally each of these versions has a ROM and a RAM. While the majority of the code is equivalent across the various incarnations of TS-DOS, there are some differences due to varying RS-232 hardware and to accomodate execution from OptROM vs. RAM.

The goal of the disassembly is to create a fully commented source file that can be assembled and subsequently modified / enhanced for new functionality. The disassembly is split into several sections to keep each page "relatively" short. The disassembly currently will not assemble as it contains absolute addresses that must be converted into assembly labels, or deleted where not needed.

== Model 100/102 ROM Version ==
[[OptROM Support]] [[UI Code]] [[FKey Handlers]] [[RST 7 Handlers]] [[TPDD Protocol]]

Not Completed Yet
[[Compression/Decompression]] [[Cold Boot Recovery]]

== Model 200 RAM Version ==
[[UI Code]] [[FKey Handlers]] [[RST 7 Handlers]] [[TPDD Protocol]]

Disassembly of RAM and ROM versions of TS-DOS

2009-04-03T06:51:36Z

Kpettit: New page: == TS-DOS Dissassembly == There are various version of TS-DOS for The Model 100/102, for T200 and for the PC-8201a. Additionally each of these versions has a ROM and a RAM. While the ma...

== TS-DOS Dissassembly ==

There are various version of TS-DOS for The Model 100/102, for T200 and for the PC-8201a. Additionally each of these versions has a ROM and a RAM. While the majority of the code is equivalent across the various incarnations of TS-DOS, there are some differences due to varying RS-232 hardware and to accomodate execution from OptROM vs. RAM.

The goal of the disassembly is to create a fully commented source file that can be assembled and subsequently modified / enhanced for new functionality. The disassembly is split into several sections to keep each page "relatively" short. The disassembly currently will not assemble as it contains absolute addresses that must be converted into assembly labels, or deleted where not needed.

== Model 100/102 ROM Version ==
[[OptROM Support]] [[UI Code]] [[FKey Handlers]] [[RST 7 Handlers]] [[TPDD Protocol]]

= Not Completed Yet =
[[Compression/Decompression]] [[Cold Boot Recovery]]

== Model 200 RAM Version ==
[[UI Code]] [[FKey Handlers]] [[RST 7 Handlers]] [[TPDD Protocol]]

TS-DOS

2009-04-03T06:33:52Z

Kpettit:

== Variants of TS-DOS ==

TS-DOS on ROM can be purchased from [http://club100.org Club100]

TS-DOS RAM version can be downloaded from [https://club100.org Club100]

== Tips and Tricks ==

[[Using TS-DOS RAM's DOS Without the GUI]]

[[Category:TPDD Client]]

== TS-DOS Disassembly ==

[[Dissasembly of RAM and ROM versions of TS-DOS]]